

;*******************************************
;*			     MENU
;*******************************************

MES_MENU:DB "MENU(Q:EXIT 8:UP 2:DOWN 4/6:SEL)"
MES_HIGH_SC_CLR:DB "HIGH-SCORE CLEAR"
MES_EXIT_GAME:DB "EXIT GAME"
MES_YN:DB  "(Y/N)"
MES_SEE_YOU:DB "See You"

;DEBUG
MES_INVINCIBLE:DB "INVINCIBLE:"
MES_ON:DB   "ON "
MES_OFF:DB  "OFF"

MES_ALLOW:DB ">"

MES_DB_LENGTH:EQU 17
MES_DB_X:EQU 2
MES_DB_SET_X:EQU 17+2+1

MENU1_CUR_YMAX:EQU 3
MENU2_CUR_YMAX:EQU 2

MENU:

;タイトル画面で使用する以下のレジスタを退避する
;$27:HIT SPC KEY!の描画/非描画のフラグ
;MENU EXITでPPUする
PHU $27

;PAGE/CURSOR POS初期化
PRE IX,EXTRA
LDW $0,0
STW $0,(IX+$31)

MENU_MAIN:

;*****************************
;*      MENU-PAGE1
;*****************************
MENU_PAGE1:

;ページ1設定
PRE IX,EXTRA
ST $31,(IX+$31)
;カーソル位置初期化
ST $30,(IX+$30)

MENU_PAGE1_LOOP:

CAL CLS

LD $10,$31
LD $11,$31
LD $12,32
LDW $13,MES_MENU
CAL D_TEXT

;HI-SCORE CLEAR
LD $10,MES_DB_X
LD $11,$30
LD $12,16
LDW $13,MES_HIGH_SC_CLR
CAL D_TEXT

;EXIT GAME
LD $10,MES_DB_X
LD $11,2
LD $12,9
LDW $13,MES_EXIT_GAME
CAL D_TEXT

ARROW_DISP_1:

LD $10,$31
PRE IX,EXTRA_COUNTER
LD $11,(IX+$31)
LD $12,1
LDW $13,MES_ALLOW
CAL D_TEXT

LDW $0,WAIT_TIME_100
CAL WAIT

;****** MENU1 SELECT *****

MENU1_WAIT_LP:
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JR Z,MENU1_WAIT_LP

LD $3,($15)
SBC $3,&H38;8
JP Z,M_CURSOR_UP
SBC $3,&H32;2
JP Z,M_CURSOR_DOWN
SBC $3,&H34;4
JR Z,M1_CURSOR_LEFT
SBC $3,&H36;6
JR Z,M1_CURSOR_RIGHT
SBC $3,&H51;Q
JP Z,MENU_EXIT
SBC $3,&H71;q
JP Z,MENU_EXIT
SBC $3,&H44;D
JP Z,MENU_PAGE2
SBC $3,&H64;d
JP Z,MENU_PAGE2

LDW $0,WAIT_TIME_100
CAL WAIT

JR MENU1_WAIT_LP

NEXT_MENU1_LOOP:

JP MENU1_WAIT_LP

;****** MENU1 SELECT *****
M1_CURSOR_LEFT:
LD $1,&HFF;-1
JR M1_MODE_CHANGE

M1_CURSOR_RIGHT:
LD $1,$30;1

M1_MODE_CHANGE:
PRE IX,EXTRA_COUNTER
LD $0,(IX+$31)

;SELECT CONTRAST/HI-SCORE CLR/END_GAME
SBC $0,$30
JR Z,M1_HIGH_SC_CLR
JR M1_END_GAME

;*****************************
;*     HIGH_SCORE_CLR
;*****************************
M1_HIGH_SC_CLR:
;
CAL CLS
;
LD $10,8
LD $11,1
LD $12,16
LDW $13,MES_HIGH_SC_CLR
CAL D_TEXT

LD $10,13
LD $11,2
LD $12,5
LDW $13,MES_YN
CAL D_TEXT

;DISP MES HI-SCORE
LD $10,8
LD $11,3
LD $12,12
LDW $13,MES_NOWHISCORE
LDW $15,&H80;NORM
CAL D_TEXT

;NOW HI-SCORE DISP
PRE IX,HIGH_SCORE
LDW $8,(IX+$31)
LD $10,19
LD $11,3
CAL D_BTOB

HI_SC_CLR_LP:
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JR Z,HI_SC_CLR_LP

LD $0,($15)
SBC $0,&H59;Y
JR Z,HI_CLR
SBC $0,&H79;y
JR Z,HI_CLR
SBC $0,&H4E;N
JR Z,END_HI_SCORE_CLR
SBC $0,&H6E;n
JR Z,END_HI_SCORE_CLR
JR HI_SC_CLR_LP

HI_CLR:
PRE IX,HIGH_SCORE
LDW $0,0
STW $0,(IX+$31)

END_HI_SCORE_CLR:
;
CAL CLS
;
JP MENU_PAGE1_LOOP

;*******************************************
;*			     END_GAME
;*******************************************
M1_END_GAME:
;
CAL CLS
;
LD $10,12
LD $11,1
LD $12,9
LDW $13,MES_EXIT_GAME
CAL D_TEXT

LD $10,14
LD $11,2
LD $12,5
LDW $13,MES_YN
CAL D_TEXT

EXIT_GAME_LOOP:
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JR Z,EXIT_GAME_LOOP

LD $0,($15)
SBC $0,&H59;Y
JR Z,EXIT_GAME_PROC
SBC $0,&H79;y
JR Z,EXIT_GAME_PROC
SBC $0,&H4E;N
JR Z,END_EXIT_GAME
SBC $0,&H6E;n
JR Z,END_EXIT_GAME
JR EXIT_GAME_LOOP

EXIT_GAME_PROC:
;
PPUW $0;スタック解放
;
CAL CLS
;
LD $10,13
LD $11,1
LD $12,7
LDW $13,MES_SEE_YOU
;LD $15,&H80
CAL D_TEXT
;
JP EXIT

END_EXIT_GAME:
;
JP MENU_PAGE1_LOOP


;*****************************
;*      MENU-PAGE2
;*****************************

MENU_PAGE2:

;ページ2設定
PRE IX,EXTRA
ST $30,(IX+$31)
;カーソル位置初期化
ST $30,(IX+$30)

MENU_PAGE2_LOOP:

CAL CLS

LD $10,$31
LD $11,$31
LD $12,32
LDW $13,MES_MENU
CAL D_TEXT

;MES_INVINCIBLE
LD $10,MES_DB_X
LD $11,$30
LD $12,11
LDW $13,MES_INVINCIBLE
CAL D_TEXT

;NOW INVINCIBLE SETTING DISP
LDW $13,MES_OFF
PRE IX,INVINCIBLE
SBC (IX+$31),$31;INVINCIBLE OFF?
JR Z,MENU_INVIN_OFF
LDW $13,MES_ON
MENU_INVIN_OFF:
LD $10,2+11
LD $11,$30
LD $12,3
CAL D_TEXT

JR ARROW_DISP_2

ARROW_DISP_2:

LD $10,$31
PRE IX,EXTRA_COUNTER
LD $11,(IX+$31)
LD $12,1
LDW $13,MES_ALLOW
CAL D_TEXT

LDW $0,WAIT_TIME_100
CAL WAIT

;****** MENU2 SELECT *****

MENU2_WAIT_LP:
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JR Z,MENU2_WAIT_LP

LD $3,($15)
SBC $3,&H38;8
JR Z,M_CURSOR_UP
SBC $3,&H32;2
JR Z,M_CURSOR_DOWN
SBC $3,&H34;4
JR Z,M2_CURSOR_LEFT
SBC $3,&H36;6
JR Z,M2_CURSOR_RIGHT
SBC $3,&H51;Q
JP Z,MENU_EXIT
SBC $3,&H71;q
JP Z,MENU_EXIT
SBC $3,&H44;D
JP Z,MENU_PAGE1
SBC $3,&H64;d
JP Z,MENU_PAGE1

LDW $0,WAIT_TIME_100
CAL WAIT

JR MENU2_WAIT_LP

NEXT_MENU2_LOOP:

JP MENU2_WAIT_LP

;****** MENU2 SELECT *****
M2_CURSOR_LEFT:
LD $1,&HFF;-1
JR M2_MODE_CHANGE

M2_CURSOR_RIGHT:
LD $1,$30;1

M2_MODE_CHANGE:
PRE IX,EXTRA
LD $0,(IX+$30);ARROW Y

;SELECT INVINCIBLE OFF/ON
SBC $0,1
JR Z,M2_INVINCIBLE
JR M2_INVINCIBLE

;*****************************
;*    M2_INVINCIBLE
;*****************************
M2_INVINCIBLE:

LDW $0,WAIT_TIME_100
CAL WAIT

PRE IX,INVINCIBLE
LD $0,(IX+$31)
INV $0
ST $0,(IX+$31)
JP MENU_PAGE2_LOOP

;*************************************
;*      CURSOR UP/DOWN
;*************************************

M_CURSOR_UP:
PRE IX,EXTRA
SBC (IX+$30),$30
JR Z,RET_MENU
SB (IX+$30),$30
JR RET_MENU

M_CURSOR_DOWN:
PRE IX,EXTRA
LD $0,(IX+$30);CURSOR POS(EXTRA COUNTER)
AD $0,$30
LD $1,MENU1_CUR_YMAX
SBC (IX+$31),$31;PAGE1?
JR Z,MENU1_CUR_DOWN
LD $1,MENU2_CUR_YMAX
MENU1_CUR_DOWN:
SBC $0,$1
JR NC,RET_MENU
ST $0,(IX+$30)
RET_MENU:
SBC (IX+$31),$31
JP Z,MENU_PAGE1_LOOP
JP MENU_PAGE2_LOOP

;*************************************
;*      MENU EXIT
;*************************************

MENU_EXIT:

PPU $27
CAL CLS

;TITLE再描画
LD $0,$30;全指定(TITLE,女の子,ライバル)
CAL DISP_TITLE

JP TITLE_LOOP

