;********************************************
;*                  FOXY
;*
;* CD C:\FX-870P\FOXY
;* HD61 FOXY.TXT /P
;*
;*DA61
;* DA61 FOXY.BMP /NC /DB
;*
;*元々はキツネが落とした鍵とBOXを回収するゲームだったが、
;*左スリッパと右スリッパを回収するゲームに変更した。
;*コメントの鍵は左スリッパのこと。左スリッパ、右スリッパだと紛らわしい
;*ので、コメントは鍵の名称のままにしている。
;********************************************

PB1000:	EQU	1		;PB-1000
PB1000C:EQU	2		;PB-1000C
AI1000:	EQU	3		;AI-1000
FX870P:	EQU	4		;FX-870P+RP33(VX-4@64K/128K)
VX4:	EQU	5		;VX-4+RP33
VX3:	EQU	6		;VX-3(64K/128K)

YES:EQU 1
NO:EQU 0
ON:EQU 1
OFF:EQU 0

RELEASE_MODE:EQU 0
DEBUG_MODE:EQU 1

;********************************************
;*              SETTING
;********************************************

MODEL:EQU FX870P
TARGET:EQU RELEASE_MODE
VRAM256_USE:EQU YES

#if( MODEL = FX870P)
BASE:EQU &H1CD0
#endif

#if( MODEL = VX3)
BASE:EQU &H5000;プログラムの最終アドレスが&HFFFF未満になるように設定
#endif

ORG BASE
START START

#if (MODEL = FX870P)
;IOCS(FX-870P)
CLEME:EQU &H0157 ;870P ;$0,$1:開始アドレス $2,$3:クリアするバイト数
DOTDS:EQU &H930F ;870P
CLEDB:EQU &H9338 ;870P
INKEY:EQU &H191D ;870P
IOCS:EQU &H5321  ;BIOS CALL用

;SYSTEM WORK AREA
RXCNT:EQU &H1559
STAT:EQU &H16F1;READY START BUFFER(42BYTE),HI_SCORE(2BYTE)
CALC:EQU &H18D3;MAP_WORK
IOBUF:EQU &H19D5;MAP_WORK
#endif

#if (MODEL = VX3)
;IOCS(VX3)
CLEME:EQU &H01DF ;VX-3
DOTDS:EQU &H1FD5 ;VX-3
CLEDB:EQU &H2035 ;VX-3
INKEY:EQU &H194E ;VX-3
IOCS:EQU &H5CA7;BIOS CALL用

;SYSTEM WORK AREA
RXCNT:EQU &H6116
STAT:EQU &H66EA;READY START BUFFER(42BYTE),HI_SCORE(2BYTE)
CALC:EQU &H68CC;MAP_WORK
IOBUF:EQU &H69CE;MAP_WORK
#endif

ENEMY_DATA:EQU          RXCNT+0;64BYTE
END_ENEMY_DATA:EQU      RXCNT+63
ENEMY_MOVE_WAITS:EQU    RXCNT+64
ENEMY_MOVE_WAITN:EQU    RXCNT+65
ENEMY_MAX_NUM:EQU       RXCNT+66
FOX_MAX_NUM:EQU         RXCNT+67
SLIPPERS_HOLD:EQU       RXCNT+68
NOW_DROP:EQU            RXCNT+69;5BYTE
ITEM_POS:EQU            RXCNT+74
ITEM_X_POS:EQU          ITEM_POS
ITEM_Y_POS:EQU          RXCNT+75
REMAIN_SLIPPERS:EQU     RXCNT+76
SCORE:EQU               RXCNT+77;2BYTE
STAGE_NO:EQU            RXCNT+79
GLOBAL_COUNTER:EQU      RXCNT+80
READY_START_FG:EQU      RXCNT+81
ON_CONTINUE:EQU         RXCNT+82
READY_START_FLAG:EQU    RXCNT+83
REDRAW_FLAG:EQU         RXCNT+84
REDRAW_SCORE:EQU        REDRAW_FLAG
REDRAW_REMAIN:EQU       RXCNT+85
REDRAW_LIFE:EQU         RXCNT+86
GIRL_CAUGHT:EQU         RXCNT+87
INVINCIBLE:EQU          RXCNT+88
RANDOM_INDEX:EQU        RXCNT+89
PHASE:EQU               RXCNT+90
PHASE_COUNTER:EQU       RXCNT+91
SECTION:EQU             RXCNT+92
SECTION_COUNTER:EQU     RXCNT+93
EXTRA:EQU               RXCNT+94
EXTRA_COUNTER:EQU       RXCNT+95

READY_START_BF:EQU      STAT+0
HIGH_SCORE:EQU          STAT+42

;256*32DOT MODE
LCD_LENGTH:EQU 256

;********* WORK AREA SECTION
MAP_WORK:EQU CALC+8;注意:496BYTE必要なためCALC+IOBUFを連続して使用

;女の子のジャンプの種類
NORM:   EQU 0;歩行、停止
HOP_N:  EQU 1;レーンからトランポリンに移行する時のホップ(FALLに移行)
HOP_UP: EQU 2;トランポリンからレーンに移行する時のホップ(NORMに移行)
HOP_RET:EQU 3;側面の壁にぶつかってトランポリンに戻るホップ
FALL:   EQU 4;落下中
UP:     EQU 5;上昇中

MY_X_MIN:EQU 8		;壁(8)
MY_X_MAX:EQU 248-16	;壁(8)+自分のキャラ長(8)
MY_Y_MIN:EQU 16		;GPRINTの余白(8)+自分のキャラ長(8)
MY_Y_MAX:EQU 128-16	;床(8)+自分のキャラ長(8)

AREA_X_MIN:EQU 0
AREA_X_MAX:EQU 248-72-8;80;192-42-8
AREA_Y_MIN:EQU 8
AREA_Y_MAX:EQU 128-16

;********* WAIT
WAIT_TIME_3000:EQU 3000
WAIT_TIME_2000:EQU 2000
WAIT_TIME_1000:EQU 1000
WAIT_TIME_500:EQU 500
WAIT_TIME_300:EQU 300
WAIT_TIME_100:EQU 100
WAIT_TIME_50:EQU 50
WAIT_TIME_10:EQU 10
WAIT_TIME_1:EQU 1

START:

;*******************************************
;* BOOT_INIT
;*******************************************
;女の子のダメージ処理を有りにする
PRE IX,INVINCIBLE
ST $31,(IX+$31)

;*******************************************
;* BOOT_LOGO
;*******************************************
BOOT_LOGO:

#IF (TARGET = RELEASE_MODE)
CAL CLS
CAL CLS256

LD $10,64
LD $11,8
LD $12,64
LDW $13,BMP_LOGO
LD $16,32
CAL GPRINT_WIDE

CAL @DOTDS

LDW $0,WAIT_TIME_1000
CAL WAIT
#ENDIF

;*******************************************
;* MAKE SUPER_BG DATA
;*******************************************

#IF (TARGET = RELEASE_MODE)
CAL CLS
CAL CLS256
LD $0,$31;TITLEのみ指定
CAL DISP_TITLE
#ENDIF
;
LD $10,9
LD $11,3
LD $12,14
LDW $13,MES_PROCESSING
CAL D_TEXT
;
CAL SET_STAGE
CAL SGPRINT_INIT
JR PROLOGUE

;*******************************************
;* LOGO
;*******************************************
LOGO:

#IF (TARGET = RELEASE_MODE)
CAL CLS
CAL CLS256

LD $10,64
LD $11,8
LD $12,64
LDW $13,BMP_LOGO
LD $16,32
CAL GPRINT_WIDE

CAL @DOTDS

LDW $0,WAIT_TIME_2000
CAL NORM_WAIT
#ENDIF

;*******************************************
;* PROLOGUE
;*******************************************
PROLOGUE:

#IF (TARGET = RELEASE_MODE)
CAL CLS
CAL CLS256

;GPRINTの描画範囲を191に設定
PRE IX,GPRINT_XMAX
LD $0,191
ST $0,(IX+$31)

JP DISP_PROLOGUE

;GPRINTの描画範囲を144に設定
PRE IX,GPRINT_XMAX
LD $0,144
ST $0,(IX+$31)
#ENDIF

;*******************************************
;* TITLE
;*******************************************
TITLE:
CAL CLS
CAL CLS256

#IF (TARGET = RELEASE_MODE)

LD $0,$30;全指定(TITLE,女の子,妖怪)
CAL DISP_TITLE
LDW $0,WAIT_TIME_100
CAL WAIT

;カウンタを初期化、10回HIT SCP KEYを点滅させたらLOGO表示へ移行させる
PRE IX,PHASE
LD $0,20;10回の場合は20にする。
ST $0,(IX+$31)

;HIT SPC KEY!の描画/非描画のフラグ
LD $27,$31

TITLE_LOOP:

;PUSH SPC KEYの表示位置設定
LD $10,10
LD $11,3
LD $12,12
LD $15,&H80;NORM

;PUSH SPC KEYの点滅表示
PRE IX,GLOBAL_COUNTER
AD (IX+$31),$30
JR NC,TITLE_KEY_CK

PRE IX,PHASE
SB (IX+$31),$30
JP Z,DEMO_PLAY

SBC $27,$31
JR Z,SET_TEXT_SPACE
;-------- HIT SPC KEY
LDW $13,MES_HIT_SPC_KEY
LD $27,$31
JR DISP_TITLE_TEXT
;-------- SPACE
SET_TEXT_SPACE:
LDW $13,MES_SPACE
LD $27,&HFF
;
DISP_TITLE_TEXT:
CAL D_TEXT

TITLE_KEY_CK:
;"SPC"又は"H"入力待ち
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,0
JR Z,TITLE_LOOP
LD $3,($15)
SBC $3,&H20;SPC
JP Z,NEW_GAME_START
SBC $3,&H4D;"M"
JP Z,MENU
SBC $3,&H6D;"m"
JP Z,MENU
JR TITLE_LOOP

#ENDIF

;*******************************************
;* GAME
;*******************************************
NEW_GAME_START:

;STAGE NO=1
PRE IX,STAGE_NO
ST $30,(IX+$31)

;女の子のLIFEを最大に設定
PRE IX,MY_LIFE
LD $0,MY_LIFE_MAX
ST $0,(IX+$31)

;スコアの初期化
PRE IX,SCORE
LDW $0,0
STW $31,(IX+$31)

NEXT_STAGE:

CAL SCR_WHITE_REDRAW
CAL INIT_WORK_AREA;STAGE_NOは初期化されない
CAL SET_STAGE_DATA;MY_LIFEは最大数に設定されない

DISP_READY:
CAL DRAW_FIRST;右画面再描画
;READY START FLAG描画FLAG=ON
PRE IX,READY_START_FLAG
ST $31,(IX+$31)

;PHASE及びPHASE COUNTER初期化
PRE IX,L_PHASE
LDW $0,0
STW $0,(IX+$31)

DISP_READY_LOOP:
CAL DISP_NON_GIRL
CAL DISP_GIRL
CAL READY_START_DISP
CAL @DOTDS
PRE IX,READY_START_FLAG
SBC (IX+$31),$31
JR Z,DISP_READY_LOOP

CAL HIT_ANYKEY

;*******************************************
;* MAIN_LOOP
;*******************************************

MAIN_LOOP:

;女の子が捕まったか?
PRE IX,GIRL_CAUGHT
SBC (IX+$31),$31
JP NZ,GIRL_CAUGHT_PROC

GAME_PROC:

CAL IN_KEY;GET_PUSHKEY

;******************************
;*        GIRL UP FALL TEST
;******************************
PRE IX,MY_DATA
LDM $10,(IX+$31),8

LD $1,2;Yの移動量

;通常(0)及びHOP_N(1),HOP_UP(2),HOP_RET(3)中なら終了
SBC $15,4
JR C,END_GIRL_FALL_UP

;FALL中ならY座標を+2する。
GIRL_FALL_PROC:
AD $10,8;上昇,落下変更フラグはキャラの右側(+8)にあるため
SBC $15,FALL;GIRL FALL
JR NZ,GIRL_UP_PROC
AD (IX+$30),$1
AD $11,$1
;女の子を落下から上昇に変更させる処理
LD $17,2;下方向
CAL CHECK_WALL_HIT
SBC $4,CONTROL_DOWN_UP;落下→上昇のフラグ
JR NZ,END_GIRL_FALL_UP
;
LD $0,UP;GIRL UP
ST $0,(IX+MY_UPFALL_IDX)
JR END_GIRL_FALL_UP

GIRL_UP_PROC:
SB (IX+$30),$1
SB $11,$1
;女の子を上昇→落下に変更させる処理
SB $11,8;1つ上のマスを見るのでY=-8する
LD $17,8;上方向
CAL CHECK_WALL_HIT
SBC $4,CONTROL_UP_DOWN;上昇→落下のフラグ
JR NZ,END_GIRL_FALL_UP
;
LD $0,FALL;FALL
ST $0,(IX+MY_UPFALL_IDX)

END_GIRL_FALL_UP:

CAL MOVE_ENEMY
CAL JUDGE_ITEM_ARROW
CAL JUDGE
CAL DISP_BG
CAL JUDGE_TF
CAL JUDGE_GE
CAL DISP_GIRL
CAL DISP_ENEMY
CAL DISP_SLIPPERS
CAL DISP_ARROW
CAL DISP_RIGHT_SIDE
;
CAL @DOTDS

;REDRAW FLAG CLEAR
PRE IX,BMP_WHITE;0
LDM $0,(IX+$31),3
PRE IX,REDRAW_FLAG
STM $0,(IX+$31),3
;

;グローバルカウンタを加算する
PRE IX,GLOBAL_COUNTER
AD (IX+$31),$30
;
JP MAIN_LOOP

;*********************************
;*           ENDING
;*********************************
ENDING:

#IF (TARGET = RELEASE_MODE)
LD $10,0
LD $11,8
LD $12,192
LDW $13,BMP_GAME_CLEAR
LD $15,&H80;NORM
LD $16,32
CAL D_GPRINT_WIDE

LDW $0,WAIT_TIME_3000
CAL WAIT
#ENDIF

JP DISP_RESULT

;*********************************
;*        SCR_WHITE_REDRAW
;*********************************
SCR_WHITE_REDRAW:
LDW $28,DOTDS
JP IOCS_CAL

;*********************************
;*      JUDGE_ITEM_ARROW
;*********************************
JUDGE_ITEM_ARROW:

;女の子と鍵/アイテムの接触判定
PRE IX,MY_DATA
LDW $10,(IX+$31)
LD $28,$31;GIRL
CAL JUDGE_ITEM

;妖怪と矢印/鍵の接触判定
PRE IX,ENEMY_DATA
LDM $9,(IX+$31),4

;妖怪と矢印の接触判定
CAL JUDGE_RA;RET:ZERO FLAG - ON:接触 OFF:接触していない
JR NZ,JUDGE_RIVAL_KEY;妖怪が矢印に接触していなければデータは更新しない

STM $9,(IX+$31),4

;妖怪と鍵の接触判定
JUDGE_RIVAL_KEY:
LD $28,$30;RIVAL
CAL JUDGE_ITEM

RTN

;*********************************
;*    DISP_TITLE
;*********************************
DISP_TITLE:

#IF (TARGET = RELEASE_MODE)

SBC $0,$31
JP Z,DISP_TITLE_ONLY

;GIRL
LD $10,0
LD $11,8
LD $12,48
LDW $13,BMP_TITLE_GIRL
LD $16,32
CAL D_GPRINT_WIDE

;RIVAL
LD $10,136
LD $11,8
LD $12,56
LDW $13,BMP_TITLE_YOUKAI
LD $16,32
CAL D_GPRINT_WIDE

DISP_TITLE_ONLY:

LD $10,48
LD $11,8
LD $12,96
LD $16,24
LDW $13,BMP_TITLE
JP D_GPRINT_WIDE
#ELSE
RTN
#ENDIF


;*********************************
;*    READY_START BUF CLEAR
;*********************************
RS_WORK_CLEAR:
LDW $0,STAT
LDW $2,42
LDW $28,CLEME
JP IOCS_CAL

;*********************************
;*          READY_START_DISP
;*********************************

L_PHASE:EQU STAT+40              ;LOCAL PHASE
L_PHASE_COUNTER:EQU STAT+41      ;LOCAL PHASE COUNTER

READY_START_DISP:

PRE IX,READY_START_FLAG
SBC (IX+$31),$31
RTN NZ

;STAGE_NO生成
PRE IX,STAGE_NO
LD $0,(IX+$31)
AD $0,&H30
PRE IX,MES_STAGE_NO
ST $0,(IX+$31)
;STAGE+NO表示
LD $10,9
LD $11,0
LD $12,8
LDW $13,MES_STAGE
CAL TEXT256

PRE IX,L_PHASE
LD $15,(IX+$31)

PRE IX,L_PHASE_COUNTER
LD $1,(IX+$31)

LD $2,$31 ;COUNTER

PRE IZ,STAT

;PHASEが奇数なら消去処理へ移行(奇数なら)
ANC $15,$30
JR NZ,READYSTART_ERASE

RS_PHASE2:;START DISP
PRE IX,BMP_READY
SBC $15,$31
JR Z,READY_START_LOOP
PRE IX,BMP_START
READY_START_LOOP:
LD $0,(IX+$2)
ST $0,(IZ+$2)
AD $2,$30
SBC $2,$1
JR C,READY_START_LOOP
JR RSD_DRAW

READYSTART_ERASE:
RS_ERASE_LOOP:
LDW $15,0
STW $15,(IZ+$1)

RSD_DRAW:
;READY START ERASEの表示
LD $10,58
LD $11,24
LD $12,40
LDW $13,STAT

PHU $1
CAL GPRINT
PPU $1

;カウンター加算及びフェーズ移行判定
AD $1,2
PRE IX,L_PHASE_COUNTER
ST $1,(IX+$31)
SBC $1,40;READY_START_MAX
JR NC,END_RSD_PHASE
RTN

END_RSD_PHASE:
PRE IX,L_PHASE_COUNTER
ST $31,(IX+$31)
PRE IX,L_PHASE
AD (IX+$31),$30
LD $0,(IX+$31)
SBC $0,4
RTN C
PRE IX,READY_START_FLAG
;READY START 表示終了
ST $30,(IX+$31)
RTN

;******************************
;*      STAGE_CLEAR
;******************************

MES_STAGE_CLEAR:DB " STAGE ";7
MES_GAME_CLEAR:DB  "  GAME ";7
MES_CLEAR:DB       " CLEAR! ";8

STAGE_CLEAR:
;
CAL DRAW_REMAIN
CAL DISP_NON_GIRL
PRE IX,MY_DATA
LDW $10,(IX+$31)
CAL CONV_G2V
LDW $13,GIRL_V_SIGN
CAL GPRINT1616
CAL @DOTDS
;
LD $10,8
LD $11,2
LD $12,7
LDW $13,MES_CLEAR
LD $15,&H80;NORM
CAL D_TEXT
;
PRE IX,STAGE_NO
LD $0,(IX+$31)
;
SBC $0,LAST_STAGE
JR Z,GAME_CLEAR
;
AD (IX+$31),$30
;
LD $10,8
LD $11,1
LD $12,7
LDW $13,MES_STAGE_CLEAR
LD $15,&H80;NORM
CAL D_TEXT

LDW $0,WAIT_TIME_100
CAL WAIT

CAL HIT_ANYKEY

JP NEXT_STAGE

GAME_CLEAR:
PRE IX,STAGE_NO
ST $31,(IX+$31)

LD $10,8
LD $11,1
LD $12,7
LDW $13,MES_GAME_CLEAR
LD $15,&H80;NORM
CAL D_TEXT

LDW $0,WAIT_TIME_1000
CAL WAIT

CAL HIT_ANYKEY

JP ENDING

;******************************
;*         CLS256
;*
;*      仮想VRAMをクリアする
;******************************
CLS256:
LDW $0,VRAM_START               ;$0,$1:開始アドレス
LDW $2,VRAM_END-VRAM_START      ;$2,$3:クリアするバイト数
LDW $28,CLEME
JP IOCS_CAL

;******************************
;*      GIRL ROTATE
;******************************
GIRL_CAUGHT_PROC:
;
CAL ROTATE_GIRL
;
;女の子が捕まったフラグを解除
PRE IX,GIRL_CAUGHT
ST $31,(IX+$31)

;女の子が左スリッパを持っていたら、鍵を持ち主のキツネに返す処理
PRE IZ,SLIPPERS_HOLD
SBC (IZ+$31),$30
JR Z,RETURN_KEY_FOX
;右スリッパが出現していたら、アイテムの鍵を持ち主のキツネに返す処理
PRE IZ,NOW_DROP
SBC (IZ+$31),$30
JR NZ,RESET_POSITION

RETURN_KEY_FOX:
;スリッパ出現フラグをOFFにする
PRE IZ,NOW_DROP
ST $31,(IZ+$31)
;きつねに返す処理
;
PHU $20;$20=&H20ならROTATE_GIRLがSPCで中断
;
LD $29,DROP_FOX_ADR_IDX
LDW $20,(IZ+$29)
PRE IZ,$20;取り戻したスリッパを所有していたキツネのデータのアドレス
LD $20,(IZ+ENEMY_MOVCNT_IDX)
OR $20,&H80;キツネのスリッパ所有FLAG=ON
ST $20,(IZ+ENEMY_MOVCNT_IDX)
;
PPU $20
;
;女の子が左スリッパを持っているフラグをクリア
PRE IZ,SLIPPERS_HOLD
ST $31,(IZ+$31)

RESET_POSITION:
PRE IX,STAGE_NO
LD $0,(IX+$31)

SBC $0,1
JR Z,RESET_POS_STAGE1
SBC $0,2
JR Z,RESET_POS_STAGE2
SBC $0,3
JR Z,RESET_POS_STAGE3
SBC $0,4
JR Z,RESET_POS_STAGE4

RESET_POS_STAGE5:
PRE IX,STAGE5_MY_DATA
LDW $0,STAGE5_ENEMYDATA
JR RESET_POS
RESET_POS_STAGE1:
PRE IX,STAGE1_MY_DATA
LDW $0,STAGE1_ENEMYDATA
JR RESET_POS
RESET_POS_STAGE2:
PRE IX,STAGE2_MY_DATA
LDW $0,STAGE2_ENEMYDATA
JR RESET_POS
RESET_POS_STAGE3:
PRE IX,STAGE3_MY_DATA
LDW $0,STAGE3_ENEMYDATA
JR RESET_POS
RESET_POS_STAGE4:
PRE IX,STAGE4_MY_DATA
LDW $0,STAGE4_ENEMYDATA
;
RESET_POS:
;MY DATA RESET
PRE IZ,MY_DATA
LDM $10,(IX+$31),7;LIFEは除く
STM $10,(IZ+$31),7

;ENEMY DATA RESET
PRE IX,$0
PRE IZ,ENEMY_DATA

LD $0,8;COUNTER

;($14)DROP ITEM保有/気まぐれカウンタは除く
RESET_POS_LOOP:
LDIM $10,(IX+$31),8
STIM $10,(IZ+$31),4
LDI $14,(IZ+$31);IZ=IZ+1(DROP ITEM保有/気まぐれカウンタは維持)
STIM $15,(IZ+$31),3;0

SB $0,$30
JR NZ,RESET_POS_LOOP

;LIFEを減じる
PRE IX,MY_LIFE
SB (IX+$31),$30
JP C,CONTINUE

SBC $20,&H20
JP Z,DISP_READY;女の子が回転中にSPCを押したらWAITは無視する

CAL HIT_ANYKEY

JP DISP_READY

ROTATE_GIRL:

CAL DRAW_SCORE

LDW $0,0;BMP ADRESS POINTER
LDW $2,32;NEXT BMP ADRESS
LD $4,4*8;女の子が回転するカウンター(1回転4アニメ*回転数)

PRE IX,MY_DATA
LDW $10,(IX+$31)
CAL CONV_G2V

GIRL_ROTATE_LOOP:

PHUM $4,5
PHUW  $11
CAL DISP_NON_GIRL
;DISP ROTATE GIRL
PPUW $10
PPUM $0,5
PHUM $4,5
PHUW $11
LDW $13,GIRL_ROTATE_0
ADW $13,$0
CAL GPRINT1616
CAL @DOTDS
;WAIT
LDW $0,WAIT_TIME_10
CAL WAIT
;
LD $20,$31
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JR Z,ROTATE_BREAK
LD $20,($15)
ROTATE_BREAK:
;
PPUW $10
PPUM $0,5
;
SBC $20,&H20
RTN Z
;
ADW $0,$2
AN $0,&H7E;128
SB $4,$30
JR NC,GIRL_ROTATE_LOOP
PHUW $11
CAL DISP_NON_GIRL
PPUW $10
LDW $13,GIRL_TEARS
CAL GPRINT1616
CAL @DOTDS

;RET CODE=ROTATE_GIRLでSPCを押すことによる中断ではない
LD $20,$31

RTN

;*************************************
;*      DISP_NON_GIRL
;*
;*女の子以外(RAIVAL、きつね、背景、矢印等)表示
;*************************************
DISP_NON_GIRL:
CAL DISP_BG
CAL DISP_ENEMY
CAL DISP_SLIPPERS
CAL DISP_ARROW
CAL DISP_RIGHT_SIDE
RTN

;******************************
;*      CONTINUE
;******************************
CONTINUE:

;CAL DRAW_FIRST;右画面再描画

;GAME OVERの表示
LD $10,8
LD $11,1
LD $12,10
LDW $13,MES_GAME_OVER
LD $15,&H80;NORM
CAL D_TEXT

;RETRYの表示
LD $10,8
LD $11,2
LD $12,11
LDW $13,MES_RETRY
LD $15,&H80;NORM
CAL D_TEXT

LDW $0,WAIT_TIME_100
CAL WAIT

RETRY_LOOP:
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JR Z,RETRY_LOOP
LD $0,($15)
SBC $0,&H59;"Y"
JR Z,RETRY_YES
SBC $0,&H79;"y"
JR Z,RETRY_YES
SBC $0,&H4E;"N"
JR Z,RETRY_NO
SBC $0,&H6E;"n"
JR Z,RETRY_NO
JR RETRY_LOOP

RETRY_YES:

;SCORE初期化
LDW $0,0
PRE IX,SCORE
STW $0,(IX+$31)

;SET MY_LIFE_MAX
PRE IX,MY_LIFE
LD $0,MY_LIFE_MAX
ST $0,(IX+$31)
JP DISP_READY

RETRY_NO:

#IF (TARGET = RELEASE_MODE)
CAL CLS

LD $10,48
LD $11,8
LD $12,96
LDW $13,BMP_GAME_OVER
LD $15,&H80
LD $16,32
CAL D_GPRINT_WIDE

LDW $0,WAIT_TIME_2000
CAL WAIT
#ENDIF

JR DISP_RESULT

;*********************************
;*        DISP_RESULT
;*
;*USE:
;*      $0-$11  MESSAGE LDM/STM WORK/BTOB PARA
;*      $23,$24 NOW SCORE
;*      $25,$26 NOW HIGH SCORE
;*      IX      INDEX WORK
;*      IZ      INDEX WORK
;*********************************
DISP_RESULT:

;CLS
CAL SCR_WHITE_REDRAW

PRE IX,SCORE
LDW $23,(IX+$31);$23,$24:SCORE
PRE IX,HIGH_SCORE
LDW $25,(IX+$31);$25,$26,HI-SCORE

;"RESULT"表示
PRE IX,MES_RESULT
LD $10,13
LD $11,$31
LD $12,6
LDW $13,MES_RESULT
CAL D_TEXT

;"HIGH SCORE: "表示
LD $10,7
LD $11,$30
LD $12,11
LDW $13,MES_NOWHISCORE
CAL D_TEXT

LDW $8,$25 ;BTOB(2進数を10進数に変換するサブルーチンに値を設定)
LD $10,18;
LD $11,$30
CAL D_BTOB

;"YOUR SCORE: "表示
LD $10,7
LD $11,2
LD $12,11
LDW $13,MES_NOWSCORE
CAL D_TEXT

LDW $8,$23 ;BTOB(2進数を10進数に変換するサブルーチンに値を設定)
LD $10,18;BTOBで10進化した得点の表示位置設定
CAL D_BTOB

SBCW $25,$23 ;今回の得点がハイスコアを上回ったら、ハイスコアを更新してハイスコアの表示をする
JR NC,DISP_RESULT_WAIT
PRE IZ,HIGH_SCORE
STW $23,(IZ+$31)

LD $10,7
LD $11,3
LD $12,16
LDW $13,MES_NEWHISCORE
CAL D_TEXT

DISP_RESULT_WAIT:

LDW $0,WAIT_TIME_1000
CAL WAIT

CAL HIT_ANYKEY

JP TITLE


;******************************
;*      INIT_WORK_AREA
;******************************
INIT_WORK_AREA:

;ZERO DATA READ
PRE IX,BMP_WHITE
LDM $0,(IX+$31),8

;鍵のデータ
PRE IX,SLIPPERS_HOLD
STM $0,(IX+$31),6;SLIPPERS_HOLD(1),NOW_DROP(5)

;CONTROL FLAG
PRE IX,READY_START_FLAG
STM $0,(IX+$31),4;READT START,REDRAW_SCORE,REDRAW_REMAIN,REDRAW_LIFE

;女の子が捕まったフラグ
PRE IX,GIRL_CAUGHT
ST $31,(IX+$31)

RTN

;******************************
;*      DRAW_FIRST
;******************************
DRAW_FIRST:
;GAME_TITLE(BMP)
LD $10,144
LD $11,8
LD $12,48
LDW $13,BMP_GAME_TITLE
CAL D_GPRINT

;DRAW_SCORE TEXT
;"SC:"(TEXT)
LD $10,24
LD $11,1
LD $12,3
LDW $13,MES_SC
CAL D_TEXT

CAL DRAW_SCORE
CAL DRAW_REMAIN
CAL DRAW_LIFE
RTN

;******************************
;*      SET STAGE DATA
;******************************
SET_STAGE_DATA:
PRE IX,STAGE_NO
LD $0,(IX+$31)
SBC $0,1
JP Z,SET_STAGE1_DATA
SBC $0,2
JP Z,SET_STAGE2_DATA
SBC $0,3
JP Z,SET_STAGE3_DATA
SBC $0,4
JP Z,SET_STAGE4_DATA
;SBC $0,5
JP SET_STAGE5_DATA
;END

;******************************************
;*              JUDGE ITEM
;*
;*　女の子と妖怪の鍵とスリッパとの接触判定
;*
;*　注意:$9-$16は変更しないこと
;*
;*PARA:
;*      $10     - GIRL X/RIVAL X
;*      $11     - GIRL Y/RIBAL Y
;*      $28     - 0:GIRL₋KEY 1:RIVAL-KEY &HFF:GIRL-SLIPPERS
;*      IX      - MY_DATA ADRESS/ENEMY_DATA(0:RIVAL)
;*USE:
;*      $0      - ITEM X
;*      $1      - ITEM Y
;*      $2,$3   - SCORE
;*      $4,$5   - 加算する得点
;*      $22     - ITEM X + X_LEN
;*      $23     - ITEM Y + Y_LEN
;*      $20     - GIRL X/RIVAL X + X_LEN
;*      $21     - GIRL Y/RIVAL Y + Y_LEN
;*      $29     - RET CODE(JUDGE)
;*      $20,$21 - WORK(妖怪が取り戻した鍵を所有していたキツネのデータのアドレス)
;*      $29     - WORK(INDEX)
;*      IZ      - WORK
;******************************************

JUDGE_ITEM:

PRE IZ,ITEM_POS
LDW $0,(IZ+$31)

;女の子が左スリッパを未保有なら鍵との衝突判定処理へ
PRE IZ,SLIPPERS_HOLD
SBC (IZ+$31),$31
JR Z,JUDGE_KEY

;*****************************
;*女の子とスリッパとの衝突判定準備
;*****************************

;妖怪?
SBC $28,$30;RIVAL?
JR Z,RAIVAL_SLOPPERS
;女の子とスリッパの衝突判定モードに設定
LD $28,&HFE
JR JUDGE_ITEM_PROC
RAIVAL_SLOPPERS:
LD $28,&HFF
JR JUDGE_ITEM_PROC

;*****************************
;*鍵との衝突判定準備
;*****************************
JUDGE_KEY:
;DROP ITEMが出現していなければ戻る
PRE IZ,NOW_DROP
SBC (IZ+$31),$31
RTN Z

;*****************************
;*アイテム(鍵/スリッパ)との衝突判定処理
;*****************************
JUDGE_ITEM_PROC:

;ITEMのの衝突範囲を設定
;X:ITEMのX+0～ITEMのX+6に設定
;Y:ITEMのY+0～ITEMのY+16に設定
LD $22,$0;X
LD $23,$1;Y
AD $22,6;X+?
AD $23,16;Y+?

;GIRL/RIVALの衝突範囲を設定
;X:GIRL/RIVALのX+4～GIRL/RIVALのX+12の中央8DOTに設定
;Y:GIRL/RIVALのY+0～GIRL/RIVALのY+8に設定
PHU $10
;
AD $10,4
LD $20,$10
LD $21,$11
AD $20,8
AD $21,8

CAL JUDGE;JUDGE RETURN CODE 0:HIT 1:NO HIT
;
PPU $10
;
SBC $29,$31;HIT?
RTN NZ

SBC $28,&HFE;女の子とスリッパの衝突判定モードか?
JR Z,GIRL_SLIPER_PROC
SBC $28,&HFF;妖怪スリッパの衝突判定モードか?
JR Z,RIVAL_SLIPR_PROC

;***********************
;*女の子/妖怪と鍵の衝突処理
;***********************
GIRL_RIVAL_KEY:
;ITEM出現フラグをOFFにする
ST $31,(IZ+$31)
SBC $28,$31;GIRL?
JR Z,GIRL_GET_KEY
;妖怪が鍵を取り戻した処理
LD $29,DROP_FOX_ADR_IDX
LDW $20,(IZ+$29)
PRE IZ,$20;取り戻した鍵を所有していたキツネのデータのアドレス
LD $20,(IZ+ENEMY_MOVCNT_IDX)
OR $20,&H80;鍵所有FLAG=ON
ST $20,(IZ+ENEMY_MOVCNT_IDX)
RTN

GIRL_GET_KEY:
;女の子が左スリッパを保有したフラグの設定
PRE IZ,SLIPPERS_HOLD
ST $30,(IZ+$31)
;得点を加算する
PRE IZ,SCORE
LDW $4,SCORE_GET_KEY
ADW (IZ+$31),$4
;REDRAW FLAG SET
PRE IX,REDRAW_SCORE
ST $30,(IX+$31);SCORE REDRAW
;
;スリッパの位置を決め、ITEM_POSにX,Y情報を書き込む
CAL SET_DROPITEM_POS

;女の子の鍵保有表示して戻る
JP DRAW_REMAIN

;***********************
;*女の子とスリッパの衝突処理
;***********************
GIRL_SLIPER_PROC:
;左スリッパを非保持にする
PRE IZ,SLIPPERS_HOLD
ST $31,(IZ+$31)
PRE IZ,NOW_DROP
ST $31,(IZ+$31)
;得点を加算する
PRE IZ,SCORE
LDW $4,SCORE_GET_SLIPPR
ADW (IZ+$31),$4
;REDRAW FLAG SET
PRE IZ,REDRAW_FLAG
LD $6,$30;SCORE REDRAW
LD $7,$30;REMAIN SLIPPERS REDRAW
STW $6,(IZ+$31)
;女の子の左スリッパ保有表示を解除する
CAL DRAW_REMAIN
;残スリッパ数を減じる
PRE IZ,REMAIN_SLIPPERS
SB (IZ+$31),$30
RTN NZ
;残スリッパ数が0になったらステージクリア処理へ移行
;JUDGE_ITEMを呼んだSSPをクリア
PPSW $0
;JUDGE_ITEM_ARROWを呼んだSSPをクリア
PPSW $0
JP STAGE_CLEAR

;***********************
;*妖怪とスリッパの衝突処理
;***********************
RIVAL_SLIPR_PROC:
;ITEM出現フラグをOFFにする
;左スリッパを非保持にする
PRE IZ,SLIPPERS_HOLD
ST $31,(IZ+$31)
PRE IZ,NOW_DROP
ST $31,(IZ+$31)
;妖怪が鍵を取り戻した処理
LD $29,DROP_FOX_ADR_IDX
LDW $20,(IZ+$29)
PRE IZ,$20;取り戻した鍵を所有していたキツネのデータのアドレス
LD $20,(IZ+ENEMY_MOVCNT_IDX)
OR $20,&H80;鍵所有FLAG=ON
ST $20,(IZ+ENEMY_MOVCNT_IDX)
;女の子の鍵保有表示を解除して戻る
JP DRAW_REMAIN

;*******************************
;*           JUDGE
;*
;*          衝突判定
;*
;*PARA:
;*      $0      - X(A)
;*      $1      - Y(A)
;*      $22     - X(A)+X_LEN
;*      $23     - Y(A)+Y_LEN
;*      $10     - X(B)
;*      $11     - Y(B)
;*      $20     - X(B)+X_LEN
;*      $21     - Y(B)+Y_LEN
;*
;*RET:
;*      $29     - 0:HIT 1:FAIL
;*******************************
JUDGE:

;SET RETURN CODE FAIL
LD $29,$30

;AとBが衝突する条件
;EX2($20)<FX1($0)=$0-$20>=0
;EX1($10)>FX2($22)=$10-$22>=0
;EY2($21)<FY1($1)=$1-$21>=0
;EY1($11)>FY2($23)=$11-$23>=0

SBC $0,$20
RTN NC;範囲外
SBC $10,$22
RTN NC;範囲外
SBC $1,$21
RTN NC;範囲外
SBC $11,$23
RTN NC;範囲外

;SET RETURN CODE FAIL
LD $29,$31
RTN

;******************************************
;*              JUDGE GE
;*
;*　女の子と敵の接触判定
;*
;*USE:IZ
;*RET:ZERO FLAG - ON:接触 OFF:接触していない
;******************************************
JUDGE_GE:

PRE IX,MY_DATA
;女の子が歩行状態でしか判定しない
SBC (IX+MY_UPFALL_IDX),$31
RTN NZ

LDW $0,(IX+$31)

;女の子と敵の接触判定の範囲はX+8～X+12,Y～Y+16
AD $0,8
LD $22,$0
LD $23,$1
AD $22,4
AD $23,16

;敵の最大数(妖怪+きつね)を読み込む
PRE IX,ENEMY_MAX_NUM
LD $27,(IX+$31)

PRE IX,ENEMY_DATA

JUDGE_GE_LOOP:

LDIM $9,(IX+$31),8
SBC $9,$31
JR Z,NEXT_JUDGE_GE

;キツネが気絶状態なら判定しない
SBC $9,3
JR Z,NEXT_JUDGE_GE
;妖怪とキツネが歩行状態なら判定する
SBC $14,$31
JR NZ,NEXT_JUDGE_GE

AD $10,2
LD $20,$10
LD $21,$11
AD $20,12;ENEMY_X+ENEMY_LENGTH_X
AD $21,16;ENEMY_Y+ENEMY_LENGTH_Y

CAL JUDGE;JUDGE RETURN CODE 0:HIT 1:NO HIT
SBC $29,$31;HIT?
JR NZ,NEXT_JUDGE_GE

;女の子が捕まった処理

;無敵設定であれば女の子が捕まったフラグを立てない
PRE IX,INVINCIBLE
SBC (IX+$31),$31;0:通常 OTHER:INVINCIBLE(無敵)
JR NZ,NO_GIRL_CAUGHT
PRE IX,GIRL_CAUGHT
ST $30,(IX+$31)
NO_GIRL_CAUGHT:

RTN

NEXT_JUDGE_GE:
SB $27,$30
JR NZ,JUDGE_GE_LOOP
RTN

;******************************************
;*              JUDGE RA
;*
;*　妖怪と矢印の接触判定
;*
;*PARA: $10 - RIVAL X
;*      $11 - RIVAL Y
;*      $12 - RIVAL DIR
;*USE:IZ
;*RET:ZERO FLAG - ON:接触 OFF:接触していない
;******************************************
JUDGE_RA:

PHUW $11;これに対応するPOPは、矢印と接触した場合としなかった場合の2か所あるので注意

;RIVALの衝突範囲を設定
;X:RIVALのX+2～GIRL/RIVALのX+12の中央10DOTに設定
;Y:RIVALのY+0～GIRL/RIVALのY+8に設定

AD $10,2
LD $20,$10
LD $21,$11
AD $20,12
AD $21,8

PRE IZ,ARROW_DATA
ARROW1_DIR_CK:
SBC (IZ+ARROW1+ARROW_DIR),$12;妖怪と同方向なら判定しない
JR Z,ARROW2_DIR_CK

;ARROW1 X,Y LOAD
LDW $0,(IZ+$30)

LD $22,$0
LD $23,$1
AD $22,8
AD $23,8

CAL JUDGE;JUDGE RETURN CODE 0:HIT 1:NO HIT
SBC $29,$31;HIT?
JR NZ,ARROW2_DIR_CK

LD $0,ARROW1+ARROW_DIR;SET ARROW1
JR RIVAL_REVERS

ARROW2_DIR_CK:
SBC (IZ+ARROW2+ARROW_DIR),$12;妖怪と同方向なら判定しない
JR Z,END_JUDGE_RA_NZ

;ARROW2 X,Y LOAD
LD $22,ARROW2+1;0=ARROW IDENTIFICATION,1:X,2:Y
LDW $0,(IZ+$22)

LD $22,$0
LD $23,$1
AD $22,8
AD $23,8

CAL JUDGE;JUDGE RETURN CODE 0:HIT 1:NO HIT
SBC $29,$31;HIT?0:HIT 1:FAIL
JR NZ,END_JUDGE_RA_NZ

LD $0,ARROW2+ARROW_DIR;SET ARROW2

RIVAL_REVERS:
;
PPUW $10
;
SBC $12,$31
JR Z,RIVAL_REVERS_R
RIVAL_REVERS_L:
AD $10,$30;矢印と接触した次のフレームでX移動禁止になるとハマるので接触範囲外に移動させる
LD $12,$31;RIVAL DIR L -> R
ST $30,(IZ+$0);ARROW DIR -> L
JR END_JUDGE_RA_Z
RIVAL_REVERS_R:
SB $10,$30;矢印と接触した次のフレームでX移動禁止になるとハマるので接触範囲外に移動させる
LD $12,$30;RIVAL DIR R -> L
ST $31,(IZ+$0);ARROW DIR -> R
END_JUDGE_RA_Z:
SBC $31,$31;SET Z FLAG
RTN

END_JUDGE_RA_NZ:
;
PPUW $10
;
SBC $30,$31;SET NZ FLAG
RTN

;******************************************
;*              DISP ARROW
;******************************************
DISP_ARROW:

;オブジェクトのグローバル座標をVIEW座標に変換する
;オブジェクトと女の子のグローバル座標の差分を算出する
PRE IZ,MY_DATA
LDW $10,(IZ+$31)

AN $11,&HFE
DISP_ARROW1:
PRE IX,ARROW_DATA
LDM $0,(IX+$31),8
;$0-ID
;$1-X
;$2-Y
;$7-DIR
PHUW $11
CAL ALLOW_DISP
PPUW $10

DISP_ARROW2:
PRE IX,ARROW_DATA+ARROW_STRUCTSIZE
LDM $0,(IX+$31),8
;$0-ID
;$1-X
;$2-Y
;$7-DIR

ALLOW_DISP:
SB $1,$10
SB $2,$11
;女の子のVIEW座標に差分を加える
CAL CONV_G2V
AD $10,$1
AD $11,$2
LD $12,$31;0:8DOT
SBC $7,$31;RIGHT?
JR Z,ALLOW_DISP_R
LDW $13,SG_CHR_DATA27;LEFT ARROW
JP SGPRINT_FAST
ALLOW_DISP_R:
LDW $13,SG_CHR_DATA28;RIGHT ARROW
JP SGPRINT_FAST

;******************************************
;*          DISP_SLIPPERS
;******************************************
DISP_SLIPPERS:

;スリッパの位置情報を読み込む
PRE IX,ITEM_POS
LDW $1,(IX+$31)

PRE IX,SLIPPERS_HOLD
SBC (IX+$31),$31;女の子が鍵を保有?
JR Z,DISP_SLIPPERS_L

DISP_SLIPPERS_R:

;キャラクタアドレス設定
LDW $13,SG_CHR_DATA26;SLOPPERS_R
JR DRAW_KEY_OR_SLIP

DISP_SLIPPERS_L:
;DROP中でなければ戻る
PRE IX,NOW_DROP
SBC (IX+$31),$31
RTN Z

;キャラクタアドレス設定
LDW $13,SG_CHR_DATA25;SLIPPERS_L

DRAW_KEY_OR_SLIP:
;オブジェクトのグローバル座標をVIEW座標に変換する
;オブジェクトと女の子のグローバル座標の差分を算出する
PRE IZ,MY_DATA
LDW $10,(IZ+$31)
SB $1,$10
SB $2,$11
;女の子のVIEW座標に差分を加える
CAL CONV_G2V
AD $10,$1
AD $11,$2

AN $11,&HFE

LD $12,$31;0:8DOT
JP SGPRINT_FAST

;******************************************
;*              JUDGE_TF
;*
;*USE:
;*      $0      - MY_X
;*      $1      - MY_Y
;*      $2,$3   - SCORE
;*      $4,$5   - 加算する得点
;*      $9-$16  - ENEMY DATA
;*      $17     - DROP ITEM WORK
;*      $18,$19 - DROP ITEM ADRESS WORK
;*      $20     - ENEMY_X + X_LEN
;*      $21     - ENEMY_Y + Y_LEN
;*      $22     - MY_X + X_LEN
;*      $23     - MY_Y + Y_LEN
;*      $24     - キツネがノックアウト状態のID(3)
;*      $25     - キツネがノックアウトから復帰する待ち時間(64)
;*      $26     - FOX_KO_RESERVE FLAG(&HFF)
;*      $27     - DROP ITEM EXIST FLAG
;*      $28     - キツネの数
;*      $29     - JUDGE RETURN CODE
;*
;******************************************

JUDGE_TF:
;キツネを脅かしていないなら戻る
PRE IX,MY_DATA
SBC (IX+MY_THREATEN_IDX),$31
RTN Z

;SCOREの読み込み
PRE IZ,SCORE
LDW $2,(IZ+$31)

;加算する得点の設定
LDW $4,SCORE_THREATEN

;$0=MY_X,$1=MY_Y
LDW $0,(IX+$31)

SBC (IX+MY_DIR_IDX),$31;RIGHT DIR?
JR Z,SET_THREATEN_R

SET_THREATEN_L:
SB $0,8;女の子の左パンチの開始位置(X座標-パンチの効果幅8DOT)
LD $22,$0
AD $22,8;効果8DOT(SB $0,8の前にLD $22,$0を置くと、このAD $22,8は不要)
JR THREATEN_PROC

SET_THREATEN_R:
AD $0,16;女の子の右パンチの開始位置(X座標+キャラ幅16DOT)
LD $22,$0
AD $22,8;効果8DOT

THREATEN_PROC:
LD $23,$1
AD $23,16

;DROPフラグを読み込み
PRE IX,NOW_DROP
LD $27,(IX+$31)

PRE IZ,FOX_MAX_NUM
LD $28,(IZ+$31);きつねの最大数を読み込む
LD $24,FOX_KNOCK_OUT_ID;キツネがノックアウト状態のID(3)
LD $25,FOX_KO_WAIT;キツネがノックアウトから復帰する待ち時間(64)
LD $26,FOX_KO_RESERVE;(&HFF)

PRE IZ,ENEMY_DATA+ENEMY_STRUCTSIZE;妖怪は除く

JUDGE_TF_LOOP:

LDM $9,(IZ+$31),8

;無効なキツネは飛ばす
SBC $9,$31
JR Z,NEXT_JUDGE_TF

;ノックアウト中のキツネは飛ばす
SBC $9,FOX_KNOCK_OUT_ID
JR Z,NEXT_JUDGE_TF

LD $20,$10
LD $21,$11
AD $20,16;ENEMY_X+ENEMY_LENGTH_X
AD $21,16;ENEMY_Y+ENEMY_LENGTH_Y

CAL JUDGE;JUDGE RETURN CODE 0:HIT 1:NO HIT
SBC $29,$31;HIT?
JR NZ,NEXT_JUDGE_TF

;得点を加算
ADW $2,$4

;NORM以外で驚かされたらHOP終了直後に(KO:ノックアウト)に変更するフラグを立てる
SBC $14,$31;NORM?
JR Z,JUDGE_TF_FOXNORM
LD $16,$26;FOX_KO_RESERVE(&HFF)
JR FOX_DROP

JUDGE_TF_FOXNORM:
;キツネがノックアウトから復帰する待ち時間を設定
LD $16,$25
;キツネのIDを3(KO:ノックアウト)に変更する
LD $9,$24;

;鍵のDROP処理
FOX_DROP:
SBC $27,$31;ドロップITEMは出ていない?
JR NZ,NEXT_JUDGE_TF
PRE IX,SLIPPERS_HOLD
SBC (IX+$31),$31;女の子が鍵を保有?
JR NZ,NEXT_JUDGE_TF
;ドロップITEMを所持しているキツネ?
ANC $13,&H80
JR Z,NEXT_JUDGE_TF
;ドロップITEMを未所持に設定、最上位BITが所有フラグ
;(下位4BITはカウンターで使用なので)&H7FでANDする
AN $13,&H7F;
;ドロップITEM出現中に変更
LD $27,$30;DROP FLAG=ON

;鍵の設置場所を決め、X($18),Y($19)に座標を入れる
CAL SET_DROPITEM_POS;IX破壊

PRE IX,NOW_DROP
LD $16,$30;DROP FLAG=ON
;ITEMを落としたキツネのデータのアドレスを保存
GRE IZ,$17
STM $16,(IX+$31),3

NEXT_JUDGE_TF:
STIM $9,(IZ+$31),8

SB $28,$30
JR NZ,JUDGE_TF_LOOP

;SCOREの書き込み
PRE IZ,SCORE

STW $2,(IZ+$31)
;REDRAW FLAG SET
PRE IZ,REDRAW_FLAG
ST $30,(IZ+$31);SCORE REDRAW

RTN

;*********************************
;*         SGPRINT_INIT
;*********************************
SGPRINT_INIT:

LDW $0,0
LDW $2,RIVAL_WALK1_R
CAL SET_SGPRINT_16Y2

LDW $0,1
LDW $2,RIVAL_WALK1_R+16
CAL SET_SGPRINT_16Y2

LDW $0,2
LDW $2,RIVAL_WALK1_L
CAL SET_SGPRINT_16Y2

LDW $0,3
LDW $2,RIVAL_WALK1_L+16
CAL SET_SGPRINT_16Y2

LDW $0,4
LDW $2,RIVAL_WALK2_R
CAL SET_SGPRINT_16Y2

LDW $0,5
LDW $2,RIVAL_WALK2_R+16
CAL SET_SGPRINT_16Y2

LDW $0,6
LDW $2,RIVAL_WALK2_L
CAL SET_SGPRINT_16Y2

LDW $0,7
LDW $2,RIVAL_WALK2_L+16
CAL SET_SGPRINT_16Y2

LDW $0,8
LDW $2,RIVAL_UP_R
CAL SET_SGPRINT_16Y2

LDW $0,9
LDW $2,RIVAL_UP_R+16
CAL SET_SGPRINT_16Y2

LDW $0,10
LDW $2,RIVAL_UP_L
CAL SET_SGPRINT_16Y2

LDW $0,11
LDW $2,RIVAL_UP_L+16
CAL SET_SGPRINT_16Y2

LDW $0,12
LDW $2,RIVAL_FALL_R
CAL SET_SGPRINT_16Y2

LDW $0,13
LDW $2,RIVAL_FALL_R+16
CAL SET_SGPRINT_16Y2

LDW $0,14
LDW $2,RIVAL_FALL_L
CAL SET_SGPRINT_16Y2

LDW $0,15
LDW $2,RIVAL_FALL_L+16
CAL SET_SGPRINT_16Y2

LDW $0,16
LDW $2,FOX_WALK1_R
CAL SET_SGPRINT_16Y2

LDW $0,17
LDW $2,FOX_WALK1_L
CAL SET_SGPRINT_16Y2

LDW $0,18
LDW $2,FOX_WALK2_R
CAL SET_SGPRINT_16Y2

LDW $0,19
LDW $2,FOX_WALK2_L
CAL SET_SGPRINT_16Y2

LDW $0,20
LDW $2,FOX_FALL_R
CAL SET_SGPRINT_16Y2

LDW $0,21
LDW $2,FOX_FALL_L
CAL SET_SGPRINT_16Y2

LDW $0,22
LDW $2,FOX_UP_R
CAL SET_SGPRINT_16Y2

LDW $0,23
LDW $2,FOX_UP_L
CAL SET_SGPRINT_16Y2

LDW $0,24
LDW $2,FOX_KNOCK_OUT
CAL SET_SGPRINT_16Y2

LDW $0,25
LDW $2,BMP_SLIPPERS_L
CAL SET_SGPRINT_DATA

LDW $0,26
LDW $2,BMP_SLIPPERS_R
CAL SET_SGPRINT_DATA

LDW $0,27
LDW $2,BMP_LEFT_ARROW
CAL SET_SGPRINT_DATA

LDW $0,28
LDW $2,BMP_RIGHT_ARROW
CAL SET_SGPRINT_DATA

;LDW $0,29
;LDW $2,CAGE_CLOSE+16
;CAL SET_SGPRINT_16Y2

;LDW $0,30
;LDW $2,CAGE_OPEN
;CAL SET_SGPRINT_16Y2

;LDW $0,31
;LDW $2,CAGE_OPEN+16
;CAL SET_SGPRINT_16Y2

RTN

;*********************************
;*          MOVE ENEMY
;*
;*USE   $0      - 女の子のY座標
;*      $1      - GLOBAL_COUNTER
;*      $9-$16  - ENEMY DATA
;*      $27     - COUNTER(ENEMY_MAX-1)
;*      $27/$28 - MOVE WAIT DATA
;*      $29     - 移動不可フラグ(0:移動可 1:移動不可)
;*********************************
MOVE_ENEMY:

;女の子のY座標を読み込む
PRE IX,MY_Y
LD $1,(IX+$31)

;X方向に移動可フラグを設定
LD $29,$31
PRE IX,ENEMY_MOVE_WAITS
;X回に1回、X方向に移動しないカウントを減算、0でなければ移動可とする
SB (IX+$30),$30
JR NZ,ENEMY_MOVE_PROC
;0になったらカウンタを初期化し、移動不可フラグに変更する
;X方向に移動不可フラグを設定
LD $29,$30
;カウンタの初期化
LD $27,(IX+$31)
ST $27,(IX+$30)

ENEMY_MOVE_PROC:

PRE IX,ENEMY_DATA

;+0:$9-ID
;+1:$10-X
;+2:$11-Y
;+3:$12-DIR
;+4:$13-MOVECNT
;+5:$14-UPFALL
;+6:$15-HOP COUNTER
;+7:$16-ETC

;COUNTER
PRE IZ,ENEMY_MAX_NUM
LD $27,(IZ+$31)
SB $27,$30

MOVE_ENEMY_LOOP:

LDM $9,(IX+$31),8

PHU $27

SBC $9,3
JR Z,ENEMY_FOX_KO
SBC $14,NORM
JR Z,MOVE_ENEMY_WALK
SBC $14,HOP_RET
JP Z,ENEMY_HOP_RET
SBC $14,FALL
JP Z,ENEMY_UP_FALL
SBC $14,UP
JP Z,ENEMY_UP_FALL
JP ENEMY_HOP

NEXT_ENEMY_MOVE:

PPU $27

STIM $9,(IX+$31),8

SB $27,$30
JR NC,MOVE_ENEMY_LOOP
RTN

ENEMY_FOX_KO:
;キツネがノックアウト状態カウンタを減じて、0になったらIDを2にして復帰させる
SB $16,$30
JP NZ,NEXT_ENEMY_MOVE
LD $9,2
JP NEXT_ENEMY_MOVE

MOVE_ENEMY_WALK:
;移動不可フラグが有効であれば移動しない
SBC $29,$30
JR Z,NEXT_ENEMY_MOVE

SBC $12,$31;DIR? 0:RIGHT 1:LEFT
JR Z,ENEMY_MOVE_RIGHT

ENEMY_MOVE_LEFT:
;NORM左移動
;
SB $10,$30
;
ANC $10,&H07;8の倍数でないなら戻る
JP NZ,NEXT_ENEMY_MOVE
;
PHUW $11
SB $10,16
SB $11,8
LD $17,4;左方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,&HE0;ここはHOP_Nするマスか?
JP NZ,NEXT_ENEMY_MOVE

LD $14,HOP_N;HOP_Nに設定
JP NEXT_ENEMY_MOVE

ENEMY_MOVE_RIGHT:
;
AD $10,$30
;
ANC $10,&H07;8の倍数でないなら戻る
JP NZ,NEXT_ENEMY_MOVE
;
PHUW $11
AD $10,16
SB $11,8
LD $17,6;右方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,&HE0;ここはHOP_Nするマスか?
JP NZ,NEXT_ENEMY_MOVE

LD $14,HOP_N;HOP_Nに設定
JP NEXT_ENEMY_MOVE

ENEMY_HOP:
SBC $12,$31;(IX+ENEMY_DIR_IDX),$31
JR NZ,ENEMY_HOP_LEFT
ENEMY_HOP_RIGHT:
AD $10,2
JR END_ENEMY_HOP_X
ENEMY_HOP_LEFT:
SB $10,2
END_ENEMY_HOP_X:
;SBC $0,4
SBC $15,4
JR NC,ENEMY_HOP_DOWN
SB $11,1
JR END_ENEMY_HOP_Y
ENEMY_HOP_DOWN:
AD $11,1
END_ENEMY_HOP_Y:
AD $15,$30
SBC $15,8
JP NZ,NEXT_ENEMY_MOVE
;
LD $15,$31
;
;HOP_NならFALL、HOP_UP中ならNORMに設定
SBC $14,HOP_N;HOP_N
JR Z,SET_ENEMY_FALL
;
SET_ENEMY_NORM:
;キツネがHOP_R時に驚かされていたら、キツネのIDを3(ノックアウト)に変更する
;妖怪なら処理を飛ばす
SBC $9,$30;RIVAL_ID
JR Z,SET_ENEMY_NORM_R
;キツネがHOP_R時に驚かされていたか?($16=HFF?)
SBC $16,&HFF;HOP-UP中に驚かされた
JR NZ,SET_ENEMY_NORM_R
LD $9,FOX_KNOCK_OUT_ID
LD $14,NORM
LD $16,FOX_KO_WAIT
JP NEXT_ENEMY_MOVE

SET_ENEMY_NORM_R:
LD $14,NORM
JP NEXT_ENEMY_MOVE
;
SET_ENEMY_FALL:
LD $14,FALL
JP NEXT_ENEMY_MOVE

END_ENEMY_HOP_NR:

JP NEXT_ENEMY_MOVE

ENEMY_HOP_RET:

SBC $12,$31;RIGHT?
JR Z,ENEMYHOPRET_R
;
ENEMYHOPRET_L:
SBC $15,4
JR NC,ENEMYHOP_RETL4L7
;
ENEMYHOP_RETL0L3:
SB $10,2
SB $11,$30
AD $15,$30
SBC $15,4
JR C,END_ENEMYHOPRETL
LD $12,$31;方向を右に変更する
JR END_ENEMYHOPRETL
;
ENEMYHOP_RETL4L7:
SB $10,2
AD $11,$30
AD $15,$30
SBC $15,8
JR C,END_ENEMYHOPRETL
LD $14,FALL;落下に設定
LD $15,$31
JR END_ENEMYHOPRETL
;
END_ENEMYHOPRETL:
JP NEXT_ENEMY_MOVE

;
ENEMYHOPRET_R:
SBC $15,4
JR NC,ENEMYHOP_RETR4R7
;
ENEMYHOP_RETR0R3:
AD $10,2
SB $11,$30
AD $15,$30
SBC $15,4
JR C,END_ENEMYHOPRETR
LD $12,$30;方向を左に変更する
JR END_ENEMYHOPRETR
;
ENEMYHOP_RETR4R7:
AD $10,2
AD $11,$30
AD $15,$30
SBC $15,8
JR C,END_ENEMYHOPRETR
LD $14,FALL;落下に設定
LD $15,$31
JR END_ENEMYHOPRETR
;
END_ENEMYHOPRETR:
JP NEXT_ENEMY_MOVE

;******************************
;*        ENEMY UP FALL
;******************************

ENEMY_UP_FALL:
;通常(0)及びHOP_N(1),HOP_UP(2),HOP_RET(3)中なら終了
SBC $14,4
JP C,NEXT_ENEMY_MOVE

;FALL中ならY座標を+2する。
ENEMY_FALL_PROC:
SBC $14,FALL
JR NZ,ENEMY_UP_PROC
AD $11,2
;妖怪/きつねを落下→上昇に変更させる処理
PHUW $11
AD $10,8;落下/上昇変更フラグは右側にあるためX+=8する
LD $17,2;下方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,CONTROL_DOWN_UP;落下→上昇のフラグ
JP NZ,NEXT_ENEMY_MOVE
LD $14,UP
JP NEXT_ENEMY_MOVE

ENEMY_UP_PROC:
SB $11,2

;Y座標が8の倍数でなければ戻る
ANC $11,&H07
JP NZ,CK_ENEMY_UPLIMIT

;現在のマスは移動可能なマスか?
;自分の位置をチェック
;CHECK_WALL_HITは現在のマスを調べられない。このため、Y座標は8の倍数のため
;Y座標を-1して一つ上のマスから下のマスをチェックすることで現在のマスの情報を得る
PHUW $11
;ここの2はY座標はメモリを直接減じているので、レジスタは減じられていない。
;そのため、Y座標のレジスタを-1、そして下を見るので-1で計2減らす。
SB $11,1
;
LD $17,2;下方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,&HE0;ここは移動可能なマスか?
JP NZ,CK_ENEMY_UPLIMIT

;女の子と同じY座標なら強制HOPさせる。
SBC $11,$0
JR Z,GIRL_Y_SAME_HOP

;16回に1回強制ホップさせる
AD $13,$30
ANC $13,&H0F
JR NZ,ENEMY_NORMAL_HOP

GIRL_Y_SAME_HOP:
;気まぐれカウンターリセット
;上位4BIT中最上位BITがドロップフラグなのでカウンターを&H80でANDする)
AN $13,&HE0
;
LD $14,HOP_UP;SET HOP_UP
;
PRE IZ,GLOBAL_COUNTER
LD $1,(IZ+$31)
AN $1,$30
JR Z,ENEMY_SET_RIGHT
JR ENEMY_SET_LEFT
;
ENEMY_NORMAL_HOP:
PRE IZ,MY_DATA
LDW $20,(IZ+$31)
SBC $11,$21
JR NZ,CK_ENEMY_UPLIMIT
;
ENEMY_FORCE_HOP:
LD $14,HOP_UP;SET HOP_UP
SBC $10,$20
JR C,ENEMY_SET_RIGHT

ENEMY_SET_LEFT:
;左が壁ならHOP_RETに変更
PHUW $11
SB $10,1
LD $17,4;左方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,&H00;左は移動可能なマスか?
JR Z,ENEMY_LEFT_OK
;壁なのでHOP_RETに変更
LD $14,HOP_RET;SET HOP_RET
;
ENEMY_LEFT_OK:
LD $12,$30;SET DIR LEFT
JP NEXT_ENEMY_MOVE

ENEMY_SET_RIGHT:
;右が壁ならHOP_RETに変更
PHUW $11
AD $10,16
LD $17,6;右方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,&H00;右は移動可能なマスか?
JR Z,ENEMY_RIGHT_OK
;壁なのでHOP_RETに変更
LD $14,HOP_RET;SET HOP_RET
;
ENEMY_RIGHT_OK:
LD $12,$31;SET DIR RIGHT
JP NEXT_ENEMY_MOVE

;上限に達したらFALLに移行
CK_ENEMY_UPLIMIT:
;妖怪/きつねを上昇→落下に変更させる処理
PHUW $11
AD $10,8;落下/上昇変更フラグは右側にあるためX+=8する
SB $11,8;1つ上のマスを見るのでY=-8する
LD $17,8;上方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,CONTROL_UP_DOWN;上昇→落下のフラグ
JP NZ,NEXT_ENEMY_MOVE
LD $14,FALL
JP NEXT_ENEMY_MOVE

;*********************************
;*          DISP ENEMY
;*********************************
DISP_ENEMY:

LD $27,$31

PRE IZ,ENEMY_MAX_NUM
LD $28,(IZ+$31)

DISP_ENEMY_LOOP:

PRE IX,ENEMY_DATA
LDM $0,(IX+$27),8
SBC $0,$31
JR Z,NEXT_DISP_ENEMY

SBC $3,$31;ENEMY_DIR? 0:RIGHT 1:LEFT
JR Z,ENEMY_DIR_RIGHT
LDW $13,256
JR END_ENEMY_DIR_CK
ENEMY_DIR_RIGHT:
LDW $13,0
END_ENEMY_DIR_CK:

PHUW $28

;戻るアドレスを設定
;LDW $20,RTN_DISP_ENEMY-1
;PHSW $21
;
SBC $0,1
JP NZ,DISP_FOX_CK
CAL DISP_RIVAL
JR RTN_DISP_ENEMY
DISP_FOX_CK:
SBC $0,4
JR NC,RTN_DISP_ENEMY
CAL DISP_FOX
;
;JUMPしなかった場合はSSPを戻す。
;PPSW $20

RTN_DISP_ENEMY:
;
PPUW $27

NEXT_DISP_ENEMY:
AD $27,ENEMY_STRUCTSIZE
SB $28,$30
JR NZ,DISP_ENEMY_LOOP
RTN

;****************************
;*      DISP RIVAL
;****************************
DISP_RIVAL:

;オブジェクトのグローバル座標をVIEW座標に変換する
;オブジェクトと女の子のグローバル座標の差分を算出する
PRE IZ,MY_DATA
LDW $10,(IZ+$31)
SB $1,$10
SB $2,$11
;女の子のVIEW座標に差分を加える
CAL CONV_G2V
AD $10,$1
AD $11,$2

AN $11,&HFE

SBC $5,$31;RIVAL NORM?
JR Z,DISP_RIVAL_WALK;NORMなら歩行中の表示
SBC $5,UP
JR Z,DISP_RIVAL_UP;上昇中なら上昇中の表示
;それ以外の表示

;妖怪がHOP中、下降中の表示
LDW $0,SG_CHR_DATA12
ADW $13,$0
JP DISP_SGPRINT16Y2

;妖怪が上昇中の表示
DISP_RIVAL_UP:
LDW $0,SG_CHR_DATA08
ADW $13,$0
JP DISP_SGPRINT16Y2

;妖怪が歩行中の表示
DISP_RIVAL_WALK:
;アニメーションにグローバルカウンターを利用
PRE IZ,GLOBAL_COUNTER
LD $0,(IZ+$31)
AN $0,&H02;歩行アニメーションは2通り及び時間稼ぎのため2でマスキングする
;
JR Z,DISP_RIVAL_WALK2
DISP_RIVAL_WALK1:
LDW $0,SG_CHR_DATA00
ADW $13,$0
JP DISP_SGPRINT16Y2
DISP_RIVAL_WALK2:
LDW $0,SG_CHR_DATA04
ADW $13,$0
JP DISP_SGPRINT16Y2

DISP_SGPRINT16Y2:
LD $12,16;0以外を指定
PHUM $14,5
CAL SGPRINT_FAST
PPUM $10,5
AD $11,8
LDW $4,&H80;128
ADW $13,$4
JP SGPRINT_FAST

;****************************
;*      DISP FOX
;****************************
DISP_FOX:

;妖怪のキャラサイズは16*16では256だが、
;キツネは16*8で128のため、$13,$14を半分にする
;RIGHT:0->0 LEFT:128->64
BIDW $14;

LD $12,16;BMP X-LENGTH

;敵のグローバル座標をVIEW座標に変換する
;敵と女の子のグローバル座標の差分を算出する
PRE IZ,MY_DATA
LDW $10,(IZ+$31)
SB $1,$10
SB $2,$11
;女の子のVIEW座標に差分を加える
CAL CONV_G2V
AD $10,$1
AD $11,$2

AD $11,8
AN $11,&HFE

SBC $0,3;KNOCK OUT?
JR Z,DISP_FOX_KO
SBC $5,$31;FOX NORM?
JR Z,DISP_FOX_WALK;NORMなら歩行中の表示
SBC $5,UP
JR Z,DISP_FOX_UP;上昇中なら上昇中の表示
;それ以外の表示

;FOXがHOP中、下降中の表示
LDW $0,SG_CHR_DATA20
ADW $13,$0
JP SGPRINT_FAST

;FOXが上昇中の表示
DISP_FOX_UP:
LDW $0,SG_CHR_DATA22
ADW $13,$0
JP SGPRINT_FAST

;FOXが歩行中の表示
DISP_FOX_WALK:
;アニメーションにグローバルカウンターを利用
PRE IZ,GLOBAL_COUNTER
LD $0,(IZ+$31)
AN $0,&H02;歩行アニメーションは2通り及び時間稼ぎのため2でマスキングする
JR Z,DISP_FOX_WALK2
DISP_FOX_WALK1:
LDW $0,SG_CHR_DATA16
ADW $13,$0
JP SGPRINT_FAST
DISP_FOX_WALK2:
LDW $0,SG_CHR_DATA18
ADW $13,$0
JP SGPRINT_FAST

DISP_FOX_KO:
LDW $13,SG_CHR_DATA24
JP SGPRINT_FAST

;*********************************
;*       SET_DROPITEM_POS
;*      スリッパの位置を決める
;*
;*RET:  $18 - X
;*      $19 - Y
;*      ITEM_POSにX,Y情報を書き込む
;*
;*USE:
;*      $0
;*      $1
;*      IX
;*********************************
SET_DROPITEM_POS:

PHUW $1

;乱数のINDEXを取得する
PRE IX,RANDOM_INDEX
LD $0,(IX+$31)
;乱数INDEXに1を加える
AD $0,$30
;乱数INDEXを&H1F(31)でマスキングする
AN $0,&H1F
;乱数のINDEXを保存する
ST $0,(IX+$31)

;乱数を取得する
PRE IX,ITEM_RANDOM
LD $1,(IX+$0)

;乱数を2倍する
BIU $1
;

;乱数に対応したスリッパを配置するX,Y座標を得る
PRE IX,ITEM_POS_XY
LDW $18,(IX+$1)

;スリッパの位置情報を保存する
PRE IX,ITEM_POS
STW $18,(IX+$31)

PPUW $0

RTN

ITEM_POS_XY:
DB 40,24
DB 40,48
DB 40,72
DB 40,96
DB 192,24
DB 192,48
DB 192,72
DB 192,96

ITEM_RANDOM:;32POINT
DB 6,3,1,7,0,5,4,2
DB 0,1,5,3,4,2,6,7
DB 1,7,4,6,2,3,5,0
DB 5,1,7,3,4,0,6,2

;*********************************
;*          PUT_MAP_ITEM
;*********************************
PUT_MAP_ITEM:
LDW $0,0
;Y=Y/8
BID $11
BID $11
BID $11
SBC $11,$30
JR C,PUT_MAP_CALC
LDW $0,8*31
SB $11,$30
JR C,PUT_MAP_CALC
LDW $0,8*31*2
SB $11,$30
JR C,PUT_MAP_CALC
LDW $0,8*31*3

PUT_MAP_CALC:
ADW $0,$10
LDW $10,MAP_WORK
ADW $0,$10

PRE IX,$0
ST $12,(IX+$31)
RTN

;*********************************
;*        DISP_RIGHT_SIDE
;*********************************

DISP_RIGHT_SIDE:

PRE IX,REDRAW_FLAG
LDM $0,(IX+$31),3

PHU $2
PHU $1
SBC $0,$30;0=NO REDRAW 1=REDRAW REQUEST
CAL Z,DRAW_SCORE
PPU $1
SBC $1,$30;0=NO REDRAW 1=REDRAW REQUEST
CAL Z,DRAW_REMAIN
PPU $2
SBC $2,$30;0=NO REDRAW 1=REDRAW REQUEST
JR Z,DRAW_LIFE
RTN

;***********************
;*      DRAW_SCORE
;***********************
DRAW_SCORE:
PRE IX,SCORE
LDW $8,(IX+$31)
LD $10,27
LD $11,1
LD $15,&H80;NORM
CAL D_BTOB
RTN

;***********************
;*   DRAW_REMAIN
;***********************
DRAW_REMAIN:
;"ST:"(TEXT)
;LCD2の2行目を消去
LD $2,2
CAL D_CLS_LCD2

;女の子が鍵を保有しているなら残スリッパ数の横に鍵を表示
PRE IX,SLIPPERS_HOLD
SBC (IX+$31),$31
JR Z,NO_KEY_HOLD
LD $10,192-6
LD $11,24
LD $12,8
LDW $13,BMP_SLIPPERS_GS
CAL D_CPRINT

NO_KEY_HOLD:
PRE IX,REMAIN_SLIPPERS
LD $0,(IX+$31)
LD $1,$31

REMAIN_LOOP:
SBC $0,$31
RTN Z
LD $10,144;+18;+18="ST:"(6*3)
AD $10,$1
LD $11,24
LD $12,8
LDW $13,BMP_SLIPPER_MINI
PHUW $1
CAL D_CPRINT
PPUW $0

AD $1,6
SB $0,$30
JR REMAIN_LOOP

;***********************
;*     DRAW_LIFE
;***********************
DRAW_LIFE:
;"LIFE"(BMP)
;LCD2の3行目を消去
LD $2,3
CAL D_CLS_LCD2

PRE IX,MY_LIFE;MY_DATA
LD $0,(IX+$31);MY_LIFE_IDX)
LD $1,$31

LIFE_LOOP:
SBC $0,$31
RTN Z

LD $10,144
AD $10,$1
LD $11,32
LD $12,16
LDW $13,GIRL_NORMRIGHT
PHUW $1
CAL D_CPRINT
PPUW $0

AD $1,16
SB $0,$30
JR LIFE_LOOP

;************************************
;* TRANS_MAP
;*PARA:
;*      $0,$1   MAP_ADRESS
;*USE:
;*      $2,$3   WORK
;*      IX      BUP WORK
;*      IZ      BUP WORK
;*      IY      BUP WORK
;************************************
TRANS_MAP:

;BUP ENDADRESS CALC
LDW $2,&H1FF
ADW $2,$0

PRE IX,$0
PRE IY,$2
PRE IZ,MAP_WORK
BUP

RTN

;************************************
;* CHANGE_MAP_TG
;*
;*マップデータ(TEXT)をグラフィックデータに変換する。
;*変換は2種類のみ
;* &H01～&HFF(指定したBMP)
;* ただし次は制御コードを兼ねる
;* &HE0:ホップさせるフラグ
;* &HE1:上昇→落下のフラグ
;* &HE2:落下→上昇のフラグ
;*
;*PARA
;* $13,$14	MAP(TEXT) ADRESS
;* $15,$16  BMP ADRESS
;*USE
;* IX,IZ	WORK
;* $0,$1	TEXT MAP READ POINTER
;* $2,$3	TEXT MAP READ END ADRESS
;* $4,$5	GRAPHIC MAP STORE POINTER
;* $6		WORK(READ TEXT DATA)
;* $14-$21	BMP DATA
;* $22-$29	WHITE BOX
;************************************

CONTROL_HOP:EQU &HE0
CONTROL_UP_DOWN:EQU &HE1;上昇→落下のフラグ
CONTROL_DOWN_UP:EQU &HE2;落下→上昇のフラグ

N_GROUND:EQU &HA0
N_GROUND_EDGE_R:EQU &HA1
N_GROUND_EDGE_L:EQU &HA2
N_GROUND_JOINT_R:EQU &HA3
N_GROUND_JOINT_L:EQU &HA4

N_WALL_R:EQU &HB0
N_WALL_L:EQU &HB1
;UP SIGNのみ左→右の順
N_UP_SIGN_L:EQU &HB2

N_CEILING:EQU &HC0
N_CEILING_R:EQU &HC1
N_CEILING_L:EQU &HC2

N_FLOOR:EQU &HD0
N_FLOOR_END_R2:EQU &HD2
N_FLOOR_END_R3:EQU &HD3
N_FLOOR_END_R4:EQU &HD4
N_FLOOR_END_L2:EQU &HD5
N_FLOOR_END_L3:EQU &HD6
N_FLOOR_END_L4:EQU &HD7

CHANGE_MAP_TG:

LDW $0,$13	;TEXT MAP READ POINTER
LDW $2,248/8*16;256/8*16
ADW $2,$0	;TEXT MAP READ END ADRESS
LDW $4,SG_CHR_DATA00;GRAPHIC MAP STORE POINTER
PRE IZ,$4

CHANGE_MAP_TG_LP:

;BMP DATAの読み込み
LD $6,($0)
;白
SBC $6,&H00
JP Z,SETMAP_WHITE
;黒
SBC $6,&HFF
JP Z,SETMAP_BLACK

;GROUND
SBC $6,N_GROUND
JR Z,SETMAP_GROUND
SBC $6,N_GROUND_EDGE_R
JR Z,SETMAP_GROUNDE_R
SBC $6,N_GROUND_EDGE_L
JR Z,SETMAP_GROUNDE_L
SBC $6,N_GROUND_JOINT_R
JR Z,SETMAP_GROUNDJ_R
SBC $6,N_GROUND_JOINT_L
JR Z,SETMAP_GROUNDJ_L

;WALL
SBC $6,N_WALL_R
JR Z,SETMAP_WALL_R
SBC $6,N_WALL_L
JR Z,SETMAP_WALL_L

;UP_SIGN
SBC $6,N_UP_SIGN_L
JR Z,SETMAP_UP_SIGN_L
SBC $6,CONTROL_DOWN_UP
JR Z,SETMAP_UP_SIGN_R

;CEILING
SBC $6,N_CEILING
JR Z,SETMAP_CEILING
SBC $6,N_CEILING_R
JR Z,SETMAP_CEILING_R
SBC $6,N_CEILING_L
JR Z,SETMAP_CEILING_L
SBC $6,CONTROL_UP_DOWN
JR Z,SETMAP_CEILING

;FLOOR
SBC $6,N_FLOOR
JR Z,SET_MAP_FLOOR
SBC $6,N_FLOOR_END_R2
JR Z,SETMAP_FLR_ED_R2
SBC $6,N_FLOOR_END_R3
JR Z,SETMAP_FLR_ED_R3
SBC $6,N_FLOOR_END_R4
JR Z,SETMAP_FLR_ED_R4
SBC $6,N_FLOOR_END_L2
JR Z,SETMAP_FLR_ED_L2
SBC $6,N_FLOOR_END_L3
JR Z,SETMAP_FLR_ED_L3
SBC $6,N_FLOOR_END_L4
JR Z,SETMAP_FLR_ED_L4
;---- 制御コードは白で塗りつぶす
JR SETMAP_WHITE

;************************
;* SET BMP ADRESS
;************************

;GROUND
SETMAP_GROUND:
PRE IX,GROUND
JR CHANGE_MAP_TG_ST

SETMAP_GROUNDE_R:
PRE IX,GROUND_END_R
JR CHANGE_MAP_TG_ST

SETMAP_GROUNDE_L:
PRE IX,GROUND_END_L
JR CHANGE_MAP_TG_ST

SETMAP_GROUNDJ_R:
PRE IX,GROUND_JOINT_R
JR CHANGE_MAP_TG_ST

SETMAP_GROUNDJ_L:
PRE IX,GROUND_JOINT_L
JR CHANGE_MAP_TG_ST

;WALL
SETMAP_WALL_R:
PRE IX,WALL_RIGHT
JR CHANGE_MAP_TG_ST

SETMAP_WALL_L:
PRE IX,WALL_LEFT
JR CHANGE_MAP_TG_ST

;UP SIGN
SETMAP_UP_SIGN_L:
PRE IX,UP_SIGN_L
JR CHANGE_MAP_TG_ST
SETMAP_UP_SIGN_R:
PRE IX,UP_SIGN_R
JR CHANGE_MAP_TG_ST

;CEILING
SETMAP_CEILING:
PRE IX,CEILING
JR CHANGE_MAP_TG_ST

SETMAP_CEILING_R:
PRE IX,CEILING_JOINT_R
JR CHANGE_MAP_TG_ST

SETMAP_CEILING_L:
PRE IX,CEILING_JOINT_L
JR CHANGE_MAP_TG_ST

;FLOOR
SET_MAP_FLOOR:
PRE IX,FLOOR
JR CHANGE_MAP_TG_ST
SETMAP_FLR_ED_R2:
PRE IX,FLOOR_END_R2
JR CHANGE_MAP_TG_ST
SETMAP_FLR_ED_R3:
PRE IX,FLOOR_END_R3
JR CHANGE_MAP_TG_ST
SETMAP_FLR_ED_R4:
PRE IX,FLOOR_END_R4
JR CHANGE_MAP_TG_ST
SETMAP_FLR_ED_L2:
PRE IX,FLOOR_END_L2
JR CHANGE_MAP_TG_ST
SETMAP_FLR_ED_L3:
PRE IX,FLOOR_END_L3
JR CHANGE_MAP_TG_ST
SETMAP_FLR_ED_L4:
PRE IX,FLOOR_END_L4
JR CHANGE_MAP_TG_ST

;BLACK
SETMAP_BLACK:
PRE IX,BMP_BLACK
JR CHANGE_MAP_TG_ST

;WHITE
SETMAP_WHITE:
PRE IX,BMP_WHITE
JR CHANGE_MAP_TG_ST

;グラフィックデータを配置
CHANGE_MAP_TG_ST:
LDM $14,(IX+$31),8
STIM $14,(IZ+$31),8
NEXT_MAP_TG:
ADW $0,$30
SBCW $0,$2
JP NZ,CHANGE_MAP_TG_LP

RTN

;************************************
;* DISP_BG
;************************************
DISP_BG:

PRE IX,MY_X
LDW $10,(IX+$31)
LD $12,143;4

JP SBG16_PRINT

;************************************
;*			CONV_G2V
;*
;* 自機を中心として表示範囲をX座標±72、Y座標を±16とした
;*自機のグローバル座標(0,0)-(248,128)をVIEW座標(0,0)-(143,32)に変換する。
;* 自機のX座標が72～176、X座標が24～112ならVIEW座標(72,24)、この範囲以外なら
;*VIEW座標がグローバル座標をはみ出ないVIEW座標を戻り値とする。
;*
;*PARA
;*	$10 	X
;*	$11		Y
;*RET
;*	$10		クライアント座標に変換されたX
;*	$11		クライアント座標に変換されたY
;************************************

CONV_G2V:

;X<72ならそのまま表示
SBC $10,72
JR C,CONV_G2L_Y;DISP_FOXROBO_Y
;X>AREA_X_MAXならX-AREA_X_MAXに表示
SB $10,AREA_X_MAX
JR C,CONV_G2L_XC;DISP_FOXROBO_XC
AD $10,72
JR CONV_G2L_Y;DISP_FOXROBO_Y

;72<X<AREA_X_MAXならX=72
CONV_G2L_XC:;DISP_FOXROBO_XC:
LD $10,72

CONV_G2L_Y:;DISP_FOXROBO_Y:

;Y<16ならそのまま表示
SBC $11,16
RTN C;JR C,END_DISP_FOXROBO
;Y>AREA_Y_MAXならY-AREA_Y_MAXに表示
SB $11,AREA_Y_MAX
JR C,CONV_G2L_YC;DISP_FOXROBO_YC
AD $11,16
RTN;JR END_DISP_FOXROBO

;16<Y<AREA_Y_MAXならY=16
CONV_G2L_YC:;DISP_FOXROBO_YC:
LD $11,16
RTN

;************************************
;* DISP_GIRL
;*USE
;*	$0-$3 ;$0:STATUS $1:DIR $2:WALK COUNT $3 NORM/JUMP/FALL
;*	$2		WORK
;*	$10		X
;*	$11		Y
;*	$13,$14 CHARACTOR ADRESS
;*	IX		MY_X
;*	&GPRINT
;************************************

DISP_GIRL:

PRE IX,MY_DATA
LDW $10,(IX+$31)

SBC (IX+MY_DIR_IDX),$31
JR Z,GIRL_DIR_RIGHT
LDW $13,32
JR END_GIRL_DIR_CK
GIRL_DIR_RIGHT:
LDW $13,0
END_GIRL_DIR_CK:

CAL CONV_G2V

SBC (IX+MY_THREATEN_IDX),$31
JR Z,NO_THREATEN
PHUW $11
PHUW $14

;手をたたいた効果を表示するY座標を女の子のY座標+4にする
AD $11,4

SBC (IX+MY_DIR_IDX),$31
JR Z,RIGHT_THREATEN
LEFT_THREATEN:
SB $10,8
JR DISP_THREATEN
RIGHT_THREATEN:
AD $10,16
DISP_THREATEN:

LD $12,8
LDW $13,BMP_THREATEN
CAL GPRINT256

PPUW $13
PPUW $10

PRE IX,MY_DATA
;キツネを脅かすフラグをOFFにする
ST $31,(IX+MY_THREATEN_IDX)

;女の子が手を叩いた表示
LDW $0,GIRL_CLAP_RIGHT
ADW $13,$0
JP GPRINT1616

NO_THREATEN:
LD $0,(IX+MY_UPFALL_IDX)
SBC $0,$31;GIRL NORM?
JR Z,DISP_GIRL_WS;NORMなら止まっているか歩行中の表示
SBC $0,UP
JR Z,DISP_GIRL_UP;上昇中なら上昇中の表示
;それ以外の表示
DISP_GIRL_EXT_R:
LDW $0,GIRL_JUMP_R_DOWN
ADW $13,$0
JP GPRINT1616

;女の子が上昇中の表示
DISP_GIRL_UP:
LDW $0,GIRL_JUMP_R_UP
ADW $13,$0
JP GPRINT1616

;女の子が停止中又は歩行中の表示
DISP_GIRL_WS:
SBC (IX+MY_STATUS_IDX),$30; 1:WALK
JR Z,DISP_GIRL_WALK
;女の子が停止中の表示
DISP_GIRL_STOP:
LDW $0,GIRL_NORMRIGHT
ADW $13,$0
JP GPRINT1616

;女の子が歩行中の表示
DISP_GIRL_WALK:
;アニメーションにグローバルカウンターを利用
PRE IZ,GLOBAL_COUNTER
LD $0,(IZ+$31)
AN $0,&H02;歩行アニメーションは2通り及び時間稼ぎのため2でマスキングする
JR Z,DISP_GIRL_WALKL2
DISP_GIRL_WALKL1:
LDW $0,GIRL_WALKRIGHT1
ADW $13,$0
JP GPRINT1616
DISP_GIRL_WALKL2:
LDW $0,GIRL_WALKRIGHT2
ADW $13,$0
JP GPRINT1616

GPRINT1616:
LD $12,16
PHUM $14,5
CAL GPRINT256
PPUM $10,5
AD $11,8
LDW $0,16
ADW $13,$0
JP GPRINT256

;******************************
;*             IN_KEY(機種依存)
;*USE:
;*  $0    WORK
;*  $1    KEYスキャン用(IAレジスタ)
;*  $2    KEYスキャン用(KYレジスタ)
;*  $3    IAレジスタ退避用
;*  $10   MY_X
;*  $11   MY_Y
;*  IX    MY_X読み込み用インデックス
;*  IZ    ジャンプ、ステータス用インデックス
;******************************

IN_KEY:

PRE IX,MY_DATA
;女の子がHOP_N中ならHOP_N処理をする
LD $0,HOP_N
SBC (IX+MY_UPFALL_IDX),$0
JP Z,GIRL_HOP
;女の子がHOP_UP中ならHOP_UP処理をする
LD $0,HOP_UP
SBC (IX+MY_UPFALL_IDX),$0
JP Z,GIRL_HOP
;女の子がHOP_RET中ならHOP_RET処理をする
LD $0,HOP_RET
SBC (IX+MY_UPFALL_IDX),$0
JP Z,GIRL_HOP_RET
;女の子がFALL中ならMODEキー以外の入力は無視する
LD $0,3
SBC (IX+MY_UPFALL_IDX),$0
JP Z,GET_MODEKEY

LDW $10,(IX+$31) ;X,Y

;停止中に設定
ST $31,(IX+MY_STATUS_IDX)

;IA退避
GST IA,$3

#if (MODEL = FX870P)
GET_KEY4:
;"4”キー(左)
LD $1,5                  ;5:FX-870P
PST IA,$1
GRE KY,$2
GRE KY,$2
SBC $2,4                ;4:BIT2 FX-870P
JR Z,SUB_LEFT           ;左

GET_KEY6:
;"6”キー(右)
LD $1,7                 ;7:FX-870P
PST IA,$1
GRE KY,$2
GRE KY,$2
SBC $2,$30              ;1:BIT0 FX-870P
JP Z,SUB_RIGHT          ;右
#endif

#if (MODEL = VX3)
GET_KEY4:
;"4”キー(左)
LD $1,5                 ;5:VX3
PST IA,$1
GRE KY,$2
GRE KY,$2
SBC $2,4                ;4:VX3
JR Z,SUB_LEFT           ;左

GET_KEY6:
;"6”キー(右)
LD $1,7                 ;7:VX3
PST IA,$1
GRE KY,$2
GRE KY,$2
SBC $2,$30              ;0:VX3
JP Z,SUB_RIGHT          ;右
#endif

JP END_MOVEKEY

SUB_LEFT:
ST $30,(IX+MY_DIR_IDX);キャラの向きを左に設定
;
;左移動処理判別
LD $0,(IX+MY_UPFALL_IDX)
;NORMであれば通常移動
SBC $0,NORM
JR Z,NORM_LEFT
;UP中でなければ終了、UP中であればレーンに戻る処理
SBC $0,UP
JP NZ,END_MOVEKEY
;
PHUW $11
AD $10,4
SB $11,8
LD $17,4;左方向
CAL CHECK_WALL_HIT
PPUW $10
;既定の位置でキーを押していないのでレーンに復帰しない
SBC $4,&HE0
JP NZ,END_MOVEKEY
ANC $11,&H07
JP NZ,END_MOVEKEY

;レーンに戻るか左の壁にぶつかってジャンプキャンセルか判定
;左方向の壁をチェック
PHUW $11
SB $10,$30
LD $17,4;左方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,$31;左側は空白?
JR Z,LEFT_SIDE_FREE
;
LEFT_SIDE_WALL:
LD $0,HOP_RET
ST $0,(IX+MY_UPFALL_IDX);HOP_RETに設定
JP END_MOVEKEY
;
LEFT_SIDE_FREE:
LD $0,HOP_UP
ST $0,(IX+MY_UPFALL_IDX);UP-HOPに設定
JP END_MOVEKEY

;NORM左移動
NORM_LEFT:
ST $30,(IX+MY_STATUS_IDX);キャラの状態を走行に設定
SB $10,$30
;
ANC $10,&H07;8の倍数でないなら戻る
JP NZ,END_MOVEKEY

;HOP CHECK
PHUW $11
SB $10,16
SB $11,8
LD $17,4;左方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,&HE0;ここはHOP_Nするマスか?
JP NZ,END_MOVEKEY
GIRL_HOP_L:
LD $0,HOP_N
ST $0,(IX+MY_UPFALL_IDX);N-HOPに設定
JP END_MOVEKEY

SUB_RIGHT:
ST $31,(IX+MY_DIR_IDX);キャラの向きを右に設定
;右移動処理判別
LD $0,(IX+MY_UPFALL_IDX)
;NORMであれば通常移動
SBC $0,NORM
JR Z,NORM_RIGHT
;UP中でなければ終了、UP中であればレーンに戻る処理
SBC $0,UP
JP NZ,END_MOVEKEY
;
PHUW $11
AD $10,4
SB $11,8
LD $17,6;右方向
CAL CHECK_WALL_HIT
PPUW $10
;既定の位置でキーを押していないのでレーンに復帰しない
SBC $4,&HE0
JP NZ,END_MOVEKEY
ANC $11,&H07
JP NZ,END_MOVEKEY

;レーンに戻るか右の壁にぶつかってジャンプキャンセルか判定
;右方向の壁をチェック
PHUW $11
AD $10,16
LD $17,6;右方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,$31;右側は空白?
JR Z,RIGHT_SIDE_FREE
;
RIGHT_SIDE_WALL:
LD $0,HOP_RET
ST $0,(IX+MY_UPFALL_IDX);HOP_RETに設定
JR END_MOVEKEY
;
RIGHT_SIDE_FREE:
LD $0,HOP_UP
ST $0,(IX+MY_UPFALL_IDX);UP-HOPに設定
JR END_MOVEKEY

;NORM右移動
NORM_RIGHT:
ST $30,(IX+MY_STATUS_IDX);キャラの状態を走行に設定
AD $10,$30
;
ANC $10,&H07;8の倍数でないなら戻る
JP NZ,END_MOVEKEY

;HOP CHECK
PHUW $11
AD $10,16
SB $11,8
LD $17,6;右方向
CAL CHECK_WALL_HIT
PPUW $10
SBC $4,&HE0;ここはHOP_Nするマスか?
JP NZ,END_MOVEKEY
GIRL_HOP_R:
LD $0,HOP_N
ST $0,(IX+MY_UPFALL_IDX);N-HOPに設定
JP END_MOVEKEY

SUB_JUMP:
JP GET_KEY4

SUB_DOWN:
;JR END_MOVEKEY;------------- DEBUG
AD $11,2
;
SBC $11,MY_Y_MAX
JR C,END_MOVEKEY
LD $11,MY_Y_MAX
JR END_MOVEKEY

END_MOVEKEY:
STW $10,(IX+$31)

;"Q”キー(THREATEN)
#if (MODEL=FX870P)
LD $1,4                 ;4:FX-870P
PST IA,$1
GRE KY,$2
GRE KY,$2
SBC $2,128              ;7:BIT1 FX-870P
JP Z,SUB_THREATEN       ;脅かす
#endif

#if (MODEL = VX3)
LD $1,4                 ;4:VX3
PST IA,$1
GRE KY,$2
GRE KY,$2
SBC $2,128              ;7:VX3
JP Z,SUB_THREATEN       ;脅かす
#endif

;押しっぱなしカウンタを0にする
PRE IX,CONT_THREATEN
ST $31,(IX+$31)

;"MODE”キー(中断)
GET_MODEKEY:
#if (MODEL = FX870P)
LD $1,3                  ;9:FX-870P
PST IA,$1
GRE KY,$2
GRE KY,$2
AN $3,64 ;KY14,15を読み込む場合、BIT8-13まではシステムが使用して値が不明なので必要な部分だけマスキングする
SBC $3,64               ;64:BIT14 FX-870P
JR Z,SUB_MODE
#endif

#if (MODEL = VX3)
LD $1,3                  ;3:VX3
PST IA,$1
GRE KY,$2
GRE KY,$2
AN $3,64 ;KY14,15を読み込む場合、BIT8-13まではシステムが使用して値が不明なので必要な部分だけマスキングする
SBC $3,64               ;14:VX3
JR Z,SUB_MODE
#endif

RTN

;******* "Q" KEY
SUB_THREATEN:

;"Q”キーを4回以上押しっぱなしなら処理を飛ばす
PRE IX,CONT_THREATEN
LD $0,4
SBC (IX+$31),$0
JR NC,GET_MODEKEY

;押しっぱなしカウンタを加算する
AD (IX+$31),$30

PRE IX,MY_DATA

;停止中又は歩行中でなければキツネを脅かせられない
SBC (IX+MY_UPFALL_IDX),$31
RTN NZ

;キツネを脅かすフラグをONにする
ST $30,(IX+MY_THREATEN_IDX)

LDW $10,(IX+$31)

AD $11,4

SBC (IX+MY_DIR_IDX),$31
JR Z,THREATEN_RIGHT
THREATEN_LEFT:
SB $10,8
JR END_THREATEN_X
THREATEN_RIGHT:
AD $10,12
END_THREATEN_X:

;キツネを脅かす位置を保存する
PRE IZ,THREATEN_XY
STW $10,(IZ+$31)

RTN

;******* MODE KEY
SUB_MODE:

PHUW $11
PHUW $13
PHUW $15

LD $10,10
LD $11,1
LD $12,8
LDW $13,MES_PAUSE
LD $15,&H80;NORM
CAL D_TEXT

LD $10,2
LD $11,2
LD $12,20
LDW $13,MES_PUSH_A_KEY
LD $15,&H80;NORM
CAL D_TEXT

PPUW $14
PPUW $12
PPUW $10

BREAK_LOOP:
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JR Z,BREAK_LOOP
LD $3,($15)
SBC $3,&H41  ; "A"キー
RTN Z
SBC $3,&H61  ; "a"キー
RTN Z
JR BREAK_LOOP

GIRL_HOP:
PRE IX,MY_DATA
LD $0,(IX+MY_COUNT_IDX)
LDW $10,(IX+$31)
SBC (IX+MY_DIR_IDX),$31
JR NZ,GIRL_HOP_LEFT
GIRL_HOP_RIGHT:
AD $10,2
JR END_GIRL_HOP_X
GIRL_HOP_LEFT:
SB $10,2
END_GIRL_HOP_X:
SBC $0,4
JR NC,GIRL_HOP_DOWN
SB $11,1
JR END_GIRL_HOP_Y
GIRL_HOP_DOWN:
AD $11,1
END_GIRL_HOP_Y:
AD $0,$30
ST $0,(IX+MY_COUNT_IDX)
SBC $0,8
JP NZ,END_MOVEKEY
ST $31,(IX+MY_COUNT_IDX)

;UP中ならNORM、NORMならFALLに設定
LD $0,HOP_N
SBC (IX+MY_UPFALL_IDX),$0; 1:N-HOP
JR Z,SET_GIRL_FALL
;
SET_GIRL_NORM:
LD $0,NORM
ST $0,(IX+MY_UPFALL_IDX)
SBC (IX+MY_DIR_IDX),$31;DIR RIGHT
JR NZ,GIRL_LEFT_SLIDE
GIRL_RIGHT_SLIDE:
AD $10,2
JP END_MOVEKEY
GIRL_LEFT_SLIDE:
SB $10,2
JP END_MOVEKEY
;
SET_GIRL_FALL:
LD $0,FALL
ST $0,(IX+MY_UPFALL_IDX)
JP END_MOVEKEY

GIRL_HOP_RET:
;
PRE IX,MY_DATA
LDW $10,(IX+$31);X,Y
;
LD $0,(IX+MY_COUNT_IDX)
;
SBC (IX+MY_DIR_IDX),$31;RIGHT?
JR Z,GIRLHOPRET_RIGHT
;
GIRLHOPRET_LEFT:
SBC $0,4
JR NC,GIRLHOP_RET_L4L7
;
GIRLHOP_RET_L0L3:
SB $10,2
SB $11,$30
AD $0,$30
ST $0,(IX+MY_COUNT_IDX)
SBC $0,4
JR C,END_GIRLHOPRET_L
ST $31,(IX+MY_DIR_IDX);方向を右に変更する
JR END_GIRLHOPRET_L
;
GIRLHOP_RET_L4L7:
SB $10,2
AD $11,$30
AD $0,$30
ST $0,(IX+MY_COUNT_IDX)
SBC $0,8
JR C,END_GIRLHOPRET_L
LD $1,FALL
ST $1,(IX+MY_UPFALL_IDX);落下に設定
ST $31,(IX+MY_COUNT_IDX)
JR END_GIRLHOPRET_L
;
END_GIRLHOPRET_L:
STW $10,(IX+$31)
JP END_MOVEKEY

;
GIRLHOPRET_RIGHT:
SBC $0,4
JR NC,GIRLHOP_RET_R4R7
;
GIRLHOP_RET_R0R3:
AD $10,2
SB $11,$30
AD $0,$30
ST $0,(IX+MY_COUNT_IDX)
SBC $0,4
JR C,END_GIRLHOPRET_R
ST $30,(IX+MY_DIR_IDX);方向を左に変更する
JR END_GIRLHOPRET_R
;
GIRLHOP_RET_R4R7:
AD $10,2
AD $11,$30
AD $0,$30
ST $0,(IX+MY_COUNT_IDX)
SBC $0,8
JR C,END_GIRLHOPRET_R
LD $1,FALL
ST $1,(IX+MY_UPFALL_IDX);落下に設定
ST $31,(IX+MY_COUNT_IDX)
JR END_GIRLHOPRET_L
;
END_GIRLHOPRET_R:
STW $10,(IX+$31)
JP END_MOVEKEY

;******************************
;*       IN_KEY_STOP(機種依存)
;*          中断キーのみ判定
;*USE:
;*  $0    WORK
;*  $1    KEYスキャン用(IAレジスタ)
;*  $2    KEYスキャン用(KYレジスタ)
;*  $3    IAレジスタ退避用
;******************************

IN_KEY_STOP:

;IA退避
GST IA,$3

;"MODE”キー(中断)
LD $1,3                  ;9:FX-870P
PST IA,$1
GRE KY,$2
GRE KY,$2
AN $3,64 ;KY14,15を読み込む場合、BIT8-13まではシステムが使用して値が不明なので必要な部分だけマスキングする
SBC $3,64               ;64:BIT14 FX-870P
JP Z,SUB_MODE

RTN

;************************************
;* CALC MAP ADRESS
;*PARA
;* $10	X(MAP座標0-31)
;* $11	Y(MAP座標0-15)
;*USE
;* $0,$1 WORK
;* $2,$3 31(NEXT LINE)
;* IZ
;*RTN:
;* $0 MAP_ADRESS
;************************************

CALC_MAP_ADRESS:

LDW $0,MAP_WORK
LDW $2,31;248/8+1

CALC_MAP_ADR_LP:
SB $11,$30
JR C,END_CALC_MAP_ADR
ADW $0,$2
JR CALC_MAP_ADR_LP

END_CALC_MAP_ADR:

LD $11,$31

ADW $0,$10

RTN

;************************************
;*          CHECK WALL HIT
;*
;*壁に衝突しているか判定する。
;*
;*PARA
;* $10	X(GLOBAL座標0-248)
;* $11	Y(GLOBAL座標8-31)
;* $17  MOVE(2,4,8,6)
;*USE
;* $0,$1 WORK
;* $2,$3 31(NEXT LINE)
;* $4	 RET CODE(&H01-&HFF:WALL HIT)
;* $28 X=0(X MOD 8=0)
;* $29 Y=0(Y MOD 8=0)
;*RTN
;* $4 MAP CODE(&H01-&HFF:WALL HIT)
;************************************

CHECK_WALL_HIT:

PHUW $11

LDW $0,MAP_WORK
LDW $2,31;248/8+1

LD $29,$11;Y座標を保存、後で8の倍数かどうか判定に使用
;$11/8
BID $11
BID $11
BID $11

CHECK_WALL_HITLP:
SB $11,$30
JR C,END_CHECKWALLHIT
ADW $0,$2
JR CHECK_WALL_HITLP

END_CHECKWALLHIT:

LD $28,$10;X座標を保存、後で8の倍数かどうか判定に使用
;$10/8
BID $10
BID $10
BID $10
LD $11,$31

ADW $0,$10
LD $4,($0)

SBC $4,$31
JR NZ,END_WALLHITCHECK;衝突していたのなら2回目の判定をせずに戻る

SBC $17,2;CK_WALL_DOWN
JR Z,CK_WALL_DOWN
SBC $17,8;UP
JR Z,CK_WALL_UP
;左右
ANC $29,&H07;Y座標が8の倍数なら戻る
JR Z,END_WALLHITCHECK
;8の倍数でないなら、下(8DOT下の壁を確認する)
ADW $0,$2
LD $4,($0)
JR END_WALLHITCHECK

CK_WALL_DOWN:
CK_WALL_UP:
;上下
ANC $28,&H07;X座標が8の倍数なら戻る
JR Z,END_WALLHITCHECK
;8の倍数でないなら、右(8DOT下の壁を確認する)
ADW $0,$30
LD $4,($0)

END_WALLHITCHECK:

PPUW $10

RTN

;**********************************
;*          SBG16_PRINT
;*
;*  画面左上(0,0)(GPRINT座標(0,8))に
;*X($10),Y($11)から長さ144のデータを転送する
;*
;*PARA: $10 X
;*		$11 Y
;*WORK:
;*		$0,1
;*      $10,$11 X
;*		$12,$13 Y
;*		$14,$15 LEN(144)
;*      $16,$17 - WORK
;**********************************
SBG16_PRINT:

;パラメータを16BITデータに展開
LD $14,143;144DOT
LD $13,$11;BIDWを使用するため$12ではなく$13に読み込む
;16BIT化したペアレジスタを初期化
LD $11,$31
LD $12,$31
LD $15,$31

SBG16_X_CK:

;X<72?左固定
SBC $10,72
JR NC,SBG16_X_CTR
LD $10,$31
JR SBG16_Y_CK
;X<AREA_X_MAX?スクロール
SBG16_X_CTR:
SBC $10,AREA_X_MAX
JR NC,SBG16_X_RIGHT
SB $10,72;描画位置は自機のX座標-72～+72なので、開始点=X座標-72
JR SBG16_Y_CK
;X>AREA_X_MAX右固定
SBG16_X_RIGHT:
LD $10,AREA_X_MAX
SB $10,72;描画位置は自機のX座標-72～+72なので、開始点=X座標-72

SBG16_Y_CK:

;Y<16?上固定
SBC $13,16
JR NC,SBG16_Y_CTR
;LD $13,16
JR END_SBG_CK
;Y<112?スクロール
SBG16_Y_CTR:
SBC $13,112;Y座標
JR NC,SBG16_Y_BOTTOM
SB $13,16;描画位置は自機のY座標-16～+16なので、開始点=Y座標-16
JR END_SBG_CK
;Y>88下固定
SBG16_Y_BOTTOM:
LD $13,112;Y座標
SB $13,32;16;描画位置は自機のY座標-16～+16なので、開始点=Y座標-16
END_SBG_CK:

;BG画面の転送アドレスを算出
;BG POS Yを8で割る(余りは$12)
BIDW $13
BIDW $13
BIDW $13
;余りを5BITシフトさせて算出
DID $12
BID $12
BID $12;2DOT単位なのでもう一回ビットシフトする

LDW $4,SBG_BMP_XMAX*SBG_DATA_LINEMAX
LDW $0,SBG16_DATA

;余り分シフトさせたSGB16データの格納アドレスを計算する
SBG_BMP_ADR_SH_L:
SBC $12,$31
JR Z,END_SBGBMPADRSHL
ADW $0,$4
SB $12,$30
JR SBG_BMP_ADR_SH_L

;行のアドレス座標を加える
END_SBGBMPADRSHL:
LDW $4,SBG_BMP_XMAX

SBG_BMP_ADR_PO_L:
SBC $13,$31
JR Z,END_SBGBMPADRPOL
ADW $0,$4
SB $13,$30
JR SBG_BMP_ADR_PO_L

END_SBGBMPADRPOL:

;L0
PRE IZ,LEDTP0
ADW $0,$10
PRE IX,$0
LDW $2,$0
ADW $2,$14
PRE IY,$2
BUP
;L1
PRE IZ,LEDTP1
ADW $0,$4
PRE IX,$0
LDW $2,$0
ADW $2,$14
PRE IY,$2
BUP
;L2
PRE IZ,LEDTP2
ADW $0,$4
PRE IX,$0
LDW $2,$0
ADW $2,$14
PRE IY,$2
BUP
;L3
PRE IZ,LEDTP3
ADW $0,$4
PRE IX,$0
LDW $2,$0
ADW $2,$14
PRE IY,$2
BUP

RTN

;**********************************
;*      SET_SBG16_DATA
;*
;*BANK1 &H0000～&H0FFFまでの248*128ドットのグラフィックデータを
;*2ドット単位でSUPER BGデータを作成する
;*
;*WORK:
;*      $2,$3   - ;*
;*      $4,$5   - 書き込みアドレス
;*      $6,$7   - 書き込みアドレスWORK
;*      $8,$9   - キャラシフトワーク
;*      $10     - Xカウンタ(0->&H0100)
;*      $11     - Yカウンタ(0->SGPRINT256MAX)
;*      $15,$16 - &HFF(読み込みアドレスインクリメント用)
;*      $17,$18 - &H200(書き込みアドレスインクリメント用)
;*      IX      - キャラクタの読み込みアドレス
;*      IZ      - キャラクタの書き込みアドレス
;**********************************

SBG_DATA_LINEMAX:EQU 16;8行
SBG_BMP_XMAX:EQU 248
SBG_BMP_NEXTLINE:EQU 248

SET_SBG16_DATA:

;SHIFT0
LD $11,SBG_DATA_LINEMAX
;キャラクタの読み込みアドレス設定
LDW $13,SG_CHR_DATA00;SUPER_GPRINT LIB(&H0000～&H0FFF)
PRE IX,SG_CHR_DATA00
;キャラクタの書き込みアドレスの設定
PRE IZ,SBG16_DATA
MKSBGDATA_LP_YS0:
LD $10,SBG_BMP_XMAX
MKSBGDATALP_S0:
LDI $8,(IX+$31)
LD $0,(IZ+$31)
OR $0,$8
STI $0,(IZ+$31)
SB $10,$30
JR NZ,MKSBGDATALP_S0
SB $11,$30
JR NZ,MKSBGDATA_LP_YS0

;SHIFT2
LD $11,SBG_DATA_LINEMAX-1
;キャラクタの読み込みアドレス設定
PRE IX,$13
;キャラクタの書き込みアドレスの設定
PRE IZ,SBG16_DATA+(SBG_BMP_XMAX*SBG_DATA_LINEMAX)*1

LD $10,SBG_BMP_XMAX
MKSBGDATALP_PS2:
LDI $8,(IX+$31)
LD $0,(IZ+$31)
BIU $8
BIU $8
OR $0,$8
STI $0,(IZ+$31)
SB $10,$30
JR NZ,MKSBGDATALP_PS2

MKSBGDATA_LP_YS2:
LD $10,SBG_BMP_XMAX
MKSBGDATALP_S2:
LDI $8,(IX+$31)
LD $9,$31
LD $0,(IZ+$31)
LD $1,(IZ-SBG_BMP_NEXTLINE)
BIUW $8
BIUW $8
OR $0,$8
OR $1,$9
ST $1,(IZ-SBG_BMP_NEXTLINE)
STI $0,(IZ+$31)
SB $10,$30
JR NZ,MKSBGDATALP_S2
SB $11,$30
JR NZ,MKSBGDATA_LP_YS2

;SHIFT4
LD $11,SBG_DATA_LINEMAX-1
;キャラクタの読み込みアドレス設定
PRE IX,$13
;キャラクタの書き込みアドレスの設定
PRE IZ,SBG16_DATA+(SBG_BMP_XMAX*SBG_DATA_LINEMAX)*2

LD $10,SBG_BMP_XMAX
MKSBGDATALP_PS4:
LDI $8,(IX+$31)
LD $0,(IZ+$31)
BIU $8
BIU $8
BIU $8
BIU $8
OR $0,$8
STI $0,(IZ+$31)
SB $10,$30
JR NZ,MKSBGDATALP_PS4

MKSBGDATA_LP_YS4:
LD $10,SBG_BMP_XMAX
MKSBGDATALP_S4:
LDI $8,(IX+$31)
LD $9,$31
LD $0,(IZ+$31)
LD $1,(IZ-SBG_BMP_NEXTLINE)
BIUW $8
BIUW $8
BIUW $8
BIUW $8
OR $0,$8
OR $1,$9
ST $1,(IZ-SBG_BMP_NEXTLINE)
STI $0,(IZ+$31)
SB $10,$30
JR NZ,MKSBGDATALP_S4
SB $11,$30
JR NZ,MKSBGDATA_LP_YS4

;SHIFT6
LD $11,SBG_DATA_LINEMAX-1
;キャラクタの読み込みアドレス設定
PRE IX,$13
;キャラクタの書き込みアドレスの設定
PRE IZ,SBG16_DATA+(SBG_BMP_XMAX*SBG_DATA_LINEMAX)*3

LD $10,SBG_BMP_XMAX
MKSBGDATALP_PS6:
LDI $8,(IX+$31)
LD $0,(IZ+$31)
BIU $8
BIU $8
BIU $8
BIU $8
BIU $8
BIU $8
OR $0,$8
STI $0,(IZ+$31)
SB $10,$30
JR NZ,MKSBGDATALP_PS6

MKSBGDATA_LP_YS6:
LD $10,SBG_BMP_XMAX
MKSBGDATALP_S6:
LDI $8,(IX+$31)
LD $9,$31
LD $0,(IZ+$31)
LD $1,(IZ-SBG_BMP_NEXTLINE)
BIUW $8
BIUW $8
BIUW $8
BIUW $8
BIUW $8
BIUW $8
OR $0,$8
OR $1,$9
ST $1,(IZ-SBG_BMP_NEXTLINE)
STI $0,(IZ+$31)
SB $10,$30
JR NZ,MKSBGDATALP_S6
SB $11,$30
JR NZ,MKSBGDATA_LP_YS6

RTN

;*********************************
;*              WAIT
;*PARA:$0,$1    - WAIT COUNT
;*********************************
WAIT:
PHUW $1
LDW $28,INKEY
CAL IOCS_CAL
PPUW $0
SBW $0,$30
JR NC,WAIT
RTN

;*********************************
;*       EXIT(DEBUG)
;*********************************
EXIT:
PST UA,&H54 ;**************(機種依存)
RTN

;*****************************
;IOCS_CAL(機種依存)
;PARAMETER
; $28,$29 CALL IOCS ADRESS
;*****************************
IOCS_CAL:
PST UA,&H54
JP IOCS

;*********************************
;*             CLS
;*USE:  $27,$28 IOCS(CLEDB)アドレス
;*********************************
CLS:
LDW $28,CLEDB ;**************(機種依存)
CAL IOCS_CAL
LDW $28,DOTDS
JP IOCS_CAL

;******************************
;*     HIT_ANY_KEY
;******************************
HIT_ANYKEY:
LDW $0,WAIT_TIME_50
CAL WAIT
HIT_ANYKEY_LOOP:
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JR Z,HIT_ANYKEY_LOOP
LDW $0,WAIT_TIME_50
JP WAIT

;******************************
;* DOTDS互換
;******************************
;LCD Parameter
; LCD1:$9 ,$10,$11
; LCD2:$12,$13,$14

@DOTDS:

DISPLCD:
        LD      $9,&H82         ;Select LCD1
        LD      $10,$31         ;Set LCD1 X Address = 0
        LD      $11,$31         ;Set LCD1 Y Address = 0

        LD      $12,&H92        ;Select LCD2
        LD      $13,$31         ;Set LCD2 X Address = 0
        LD      $14,$31         ;Set LCD2 Y Address = 0

;        PRE     IX,LEDTP0V		;Set LEDTP Address

        LDW     $20,LEDTP0
        LDW     $22,LCD_LENGTH
        LD      $8,4            ;Set LCD line( = 4 )

LOOP:
        PRE     IX,$20

        PPO     &HDF            ;Set LCD (Select command register)
        STLM    $9,3            ;Set LCD1 Parameter

        PPO     &HDE            ;Set LCD (Select data ram)
        CAL     DISPL           ;LEDTP --> LCD( 96 byte )

        PPO     &HDF            ;Set LCD (Select command register)
        STLM    $12,3           ;Set LCD2 Parameter

        PPO     &HDE            ;Set LCD (Select data ram)
        CAL     DISPR           ;LEDTP --> LCD( 48 byte )

;        LDD     $0,(IX+8*6)     ;Set IX next line.(IX=IX+56)
								;64->描画開始LCD8(FOREX),56描画開始LCD0(FOXROBO)
        AD      $11,$30         ;X Line +1
        AD      $14,$30         ;Y Line +1

        ADW     $20,$22
        SB      $8,$30          ;finished ?
        JR      NZ,LOOP         ;

        RTN                     ;

;----------------------------------
; INPUT : IX -- LCDTP pointer
;----------------------------------
DISPL:
        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )
DISPR:
        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )
;DISPR:
        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        LDIM    $0,(IX+$31),8   ;Read bit data ( 8byte )
        STLM    $0,8            ;Display LCD ( 8byte )

        RTN

;**************************************
;*              CHECK_RAM
;**************************************
MES_ERROR:DB "MEMORY ERROR"

CHECK_RAM:
PHUW $1
GRE IX,$0
PHUW $1
PRE IX,&H6EC7
LD $0,80
SBC (IX+$31),$0
JR NZ,ERROR_LOOP
PPUW $0
PRE IX,$0
PPUW $0
RTN

PPSW $0
PHSW $1

ERROR_LOOP:

LD $10,0
LD $11,1
LD $12,12
LDW $13,MES_ERROR
CAL D_TEXT

LDW $0,WAIT_TIME_1000
CAL WAIT
CAL HIT_ANYKEY

RTN

#IF (TARGET = RELEASE_MODE)
        #INCLUDE (PROLOGUE.TXT)
        #INCLUDE (DEMO.TXT)
#ENDIF

#INCLUDE (STAGE.TXT)
#INCLUDE (GRAPHIC.TXT)
#INCLUDE (D_GRAPHIC.TXT)
#INCLUDE (RESOURCE.TXT)
#INCLUDE (MENU.TXT)


;************************************
;*              VRAM256
;************************************
;SBG16_BUF->LEDTPのBUPを使うので、LEDTPはSBG16_DATAの前に配置すること
;
;SUPER GPRINTの仕様で、-32<X<0の範囲で描画する場合、LEDTPx-32～LEDTPx-1の
;アドレスに書き込む。この結果、意図しないエリアに不要なデータを書き込み暴走等の不具合が発生する。
;VIRTUAL VRAM256範囲外のメモリにアクセスしないよう、LEDTPxの前32BYTEのバッファを設ける。
;
VRAM_START:
DS 32
LEDTP0:DS 192
DS 32
DS 32
LEDTP1:DS 192
DS 32
DS 32
LEDTP2:DS 192
DS 32
DS 32
LEDTP3:DS 192
DS 32
DS 32;後ろを+64DOTにするために32DOT加える
VRAM_END:

;*************************************
;*      SUPER_BG DATA AREA
;*************************************
SBG16_DATA:DS LCD_LENGTH*4*16;256*4*16=16KB

;*************************************
;*     GPRINTの描画範囲(X)
;*************************************
GPRINT_XMAX:DB 144;GPRINTの描画範囲(0-191)この範囲を超えると描画されない

;*************************************
;*      女の子のデータ
;*************************************
;
;順番の入れ替え禁止
MY_DATA:
MY_X:DB &HC0;232
MY_Y:DB &H48;24
;ここから順番の入れ替え禁止
MY_DIR:DB 1;0			;0:RIGHT 1:LEFT
MY_STATUS:DB 0		;0:STOP 1:RUN
MY_WALKCNT:DB 0		;左右のキーを押すと+1、アニメ用カウンタ
MY_UPFALL:DB 0 	;0:NORM 1:N-HOP 2:UP-HOP 3:RET-HOP 4:FALL 5:UP
;ここまで順番の入れ替え禁止
MY_COUNT:DB 0		;HOPカウンタ
MY_LIFE:DB 0
MY_THREATEN:DB 0	;0:無し 1:手を叩いてキツネを脅かし中
THREATEN_XY:DB 0,0  ;キツネがびっくりする座標(手を叩いた位置)
CONT_THREATEN:DB 0

MY_X_IDX:EQU 		0;X
MY_Y_IDX:EQU 		1;Y
MY_DIR_IDX:EQU 		2;DIR
MY_STATUS_IDX:EQU 	3;STOP/RUN
MY_UPFALL_IDX:EQU	5;UP/FALL
MY_WALKCNT_IDX:EQU	4;
MY_COUNT_IDX:EQU 	6;HOPカウンタ
MY_LIFE_IDX:EQU 	7;LIFE
MY_THREATEN_IDX:EQU 8;手を叩いているかのフラグ

MY_LIFE_MAX:EQU 2

;*************************************
;*      妖怪/きつねのデータ
;*************************************
;ENEMY_DATA:
;DB 0,0,0,0,0,0,0,0;妖怪固定
;DB 0,0,0,0,0,0,0,0;FOX1
;DB 0,0,0,0,0,0,0,0;FOX2
;DB 0,0,0,0,0,0,0,0;FOX3
;DB 0,0,0,0,0,0,0,0;FOX4
;DB 0,0,0,0,0,0,0,0;FOX5
;DB 0,0,0,0,0,0,0,0;FOX6
;DB 0,0,0,0,0,0,0,0;FOX7
;END_ENEMY_DATA:

ENEMY_ID_IDX:EQU        0
ENEMY_X_IDX:EQU 		1
ENEMY_Y_IDX:EQU 		2
ENEMY_DIR_IDX:EQU 		3;0:RIGHT 1:LEFT
ENEMY_MOVCNT_IDX:EQU    4;上位4BIT:DROP ITEM所有/下位4BIT:気まぐれ移動カウンタ
ENEMY_UPFALL_IDX:EQU	5;0:NORM 1:N-HOP 2:UP-HOP 3:RET-HOP 4:FALL 5:UP
ENEMY_COUNT_IDX:EQU 	6;HOPカウンタ
ENEMY_ETC_IDX:EQU       7;ステータス(雑用:64:WAIT &HFF:HOP中に驚かされた)
;
;ENEMY_MOVE_WAITS:EQU RXCNT+R_ENEMY_MOVE_WS;  X回に1回X方向に移動しない設定
;ENEMY_MOVE_WAITN:EQU RXCNT+R_ENEMY_MOVE_WN;  現在の移動カウント
;
ENEMY_STRUCTSIZE:EQU 8
;
;ENEMY_MAX_NUM:DB 0;RIVAL+FOX
;FOX_MAX_NUM:DB 0;FOX

;*************************************
;*      鍵のデータ
;*************************************
;SLIPPERS_HOLD:DB 0;0=NO HOLD

;NOW_DROP:EQU DB 0;RXCNT+R_NOW_DROP;0:DROP FLAG 1,2:DROP FOX DATA ADRESS 3:X(未使用) 4:Y(未使用)
DROP_FOX_ADR_IDX:EQU 1

;ITEM_POS:
;ITEM_X_POS:EQU DB 0
;ITEM_Y_POS:EQU DB 0

;*************************************
;*      残りのスリッパの数
;*************************************
;残りのスリッパの数
;REMAIN_SLIPPERS:DB 0

;*************************************
;*      妖怪が反転する矢印のデータ
;*************************************
ARROW_DATA:
DB 4,080,72,0,0,0,0,0; +07->0:RIGHT 1:LEFT
DB 4,176,48,0,0,0,0,1; +07->0:RIGHT 1:LEFT
;
ARROW1:EQU 0
ARROW2:EQU 8
ARROW_DIR:EQU 7
ARROW_STRUCTSIZE:EQU 8
;
RIVAL_ID:EQU            1
FOX_ID:EQU              2
FOX_KNOCK_OUT_ID:EQU    3
FOX_KO_WAIT:EQU         64
FOX_KO_RESERVE:EQU      &HFF
;
;*************************************
;*              SCOREのデータ
;*************************************
;
;SCORE:DW 0;(2BYTE)
;HIGH_SCORE:DW 0;(2BYTE)
;
SCORE_THREATEN:EQU 10
SCORE_GET_KEY:EQU 50
SCORE_GET_SLIPPR:EQU 100
SCORE_CLEAR_ST:EQU 300
;
;*************************************
;*              STAGE NO
;*************************************
;
;STAGE_NO:DB 0
LAST_STAGE:EQU 5
;
;*************************************
;*           GLOBAL_COUNTER
;*************************************
;
;GLOBAL_COUNTER:DB 0
;
;*************************************
;*           CONTROL FLAG
;*************************************
;READY_START_FLAG:DB 0
;ON_CONTINUE:DB 0;0=NO CONTINUE 1=CONTINUE
;
;REDRAW_FLAG:
;REDRAW_SCORE:DB 0       ;0=NO REDRAW 1=REDRAW REQUEST
;REDRAW_REMAIN:DB 0      ;0=NO REDRAW 1=REDRAW REQUEST
;REDRAW_LIFE:DB 0        ;0=NO REDRAW 1=REDRAW REQUEST
;
;GIRL_CAUGHT:DB 0;0=ON GAME 1=GAIRL WAS CAUGHT

;INVINCIBLE:DB 0;0=女の子のダメージ処理有り OTHER=なし(無敵)

;RANDOM_INDEX:DB 0

;*************************************
;*        PROLOGUE/MENU管理用
;*************************************

;PROLOGUEで使用
;PHASE:DB 0
;PHASE_COUNTER:DB 0
;無敵設定の退避に使用
;SECTION:DB 0;
;SECTION_COUNTER:DB 0
;MENUで使用
;EXTRA:DB 0
;EXTRA_COUNTER:DB 0

