
;****************************************
;*              DEMO PLAY
;****************************************

DEMO_KEY_DATA_PT:DB 0
DEMO_KEY_DIR:DB 0
DEMO_KEY_COUNTER:DB 0

DEMO_PLAY:

;------------------DEMO_INIT
PRE IX,INVINCIBLE
;現在の無敵設定を読み込む
LD $0,(IX+$31)

;SECTIONに現在の無敵設定を保存する
PRE IZ,SECTION
ST $0,(IZ+$31)

;デモ中は通常設定にする(無敵にしない)
ST $31,(IX+$31)

;STAGE NO=1
PRE IX,STAGE_NO
ST $30,(IX+$31)

PRE IX,MY_LIFE
LD $0,MY_LIFE_MAX
ST $0,(IX+$31)

PRE IX,SCORE
LDW $0,0
STW $31,(IX+$31)

;DEMO KEY INIT
PRE IX,BMP_WHITE
LDM $0,(IX+$31),3
PRE IZ,DEMO_KEY_DATA_PT
STM $0,(IZ+$31),3

;DEMO KEYの最初のデータをセットする
PRE IX,DEMO_KEY_DATA
LDM $0,(IX+$31),2;DEMO KEY DIR,COUNTER
PRE IZ,DEMO_KEY_DIR
STM $0,(IZ+$31),2;DEMO KEY DIR,COUNTER


CAL SCR_WHITE_REDRAW
CAL INIT_WORK_AREA;STAGE_NOは初期化されない
CAL SET_STAGE_DATA;MY_LIFEは最大数に設定されない
CAL DRAW_FIRST;右画面再描画

;------------------DEMO_INIT END

DEMO_PLAY_LOOP:

;----------------- INKEY PROC
PRE IX,MY_DATA
;女の子がHOP_N中ならHOP_N処理をする
LD $0,HOP_N
SBC (IX+MY_UPFALL_IDX),$0
JP Z,DEMO_GIRL_HOP
;女の子がHOP_UP中ならHOP_UP処理をする
LD $0,HOP_UP
SBC (IX+MY_UPFALL_IDX),$0
JP Z,DEMO_GIRL_HOP
;女の子がHOP_RET中ならHOP_RET処理をする
LD $0,HOP_RET
SBC (IX+MY_UPFALL_IDX),$0
JP Z,DEMO_GIRL_H_RET
;女の子がFALL中なら入力は無視する
LD $0,3
SBC (IX+MY_UPFALL_IDX),$0
JR Z,END_DEMO_KEYPROC
;HOP中でなければKEY入力へ
JR DOMO_KEY_PROC

DEMO_GIRL_HOP:
CAL GIRL_HOP
JR END_DEMO_KEYPROC
DEMO_GIRL_H_RET:
CAL GIRL_HOP_RET
JR END_DEMO_KEYPROC

DOMO_KEY_PROC:

LDW $10,(IX+$31) ;X,Y

;停止中に設定
ST $31,(IX+MY_STATUS_IDX)

PRE IX,DEMO_KEY_DIR
LD $29,(IX+$31);DEMO KEY DIR
SB (IX+$30),$30;DEMO KEY COUNTER-=1
JR NZ,INPUT_KEY_DATA

PRE IX,DEMO_KEY_DATA_PT
LD $0,2
AD (IX+$31),$0
LD $0,(IX+$31)
PRE IX,DEMO_KEY_DATA
LDM $0,(IX+$0),2
PRE IZ,DEMO_KEY_DIR
STM $0,(IZ+$31),2

INPUT_KEY_DATA:
PRE IX,MY_DATA
SBC $29,4
CAL Z,SUB_LEFT
SBC $29,6
CAL Z,SUB_RIGHT
SBC $29,9;"Q"
CAL Z,SUB_THREATEN

END_DEMO_KEYPROC:
;----------------- INKEY END

;女の子が捕まったか?

PRE IX,GIRL_CAUGHT
SBC (IX+$31),$31
JP NZ,END_DEMO_PLAY

;******************************
;*        GIRL UP FALL TEST
;******************************
PRE IX,MY_DATA
LDM $10,(IX+$31),8

LD $1,2;Yの移動量

;通常(0)及びHOP_N(1),HOP_UP(2),HOP_RET(3)中なら終了
SBC $15,4
JR C,DM_ENDGIRLFALLUP

;FALL中ならY座標を+2する。
DM_GIRL_FALLPROC:
AD $10,8;上昇,落下変更フラグはキャラの右側(+8)にあるため
SBC $15,FALL;GIRL FALL
JR NZ,DM_GIRL_UP_PROC
AD (IX+$30),$1
AD $11,$1
;女の子を落下から上昇に変更させる処理
LD $17,2;下方向
CAL CHECK_WALL_HIT
SBC $4,CONTROL_DOWN_UP;落下→上昇のフラグ
JR NZ,DM_ENDGIRLFALLUP
;
LD $0,UP;GIRL UP
ST $0,(IX+MY_UPFALL_IDX)
JR DM_ENDGIRLFALLUP

DM_GIRL_UP_PROC:
SB (IX+$30),$1
SB $11,$1
;女の子を上昇→落下に変更させる処理
SB $11,8;1つ上のマスを見るのでY=-8する
LD $17,8;上方向
CAL CHECK_WALL_HIT
SBC $4,CONTROL_UP_DOWN;上昇→落下のフラグ
JR NZ,DM_ENDGIRLFALLUP
;
LD $0,FALL;FALL
ST $0,(IX+MY_UPFALL_IDX)

DM_ENDGIRLFALLUP:

CAL MOVE_ENEMY
CAL JUDGE_ITEM_ARROW
CAL JUDGE
CAL DISP_BG
CAL JUDGE_TF
CAL JUDGE_GE
CAL DISP_GIRL
CAL DISP_ENEMY
CAL DISP_SLIPPERS
CAL DISP_ARROW
CAL DISP_RIGHT_SIDE
;
CAL @DOTDS

;REDRAW FLAG CLEAR
PRE IX,BMP_WHITE;0
LDM $0,(IX+$31),3
PRE IX,REDRAW_FLAG
STM $0,(IX+$31),3
;

;グローバルカウンタを加算する
PRE IX,GLOBAL_COUNTER
AD (IX+$31),$30

;PUSH ANY KEY表示
LD $0,(IX+$31)
AN $0,&H10
JR NZ,BREAK_DEMO_CHECK
LD $10,11
LD $11,0
LD $12,13
LDW $13,MES_HIT_ANY_KEY
LD $15,&H80
CAL D_TEXT
;
BREAK_DEMO_CHECK:
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JP Z,DEMO_PLAY_LOOP
JP TITLE


END_DEMO_PLAY:

;SECTIONに保存した無敵設定を読み込む
PRE IZ,SECTION
LD $0,(IZ+$31)

;無敵設定を復旧させる
PRE IX,INVINCIBLE
ST $0,(IX+$31)

CAL ROTATE_GIRL

;ROTATE_GIRLがSPCを押して中断したならTITLEへ移行
SBC $20,&H20
JP Z,TITLE

LDW $0,WAIT_TIME_500
CAL WAIT

JP LOGO

DEMO_KEY_DATA:
DB 4,152
DB 0,104
DB 6,176
DB 0,192
DB 4,144
