MES_DEMO:DB "DEMO"

DEMO_INIT:

;STAGE_NO SET
#if (TEST_MODE=ON)
        #if (TEST_STAGE=1)
        CAL SET_STAGE2_DATA
        #endif
        #if (TEST_STAGE=2)
        CAL SET_STAGE4_DATA
        #endif
        #if (TEST_STAGE=3)
        CAL SET_STAGE5_DATA
        #endif
#else
CAL SET_STAGE2_DATA
#endif

DEMO_LOOP:
CAL REDRAW_FLAG_OFF
;
;無敵カウンターを減じる
CAL CHECK_MUTEKI
;
;INSERT OBJECT DATA POINTER初期化
PRE IX,INSERT_OBJ_PT
ST $31,(IX+$31)

PRE IX,GLOBAL_COUNTER
LD $0,(IX+$31)
AN $0,$30 ;1
JR Z,DEMO_NO_BG_SCROL
;
CAL BG_SCROLL
;----- $28:EVENT NO(0:NOTHING &HFF:END=BOSS/EXIT)
SBC $28,&HFF
JP Z,BOSS_MAIN
;
DEMO_NO_BG_SCROL:
CAL INS_ENEMY
PRE IX,ENEMY_MOVE_ADR
LDW $28,(IX+$31)
CAL CAL_REG28
;

CAL MOVE_GUN

;GAME OVER CHECK
PRE IX,GAME_OVER_FLAG
SBC (IX+$31),$31
JR Z,DEMO_CONTINUE
;GAME OVER時の余韻の処理
PRE IX,EXTRA_COUNTER
SB (IX+$31),$30
;****************************
;*   DEMO通常終了(撃破される)
;****************************
JP Z,END_DEMO
DEMO_CONTINUE:

CAL INSERT_OBJECT_ON
CAL JUDGE
;
LDW $28,INKEY
CAL IOCS_CAL
SBC $17,$31
JR Z,DEMO_DISP_SEC
;
;****************************
;*      SPCキーでDEMO終了
;*      ON_DEMO=2に設定
;****************************
LD $3,($15)
SBC $3,&H20
JP NZ,DEMO_DISP_SEC
PRE IX,ON_DEMO
LD $0,2
ST $0,(IX+$31)
JP END_DEMO
;
;********* DEMO DISPLAY ROUTINE SECTION START
DEMO_DISP_SEC:
;
CAL TRANS_MAP
;
CAL DISP_SPARK
;CAL ENEMY_DISP
PRE IX,ENEMY_DISP_ADR
LDW $28,(IX+$31)
CAL CAL_REG28
;
CAL DISP_FIGHTER
CAL DISP_GUN
CAL DISP_OPTION

CAL ITEM_PROC;この処理はREDRAW_CHECKの前に行う
CAL REDRAW_CHECK
CAL DISP_ALERT
;CAL READY_START_DISP

;*************************
;*      DISPLAY
;*      "DEMO"
;*  "PUSH SPC KEY!"
;*************************
PRE IX,GLOBAL_COUNTER
LD $0,(IX+$31)
AN $0,&H20
JR NZ,END_DEMO_INFO

LD $10,11
LD $11,1
LD $12,4
LDW $13,MES_DEMO
CAL TEXT

LD $10,7
LD $11,2
LD $12,12
LDW $13,MES_PUSH_SPC
CAL TEXT

END_DEMO_INFO:

;********* DISPLAY ROUTINE SECTION END

CAL @DOTDS

PRE IX,GLOBAL_COUNTER
AD (IX+$31),$30

JP DEMO_LOOP
