;****************************************
;*  GPRINT_WIDE
;*
;*X(8～192)、Y(8,16,24,32)のキャラを表示する
;*
;*PARA
;*      $10     - X
;*      $11     - Y
;*      $12     - X-LENGTH(8-192)
;*      $13,$14 - CHARACTOR BMP ADRESS
;*      $16     - Y-LENGTH(8,16,24,32)
;****************************************
GPRINT_WIDE:

SBC $16,8
JR Z,GPRINT_WIDE08
SBC $16,16
JR Z,GPRINT_WIDE16
SBC $16,24
JR Z,GPRINT_WIDE24
;SBC $16,32
;JR Z,GPRINT_WIDE32

GPRINT_WIDE32:
CAL GPRINT_WIDE_PROC
GPRINT_WIDE24:
CAL GPRINT_WIDE_PROC
GPRINT_WIDE16:
CAL GPRINT_WIDE_PROC
GPRINT_WIDE08:
;JP GPRINT_WIDE_PROC

GPRINT_WIDE_PROC:
PHUM $15,6
CAL GPRINT
PPUM $10,6

;Y座標を+8
AD $11,8

;BMP開始アドレスを指定されたBMPの長さ分プラスする
LD $17,$12
LD $18,$31

ADW $13,$17

RTN

;****************************************
;*  GPRINT_X16_WIDE
;*
;*X(8～192)、Y(8,16,24,32)のキャラを表示する
;*
;*PARA
;*      $11     - Y
;*      $12     - X-LENGTH(8-192)
;*      $13,$14 - CHARACTOR BMP ADRESS
;*      $16     - Y-LENGTH(8,16,24,32)
;*      $17,$18 - X(16BIT)
;****************************************
GPRINT_X16_WIDE:

SBC $16,8
JR Z,GPRINT_X16_W08
SBC $16,16
JR Z,GPRINT_X16_W16
SBC $16,24
JR Z,GPRINT_X16_W24
;SBC $16,32
;JR Z,GPRINT_X16_W32

GPRINT_X16_W32:
CAL GPRINT_X16W_PROC
GPRINT_X16_W24:
CAL GPRINT_X16W_PROC
GPRINT_X16_W16:
CAL GPRINT_X16W_PROC
GPRINT_X16_W08:
;JP GPRINT_X16W_PROC

GPRINT_X16W_PROC:
PHUM $18,8
CAL GPRINT_X16BIT
PPUM $11,8

;Y座標を+8
AD $11,8

;BMP開始アドレスを指定されたBMPの長さ分プラスする
LD $0,$12
LD $1,$31

ADW $13,$0

RTN

;******************************************
;*           GPRINT_X16BIT
;*
;*&H-7FFF<X<&HFFFFまでの範囲でGPRINTを行う
;*
;*PARA:
;*      $11     - Y
;*      $12     - X_LENGTH
;*      $13,$14 - CHARACTOR ADRESS
;*      $17,$18 - X
;*
;*USE:  $20,$21 - X_LEN(16BIT)
;*      $22,$23 - NEW X_LEN(16BIT)
;*      $24,$25 - &H00C0
;*      $26,$27 - &H8000
;*      $28,$29 - &H80C0
;******************************************
GPRINT_X16BIT:

LDW $24,&H00C0
LDW $26,&H8000
LDW $28,&H80C0

;X<192ならGPRINTで処理する
SBCW $17,$24
JR NC,START_GPRX16BIT
ADW $17,$26
JP GPRX16_LEN_CUT

START_GPRX16BIT:

ADW $26,$17;&H8000

;X>192なら戻る(描画エリアは&H8000～&H80C0)
SBCW $26,$28;&H80C0
RTN NC

;$20,$21でX_LENを16BIT化
LD $21,$31
LD $20,$12

;X+X_LEN<&H8000なら戻る(描画エリアは&H8000～&H80C0)
ADW $20,$26
LDW $26,&H8000
SBCW $20,$26;&H8000
RTN C

;負のX座標を2の補数で正の数にする
CMPW $17

;キャラクタデータの描画開始位置を補正する
ADW $13,$17

;キャラクタデータの長さを補正する
SB $12,$17

;Xの描画位置を&H8000(0)にする
LDW $17,&H8000

GPRX16_LEN_CUT:

;$23,$24でX_LENを16BIT化
LD $23,$12
LD $24,$31

;X_LEN>192(&HC0)なら長さを&H80C0-(X+X_LEN)に変更
ADW $23,$17
SBW $23,$28
JR C,GPRX16BITXLEN_OK
;X_LENを補正する
SB $12,$23

GPRX16BITXLEN_OK:
;補正したX座標を8BIT化する
LD $10,$17

JP GPRINT

;***********************************************************
;*                  TEXT256
;*
;*VRAMの幅が256DOTの仮想VRAMの場合に使用する。
;*
;*PARAMETER
;* $10       キャラのX座標(0-31)
;* $11       キャラのY座標(0-3)
;* $12       キャラの長さ 0:8DOT 1:16DOT
;* $13-$14   キャラのアドレス
;***********************************************************
TEXT256:

;X>32なら戻る
SBC $10,32
RTN NC

;LENGTH>31なら戻る
SBC $12,31
RTN NC

;Xを6倍する
BIU $10;X*2
PHU $10
BIU $10;X*4
PPU $0;X*2
AD $10,$0;(X*4)+(X*2)

;Y座標の開始アドレスを計算する
LDW $4,LEDTP0
LDW $0,256
;Y座標を0-3に制限
AN $11,3
;+256
ANC $11,&H01
JR Z,TEXT_CK512
ADW $4,$0
;+512
TEXT_CK512:
ANC $11,&H02
JR Z,END_TEXT_CK
BIUW $0
ADW $4,$0
END_TEXT_CK:

;開始アドレス=LEDTP+(Y*256)+(X*6)
LD $11,$31;(Xを$10,$11でWORD化)
ADW $4,$10

;読み込むテキストデータ
PRE IX,$13

;IZはFONTが格納されているBANK2に設定、他はBANK1
LD $2,&H95;IZ=B2,IX=B1,SSP/USP=B1,PC=B1
PST UA,$2
PRE IZ,0;FONTの先頭アドレス(BANK2:&H0000," ","!"で始まる)

SB $12,$30

PRE IX,$4

TEXT256_LOOP:
LD $0,($13)
;BANK2 ROMのフォントの先頭(" ")は&H0000
;" "のキャラクターコードは&H20なので、読み込んだキャラクターコードから
;&H20を減じてROMのキャラクターコードと読み込んだキャラクターコードを
;一致させる
SB $0,&H20

LD $1,$31;($0,$1でWORD化)

BIUW $0;*2
PHUW $1
BIUW $0;*4
PPUW $2
ADW $0,$2;*2+*4=*6

PRE IZ,$0
LDM $0,(IZ+$31),6
STIM $0,(IX+$31),6

ADW $13,$30

SB $12,$30
JR NC,TEXT256_LOOP

;BANK1に設定
LD $0,&H55
PST UA,$0
RTN


;************************************************************
;                       GPRINT256
;
;   VRAMの幅が256DOTの場合に使用する。
; 　LCD(0,0)がこのサブルーチンでは(0,8)となる。
;   Y座標は画面外に書き込まない処理を行っている。
;
;   処理は最上段(キャラクタをBYTE SHFIT)と最下段(キャラクタをBYTE SHFIT)、
;   行をまたぐためキャラクタをWORD SHIFTする場合の3つに分けて行っている。
;   また、高速化のためY座標が８の倍数の場合は、キャラのシフトを行わない処理を行っている。
;
; PARAMETER
;  $10       キャラのX座標
;  $11       キャラのY座標
;  $12       キャラの長さ 0:8DOT 1:16DOT
;  $13-$14   キャラのアドレス
;
; WORK
;  $0        カウンタ
;  $1        GPRINT_XMAX読み込み用
;  $15-$16   LEDTPのアドレス（LEDTP0:&H6201、LEDTP1:&H62C1・・）
;  $17-$18   LEDTP+192(LCDをまたぐ際の下段LCDのアドレス）
;  $19-$20   キャラシフト用ワーク
;  $21       レジスタ退避用
;  $22-$23   またぐ場合：2バイト足し算（ADW $R+$22)
;            またがない場合（LCDLINE1）：ワーク
;  $24       OR転送用ワーク
;  IX        CHR ADRESS
;  IZ        BASE LEDTP ADRESS
;************************************************************

GPRINT256:

ANC $11,&H07
JP NZ,GPRINT256_PROC
LD $15,$31;REP=OFF(状況によってはREP指定になるためOFFにする)
JP CPRINT_OR256

GPRINT256_PROC:
;Y軸チェック
;キャラのY座標=0なら描画範囲外なので戻る
SBC $11,$31 ;$31=0
RTN Z

;キャラのY座標>40なら描画範囲外なので戻る
SBC $11,40
RTN NC

;X軸チェック
;キャラのX座標>255-15(X_LEN=16の場合)なら描画処理へ
SBC $10,255-15
JR NC,GPRINT256_DRAW

;キャラのX座標>GPRINT_XMAXなら描画範囲外なので戻る
PRE IX,GPRINT_XMAX
LD $1,(IX+$31)
SBC $10,$1
RTN NC

GPRINT256_DRAW:

;  Y<8ならLINE0のみの描画処理
LINE_0_256:
SBC $11,8
JR NC,LINE01_256
JR DRAW1_256

;  8<Y<16ならLINE0とLINE1のまたぎ描画処理
LINE01_256:
SB $11,8
SBC $11,8
JR NC,LINE12_256
LDW $15,LEDTP0
JP DRAW03_256 ;JRは使用不能

;  16<Y<24ならLINE1とLINE2のまたぎ描画処理
LINE12_256:
SB $11,8
SBC $11,8
JR NC,LINE23_256
LDW $15,LEDTP1
JP DRAW03_256

;  24<Y<32ならLINE2とLINE3のまたぎ描画処理
LINE23_256:
SB $11,8
SBC $11,8
JR NC,LINE4_256
LDW $15,LEDTP2
JR DRAW03_256

;  32<Y<40ならLINE3のみの描画処理
LINE4_256:
SB $11,8
LDW $15,LEDTP3

;************************
;境界をまたがないLCD最下段の描画
;************************
DRAW4_256:

LD $0,$31 ;$31=0 COUNTER=0

PRE IX,$13 ;キャラのアドレス
PRE IZ,LEDTP3

LOOP4_256:
LD $21,$11 ;$11はY-(8*n)の余りあまりなので
;キャラクタを何ビットシフトするのかを決める値

LD $20,(IX+$0) ;$0=COUNTER

   SBC $21,$31
   JR Z,NO_SHIFT4_256

    CHRSHFT4_256:
    BID $20
    SB $21,$30 ;$30=1
    JR NZ,CHRSHFT4_256

NO_SHIFT4_256:
PHU $0
AD $0,$10 ;X座標を追加

LD $24,(IZ+$0)
OR $20,$24;OR転送
ST $20,(IZ+$0)
PPU $0

AD $0,$30 ;$30=1
SBC $0,$12
JR NZ,LOOP4_256
RTN

;************************
;境界をまたがないLCD最上段の描画
;************************
DRAW1_256:
LD $0,$31 ;$31=0 COUNTER=0

PRE IX,$13 ;キャラのアドレス
PRE IZ,LEDTP0

LOOP1_256:
LD $21,$11 ;$11はY-(8*n)の余りあまりなので
;キャラクタを何ビットシフトするのかを決める値

LD $20,(IX+$0) ;$0=COUNTER

;LCDLINE1だけはSHIFTを逆にしているので8から
;SHIFT量を減算して調整する

;また8だとキャラが消えてしまうので8の場合はSHIFT
;はしない
;LD $22,8
;SB $22,$21
;JR Z,N_SHIFT1_256

    CHRSHFT1_256:
    BIU $20
    SB $22,$30 ;$30=1
    JR NZ,CHRSHFT1_256

N_SHIFT1_256:
PHU $0
AD $0,$10 ;X座標を追加

LD $24,(IZ+$0)
OR $20,$24;OR転送
ST $20,(IZ+$0)
PPU $0

AD $0,$30 ;$30=1
SBC $0,$12
JR NZ,LOOP1_256
RTN

;************************
;境界をまたぐ描画
;************************
DRAW03_256:
LD $0,$31 ;$31=0 COUNTER=0
LDW $22,256;&H100

;PRE IX,$13 ;キャラのアドレス
PRE IZ,$15 ;描画するLCDの上段アドレス

LOOP03_256:
LD $21,$11 ;$11はY-(8*n)の余りあまりなので
;キャラクタを何ビットシフトするのかを決める値

PRE IX,$13 ;キャラのアドレス

LD $20,(IX+$0) ;$0=COUNTER
LD $19,$31 ;$31=0 キャラシフトに2バイト使用するので下位ビットをクリアする

    SBC $21,$31
    JR Z,NO_SHIFTE_256

    CHRSHFTE_256:
    BIDW $20
    SB $21,$30 ;$30=1
    JR NZ,CHRSHFTE_256

NO_SHIFTE_256:

;$17に下段のLCDアドレスを設定$15(LCD上段アドレス＋&H100(256)
LDW $17,$15
ADW $17,$22;$22=&H100(256)

PRE IX,$17

PHU $0
AD $0,$10 ;X座標を追加
LD $24,(IZ+$0)
OR $20,$24;OR転送
ST $20,(IZ+$0);上段の描画

LD $24,(IX+$0)
OR $19,$24;OR転送
ST $19,(IX+$0);下段の描画
PPU $0

AD $0,$30 ;$30=1
SBC $0,$12
JR NZ,LOOP03_256
RTN

;*********************************
;*           CPRINT_OR256
;*PARA:
;*      $10     X(0-191)
;*      $11     Y(8の倍数:8,16,24,32,40)
;*      $12     LENGTH(8の倍数以外は動作保証しない)
;*      $13,$14 CHARACTOR ADRESS
;*      $15     LOOP(&HFF=LOOP指定):同じキャラクタを繰り返して表示
;*********************************
CPRINT_OR256:

SB $11,8 ;GPRINT座標系は左上が(0,8)なので、Y座標から8を引き座標系を(0,0)にする

LDW $0,LEDTP0
LDW $2,256
SET_LEDTOPLP_OR:
SB $11,8
JR C,SET_C_PRINT_OR
ADW $0,$2
JR SET_LEDTOPLP_OR

SET_C_PRINT_OR:
LD $11,$31
ADW $0,$10

PRE IX,$0
PRE IZ,$13

SBC $15,&HFF
JR Z,C_PRTOR_LOOP_REP

C_PRINT_OR_LOOP:
LDIM $0,(IZ+$31),8
LDM $20,(IX+$31),8
ORM $20,$0,8
STIM $20,(IX+$31),8
SB $12,8
RTN Z ;SBC $12,$30 ;調整
JR C_PRINT_OR_LOOP

C_PRTOR_LOOP_REP:
LDM $0,(IZ+$31),8
C_PRTOR_LOOPREPL:
LDM $20,(IX+$31),8
ORM $20,$0,8
STIM $20,(IX+$31),8
SB $12,8
RTN Z ;SBC $12,$30 ;調整
JR C_PRTOR_LOOPREPL

;**********************************
;*      SET_SGPRINT_DATA
;*PARA: $0,$1   - NO(0-31)
;*      $2,$3   - CHARACTOR DATA ADRESS(8*8 BITMAP)
;*WORK:
;*      IX      - キャラクタの読み込みアドレス
;*      IZ      - キャラクタの書き込みアドレス
;**********************************

MK_SG_CLR:DB 0,0,0,0,0,0,0,0

SET_SGPRINT_DATA:

PRE IX,MK_SG_CLR
LDM $20,(IX+$31),8

;格納先アドレスの算出。1キャラ128BYTEなのでキャラ番号を128倍する
BIUW $0;2
BIUW $0;4
BIUW $0;8
BIUW $0;16
BIUW $0;32
BIUW $0;64
BIUW $0;128

LDW $4,SG_CHR_DATA00
ADW $0,$4

PHUW $1

;キャラクタの読み込みアドレス設定
PRE IX,$2

;キャラクタの書き込みアドレスの設定
PRE IZ,$0

LD $19,64;下段書き込み用

;0DOT SHIFT
LDM $0,(IX+$31),8
STM $0,(IZ+$31),8       ;上段
STM $20,(IZ+$19),8     ;下段

PPUW $20
LDW $18,8
ADW $20,$18
LDW $22,$20
LDW $18,64
ADW $22,$18

PRE IX,$20;上段書き込み用
PRE IZ,$22;下段書き込み用

;データをレジスタに展開・初期化
LD $15,$7
LD $14,$31
LD $13,$6
LD $12,$31
LD $11,$5
LD $10,$31
LD $9,$4
LD $8,$31
LD $7,$3
LD $6,$31
LD $5,$2
LD $4,$31
LD $3,$1
LD $2,$31
LD $1,$0
LD $0,$31

LD $18,7  ;データ読み込みカウンタ


MSGDATA_LOOP:
BIDW $1
BIDW $3
BIDW $5
BIDW $7
BIDW $9
BIDW $11
BIDW $13
BIDW $15

STI $0,(IZ+$31)
STI $1,(IX+$31)
STI $2,(IZ+$31)
STI $3,(IX+$31)
STI $4,(IZ+$31)
STI $5,(IX+$31)
STI $6,(IZ+$31)
STI $7,(IX+$31)
STI $8,(IZ+$31)
STI $9,(IX+$31)
STI $10,(IZ+$31)
STI $11,(IX+$31)
STI $12,(IZ+$31)
STI $13,(IX+$31)
STI $14,(IZ+$31)
STI $15,(IX+$31)

SB $18,$30
JR NZ,MSGDATA_LOOP
RTN

;**********************************
;*      SET_SGPRINT_16Y2
;*
;* 16*8のSUPER GPRINTのキャラクタを生成する
;*
;*PARA: $0,$1   - NO(0-31)
;*      $2,$3   - CHARACTOR DATA ADRESS(16*8 BITMAP)
;*USE :
;*      $10-$11   CHARACTOR DATA ADRESS(16*8 BITMAP) BACKUP
;*      $16       SHIFT
;*      $18       ワーク/キャラデータ・シフト・カウンタ
;*      $19       下段書き込みワーク(+64)
;*      $20-$27 　下段キャラデータ初期化用ワーク(&H00:8Byte)
;*WORK:
;*      IX      - キャラクタの読み込みアドレス
;*      IZ      - キャラクタの書き込みアドレス
;**********************************

SET_SGPRINT_16Y2:

;キャラクタの格納アドレスの算出。1キャラ128BYTEなのでキャラ番号を128倍する
BIUW $0;2
BIUW $0;4
BIUW $0;8
BIUW $0;16
BIUW $0;32
BIUW $0;64
BIUW $0;128

LDW $4,SG_CHR_DATA00
ADW $0,$4

;キャラクタデータ読み込みアドレス退避
LDW $10,$2

;キャラクタデータ読み込みのアドレス設定
PRE IX,$2
;キャラクタの書き込みアドレスの設定
PRE IZ,$0

LD $16,$31    ;SHIFT量(0,2,4,6)

SBG16Y2_BITS_LP:

LD $17,$31           ;キャラ幅カウンタ

SBG16Y2_SHIFTLP:

LD $1,(IX+$17)     ;キャラデータ読み込み
LD $0,$31           ;キャラデータ下段初期化

SBC $16,0
JR Z,SBG16Y2_BS0
SBC $16,2
JR Z,SBG16Y2_BS2
SBC $16,4
JR Z,SBG16Y2_BS4

SBG16Y2_BS6:
BIDW $1
BIDW $1
SBG16Y2_BS4:
BIDW $1
BIDW $1
SBG16Y2_BS2:
BIDW $1
BIDW $1
SBG16Y2_BS0:

ST $0,(IZ+64) ;キャラデータ下段書き込み
STI $1,(IZ+$31);キャラデータ上段書き込み

AD $17,$30
SBC $17,16
JR NZ,SBG16Y2_SHIFTLP

AD $16,2
SBC $16,8
JR NZ,SBG16Y2_BITS_LP
RTN

;************************************************************
; SGPRINT_FAST
; 　LCD(0,0)がこのサブルーチンでは(0,8)となる。
;   Y座標は画面外に書き込まない処理を行っている。
;   X座標の描画制限を無視したい場合は、このサブルーチン内のSGPRINT_FAST_NCを呼び出すこと。
;   キャラクタ長は8固定でGPRINT_XMAX(定数)を超える部分も描画する。
;
;   処理は最上段(キャラクタをBYTE SHFIT)と最下段(キャラクタをBYTE SHFIT)、
;   行をまたぐためキャラクタをWORD SHIFTする場合の3つに分けて行っている。
;   また、高速化のためY座標が８の倍数の場合は、キャラのシフトを行わない処理を行っている。
;
; PARAMETER
;  $10       キャラのX座標
;  $11       キャラのY座標
;  $12       0:X_LEN=8(1DOT SCROOL) 1:X_LEN=16(2DOT SCROOL)
;  $13-$14   キャラのアドレス
;
; WORK
;  $0        カウンタ
;  $15-$16   LEDTPのアドレス（LEDTP0:&H6201、LEDTP1:&H62C1・・）
;  $17-$18   LEDTP+192(LCDをまたぐ際の下段LCDのアドレス）
;  $19-$20   キャラシフト用ワーク
;  $21       レジスタ退避用
;  $22-$23   またぐ場合：2バイト足し算（ADW $R+$22)
;            またがない場合（LCDLINE1）：ワーク
;  $24,$25   OR転送用ワーク
;  $26,$27   LEDTP設定ワーク
;  IX        CHR ADRESS
;  IZ        BASE LEDTP ADRESS
;************************************************************

SGPRINT_FAST:

#IF(VRAM256_USE=YES)
;X軸チェック
SBC $10,&HFF-32
JR NC,SGPRINT_FAST_NC
#ENDIF

SBC $10,144;D_GPRINT_XMAX
RTN NC

SGPRINT_FAST_NC:

;Y軸チェック

;キャラのY座標=0なら描画範囲外なので戻る
SBC $11,$31 ;$31=0
RTN Z

;キャラのY座標>=40なら描画範囲外なので戻る
SBC $11,40
RTN NC

;  Y<7ならLINE0のみの描画処理
SGF_LINE_0:
SBC $11,8
JR NC,SGF_LINE_0_1
LDW $26,LEDTP0
JR SGF_DRAW1

;  8<Y<15ならLINE0とLINE1のまたぎ描画処理
SGF_LINE_0_1:
SB $11,8
SBC $11,8
JR NC,SGF_LINE_1_2
LDW $26,LEDTP0
JP SGF_DRAW0_3 ;JRは使用不能

;  16<Y<24ならLINE1とLINE2のまたぎ描画処理
SGF_LINE_1_2:
SB $11,8
SBC $11,8
JR NC,SGF_LINE_2_3
LDW $26,LEDTP1
JP SGF_DRAW0_3

;  24<Y<32ならLINE2とLINE3のまたぎ描画処理
SGF_LINE_2_3:
SB $11,8
SBC $11,8
JR NC,SGF_LINE_4
LDW $26,LEDTP2
JR SGF_DRAW0_3

;  32<Y<40ならLINE3のみの描画処理
SGF_LINE_4:
SB $11,8
LDW $26,LEDTP3

;************************
;境界をまたがないLCD最下段の描画
;************************
SGF_DRAW4:

;キャラクターの読み込みアドレスを算出する
CAL SUB_SGPRINT_CALC

;書き込みアドレスの算出
LD $2,$10
LD $3,$31
ADW $26,$2;LEDTPX+X座標
;書き込みアドレスをIZに設定
PRE IZ,$26

JP SGF_DATA_PROC
;RTN

;************************
;境界をまたがないLCD最上段の描画
;************************
SGF_DRAW1:

;キャラクターの読み込みアドレスを算出する
CAL SUB_SGPRINT_CALC

;読み込みキャラクタのアドレスを+64(8BYTE×8キャラ)して下段のキャラに設定
LDW $0,64
ADW $22,$0
;読み込みキャラクタのアドレスをIXに設定
PRE IX,$22

;$0-$7  読み込みキャラクタデータ
;$8-$15 背景データ
;IX     読み込みキャラクタデータ
;IZ     書き込みアドレス

;書き込みアドレスの算出
LD $2,$10
LD $3,$31
ADW $26,$2;LEDTPX+X座標

;書き込みアドレスをIZに設定
PRE IZ,$26

JR SGF_DATA_PROC

;RTN

;************************
;境界をまたぐ描画
;************************
SGF_DRAW0_3:

CAL SUB_SGPRINT_CALC

;読み込みキャラクタ(下段)のアドレスを+64(8BYTE×8キャラ)に設定
LDW $24,$22
LDW $0,64
ADW $24,$0

;書き込みアドレス(上段)の算出
LD $2,$10
SBC $10,LCD_LENGTH-24
JR NC,SGF_LED_MINUS
LD $3,$31
JR SGP_PLUS_MINUS
SGF_LED_MINUS:
LD $3,&HFF

SGP_PLUS_MINUS:
ADW $26,$2;LEDTPX+X座標

;書き込みアドレス(下段)の算出
LDW $28,$26
LDW $0,LCD_LENGTH;NEXT VRAM
ADW $28,$0

;$0-$7  読み込みキャラクタデータ
;$8-$15 背景データ
;IX     読み込みキャラクタデータ
;IZ     書き込みアドレス

;読み込みキャラクタ(上段)のアドレスをIXに設定
PRE IX,$22
;書き込みアドレス(上段)をIZに設定
PRE IZ,$26

;下段のVRAMデータ(上段)を$8-$14に読み込む
PHU $12
CAL SGF_DATA_PROC
PPU $12

;読み込みキャラクタ(下段)のアドレスをIXに設定
PRE IX,$24
;書き込みアドレス(下段)をIZに設定
PRE IZ,$28

JR SGF_DATA_PROC

;RTN

;******************************
;*PARA
;* IX   - CHARACTOR DATA ASRESS
;* IZ   - VRAM ADRESS
;*WORK
;* $0-$7  - CHARACTOR DATA
;* $8-$15 - VRAM DATA
;******************************

SGF_DATA_PROC:
SBC $12,$31
JR NZ,SGF_DATA16_PROC
;キャラクタ(上段)を$0-$7に読み込む
LDIM $0,(IX+$31),8

;VRAMデータ(上段)を$8-$14に読み込む
LDM $8,(IZ+$31),8

;キャラと背景のOR(8BYTE)をとる
ORM $0,$8,8

;VRAMデータ(上段)に書き込む
STIM $0,(IZ+$31),8

RTN

SGF_DATA16_PROC:
;キャラクタ(上段)を$0-$7に読み込む
LDIM $0,(IX+$31),8

;VRAMデータ(上段)を$8-$14に読み込む
LDM $8,(IZ+$31),8

;キャラと背景のOR(8BYTE)をとる
ORM $0,$8,8

;VRAMデータ(上段)に書き込む
STIM $0,(IZ+$31),8

;キャラクタ(上段)を$0-$7に読み込む
LDM $0,(IX+$31),8

;VRAMデータ(上段)を$8-$14に読み込む
LDM $8,(IZ+$31),8

;キャラと背景のOR(8BYTE)をとる
ORM $0,$8,8

;VRAMデータ(上段)に書き込む
STM $0,(IZ+$31),8

RTN

;**********************************
;*PARA
;* $11      - キャラクタのシフト量
;* $13,$14  - キャラクタデータの先頭アドレス
;*USE
;* $0
;* $1
;*RTN
;* IX       - READ CHARACTOR ADRESS
;* $22,$23  - READ CHARACTOR ADRESS
;**********************************

;$22,$23 読み込みキャラクタデータ(上段)
;$24,$25 読み込みキャラクタデータ(下段)(ここでは未使用)
;$26,$27 書き込みアドレス(上段)
;$28,$29 書き込みアドレス(下段)(ここでは未使用)
;IX      読み込みキャラクタデータ
;IZ      書き込みアドレス

SUB_SGPRINT_CALC:
LDW $22,$13
;シフト済みキャラクタの読み込みアドレスの算出
LD $1,$31
LD $0,$11
;シフトする量を8倍する
BIU $0
BIU $0
BIU $0
ADW $22,$0
;読み込みキャラクタのアドレスをIXに設定
PRE IX,$22
RTN

;************************************************************
; GPRINT
; 　LCD(0,0)がこのサブルーチンでは(0,8)となる。
;   Y座標は画面外に書き込まない処理を行っている。
;   X座標についてはGPRINT_XMAX(定数)を超える部分は描画しない処理を行っている。
;   X座標の描画制限を無視したい場合は、このサブルーチン内のGPRINT_NO_CHECKを呼び出すこと。
;
;   処理は最上段(キャラクタをBYTE SHFIT)と最下段(キャラクタをBYTE SHFIT)、
;   行をまたぐためキャラクタをWORD SHIFTする場合の3つに分けて行っている。
;   また、高速化のためY座標が８の倍数の場合は、キャラのシフトを行わない処理を行っている。
;
; PARAMETER
;  $10       キャラのX座標
;  $11       キャラのY座標
;  $12       キャラの長さ
;  $13-$14   キャラのアドレス
;
; WORK
;  $0        カウンタ
;  $1        GPRINT_XMAX読み込み用
;  $15-$16   LEDTPのアドレス（LEDTP0:&H6201、LEDTP1:&H62C1・・）
;  $17-$18   LEDTP+192(LCDをまたぐ際の下段LCDのアドレス）
;  $19-$20   キャラシフト用ワーク
;  $21       レジスタ退避用
;  $22-$23   またぐ場合：2バイト足し算（ADW $R+$22)
;            またがない場合（LCDLINE1）：ワーク
;  $24       OR転送用ワーク
;  IX        CHR ADRESS
;  IZ        BASE LEDTP ADRESS
;************************************************************

GPRINT:

;横幅が0なら戻る
SBC $12,0
RTN Z

;Y軸チェック

;キャラのY座標=0なら描画範囲外なので戻る
SBC $11,$31 ;$31=0
RTN Z

;キャラのY座標>40なら描画範囲外なので戻る
SBC $11,40
RTN NC

;X軸チェック
SBC $10,192;X<192なら次の処理へ
JR C,GPRINT_X_OVER_CK
;X<0の場合で描画可能(X+X_LEN<255)かのチェック
LD $21,$12
AD $12,$10
RTN NC;画面外なので戻る
;調節後の長さが0になら戻る
RTN Z
LD $10,$31
;調節したBMPの長さが元の長さより大きくなったので戻る
SBC $12,$21
RTN NC
;BMP開始アドレスを切り捨てた長さ分加える
LD $15,$12
LD $16,$31
ADW $13,$15

;キャラのX座標>GPRINT_XMAXなら描画範囲外なので戻る
GPRINT_X_OVER_CK:
PRE IX,GPRINT_XMAX
LD $1,(IX+$31)
SBC $10,$1
RTN NC

;キャラのX座標+キャラの長さ>GPRINT_XMAXなら、キャラの長さを調節して
;描画するキャラがGPRINT_XMAXからはみ出ないようにする。
LD $0,$10
AD $0,$12
SBC $0,$1
JR C,LINE_0
LD $12,$1
SB $12,$10 ;キャラの長さ=GPRINT_XMAX-キャラのX座標

GPRINT_NO_CHECK:

;  Y<8ならLINE0のみの描画処理
LINE_0:
SBC $11,8
JR NC,LINE_0_1
JR DRAW1

;  8<Y<16ならLINE0とLINE1のまたぎ描画処理
LINE_0_1:
SB $11,8
SBC $11,8
JR NC,LINE_1_2
LDW $15,LEDTP0
JP Z,LINE_NOSHIFT  ;Y座標が8の倍数(8)の処理
JP DRAW0_3 ;JRは使用不能

;  16<Y<24ならLINE1とLINE2のまたぎ描画処理
LINE_1_2:
SB $11,8
SBC $11,8
JR NC,LINE_2_3
LDW $15,LEDTP1
JP Z,LINE_NOSHIFT  ;Y座標が8の倍数(16)の処理
JP DRAW0_3

;  24<Y<32ならLINE2とLINE3のまたぎ描画処理
LINE_2_3:
SB $11,8
SBC $11,8
JR NC,LINE_4
LDW $15,LEDTP2
JP Z,LINE_NOSHIFT  ;Y座標が8の倍数(24)の処理
JR DRAW0_3

;  32<Y<40ならLINE3のみの描画処理
LINE_4:
SB $11,8
LDW $15,LEDTP3
JP Z,LINE_NOSHIFT  ;Y座標が8の倍数(32)の処理

;************************
;境界をまたがないLCD最下段の描画
;************************
DRAW4:
LD $0,$31 ;$31=0 COUNTER=0

PRE IX,$13 ;キャラのアドレス
PRE IZ,LEDTP3

LOOP4:
LD $21,$11 ;$11はY-(8*n)の余りあまりなので
;キャラクタを何ビットシフトするのかを決める値

LD $20,(IX+$0) ;$0=COUNTER

   SBC $21,$31
   JR Z,NO_SHIFT4

    CHRSHFT4:
    BID $20
    SB $21,$30 ;$30=1
    JR NZ,CHRSHFT4

NO_SHIFT4:
PHU $0
AD $0,$10 ;X座標を追加

LD $24,(IZ+$0)
OR $20,$24;OR転送
ST $20,(IZ+$0)
PPU $0

AD $0,$30 ;$30=1
SBC $0,$12
JR NZ,LOOP4
RTN

;************************
;境界をまたがないLCD最上段の描画
;************************
DRAW1:
LD $0,$31 ;$31=0 COUNTER=0

PRE IX,$13 ;キャラのアドレス
PRE IZ,LEDTP0

LOOP1:
LD $21,$11 ;$11はY-(8*n)の余りあまりなので
;キャラクタを何ビットシフトするのかを決める値

LD $20,(IX+$0) ;$0=COUNTER

;LCDLINE1だけはSHIFTを逆にしているので8から
;SHIFT量を減算して調整する

;また8だとキャラが消えてしまうので8の場合はSHIFT
;はしない
LD $22,8
SB $22,$21
JR Z,N_SHIFT1

    CHRSHFT1:
    BIU $20
    SB $22,$30 ;$30=1
    JR NZ,CHRSHFT1

N_SHIFT1:
PHU $0
AD $0,$10 ;X座標を追加

LD $24,(IZ+$0)
OR $20,$24;OR転送
ST $20,(IZ+$0)
PPU $0

AD $0,$30 ;$30=1
SBC $0,$12
JR NZ,LOOP1
RTN

;************************
;境界をまたぐ描画
;************************
DRAW0_3:
LD $0,$31 ;$31=0 COUNTER=0
LDW $22,LCD_LENGTH

;PRE IX,$13 ;キャラのアドレス
PRE IZ,$15 ;描画するLCDの上段アドレス

LOOP0_3:
LD $21,$11 ;$11はY-(8*n)の余りあまりなので
;キャラクタを何ビットシフトするのかを決める値

PRE IX,$13 ;キャラのアドレス

LD $20,(IX+$0) ;$0=COUNTER
LD $19,$31 ;$31=0 キャラシフトに2バイト使用するので下位ビットをクリアする

    SBC $21,$31
    JR Z,NO_SHIFTE

    CHRSHFTE:
    BIDW $20
    SB $21,$30 ;$30=1
    JR NZ,CHRSHFTE

NO_SHIFTE:

;$17に下段のLCDアドレスを設定$15(LCD上段アドレス＋192
LDW $17,$15
ADW $17,$22;$22=&HC0

PRE IX,$17

PHU $0
AD $0,$10 ;X座標を追加
LD $24,(IZ+$0)
OR $20,$24;OR転送
ST $20,(IZ+$0);上段の描画

LD $24,(IX+$0)
OR $19,$24;OR転送
ST $19,(IX+$0);下段の描画
PPU $0

AD $0,$30 ;$30=1
SBC $0,$12
JR NZ,LOOP0_3
RTN

LINE_NOSHIFT:

LD $11,$31
ADW $15,$10

SET_CPRINT_OR:

PRE IX,$15
PRE IZ,$13

C_PRINTLOOP_OR:
SB $12,$30
RTN C
LD $0,(IZ+$12)
LD $1,(IX+$12)
OR $0,$1
ST $0,(IX+$12)
JR C_PRINTLOOP_OR

;*********************************
;*           CPRINT
;*PARA:
;*      $10     X(0-191)
;*      $11     Y(8の倍数:8,16,24,32,40)
;*      $12     LENGTH(8の倍数以外は動作保証しない)
;*      $13,$14 CHARACTOR ADRESS
;*      $15     LOOP(&HFF=LOOP指定):同じキャラクタを繰り返して表示
;*********************************
CPRINT:

AN $12,&HF8
RTN Z

SB $11,8 ;GPRINT座標系は左上が(0,8)なので、Y座標から8を引き座標系を(0,0)にする

LDW $0,LEDTP0
LDW $2,LCD_LENGTH
SET_LEDTOPLOOP:
SB $11,8
JR C,SET_CPRINT
ADW $0,$2
JR SET_LEDTOPLOOP

SET_CPRINT:
LD $11,$31
ADW $0,$10

PRE IX,$0
PRE IZ,$13

SBC $15,&HFF
JR Z,C_PRINTLOOP_REP

C_PRINTLOOP:
LDIM $0,(IZ+$31),8
STIM $0,(IX+$31),8
SB $12,8
RTN Z ;SBC $12,$30 ;調整
JR C_PRINTLOOP

C_PRINTLOOP_REP:
LDM $0,(IZ+$31),8
C_PRINTLOOP_REPL:
STIM $0,(IX+$31),8
SB $12,8
RTN Z ;SBC $12,$30 ;調整
JR C_PRINTLOOP_REPL
