;***************************************************
;*         GRAPHIC LIBRALY(NORMAL系)
;*
;*(1)CLS
;*(2)GPRINT
;*(3)GPRINT_WIDE(X(8～192)、Y(8,16,24,32)のキャラを表示する)
;*(4)GPRINT_X16BIT(Xを16BIT化してX<0でも正しくGPRINT表示を行う。)
;*(5)SGPRINT(FX-870P専用)BANK1(&H0000～&H1000)の空きメモリにシフト展開済みのキャラクタを転送する
;*(6)SGPRINT_FAST:(3)の高速版、キャラクタ長は8固定、X方向の描画制限以上にも書き込む
;*(7)SGPRINT_4:(3)の幅4高さ2のビットマップデータへ特化。Y軸は偶数しか移動できない。VRAMまたぎをしないので超高速。弾に使用を想定
;*(8)SET_SGPRINT_DATA:FX-870Pの&H0480～&H0FFFまでに1ドットごとシフトしたキャラデータを展開する(最大23個)上段:基準アドレス～+63BYTE,下段:64BYTE～128BYTE
;*(9)CPRINT(X:0-191),(Y:8,16,24,32)指定でキャラクタを通常転送する。同じキャラの繰り返し描画機能あり
;*(10)CPRINT_OR(X:0-191),(Y:8,16,24,32)指定でキャラクタをOR転送する。同じキャラの繰り返し描画機能あり
;*(11)CPRINT_FILL(指定した範囲を指定したPTNでAND,OR,XORする)(Y:8,16,24,32)
;*(12)TEXT;FX-870P専用
;*(13)PSET
;*(14)LINE      ;妖怪ビルディングまで使用していたLINE命令
;*(15)LINE_NEW  ;FX-890Pから移植したLINE命令、PSETのたびにPUSH,POPしない。($7以外のレジスタ,IX,IZを破壊)
;*(16)BTOB(2BYTEの2進数を10進数に変換表示:0～65535)
;*(17)BTOB256(2進数を10進数に変換表示:0～255)
;*(18)R2D(2次元回転)
;*(19)GET_BMP_PIXCEL(BMPの(X,Y)座標のデータの有無を調べる)
;*(20)CROSS_Y_ANS_X(指定した直線が指定したYで交わる時のX座標を算出する)
;*(21)ROTATE_BMP(ビットマップを回転させる:Y<0で暴走はしないが反応しなくなるので注意)
;*(22)PAINT_SQUARE(四角形の塗りつぶし:画面外に描画すると暴走はしないが反応しなくなるので注意)
;*(23)CONTRAST_CHANGE(画面の輝度を変更する)
;*(24)LINE_HORIZON8(横位置が8の倍数の位置間で線を引く)
;***************************************************

;*********************************
;*           BIN TO BCD
;*
;*D_BTOBより破壊レジスタが多いので注意(IZ,$0～$11)
;*
;*PARAMETER
;* $8,$9    BINARY DATA
;* $10      X
;* $11      Y
;*USE
;* $0~$11   サブルーチンTEXTで使用
;* $20      BCD CHR
;* $21,$22  10000,1000,100,10,1
;* $23      NUMBER OF DIGIT COUNTER
;* IZ       PUT BCD START ADRESS(EDTOP)
;**********************************
BTOB_ANS:DB 0,0,0,0,0

BTOB:

LD $23,$31

PRE IZ,BTOB_ANS

LDW $21,10000
CAL CONV
LDW $21,1000
CAL CONV
LDW $21,100
CAL CONV
LDW $21,10
CAL CONV
LDW $21,$30
CAL CONV

LD $12,5
LDW $13,BTOB_ANS
CAL TEXT

RTN

CONV:
LD $20,&H30 ;CHR CODE "0"

LPCNV:
SBCW $8,$21
JP C,CONVE
SBW $8,$21
AD $20,$30
JP LPCNV

CONVE:
ST $20,(IZ+$23)
AD $23,$30
RTN

;*********************************
;*            BIN TO BCD(256)
;*
;* D_BTOB256より破壊レジスタが多いので注意(IZ,$0～$11)
;*
;*PARAMETER
;* $9       BINARY DATA
;* $10      X
;* $11      Y
;*USE
;* $0~$11   サブルーチンTEXTで使用
;* $20      BCD CHR
;* $21,$22  10000,1000,100,10,1
;* $23      NUMBER OF DIGIT COUNTER
;* IZ       PUT BCD START ADRESS(EDTOP)
;**********************************
BTOB256_ANS:DB 0,0,0

BTOB256:

LD $23,$31

PRE IZ,BTOB256_ANS

LDW $21,100
CAL CONV256
LDW $21,10
CAL CONV256
LDW $21,$30
CAL CONV256

LD $12,3
LDW $13,BTOB256_ANS
CAL TEXT

RTN

CONV256:
LD $20,&H30 ;CHR CODE "0"

LPCNV256:
SBC $9,$21
JP C,CONVE256
SB $9,$21
AD $20,$30
JP LPCNV256

CONVE256:
ST $20,(IZ+$23)
AD $23,$30
RTN

;**************************************************
;*              CONTRAST_CHANGE
;*
;*FX-870P/VX-4のコントラストを変更する
;*
;*動作原理：
;*$3,$4に0D2E(薄い)～0D6C(濃い)(+2STEP)をパラメータとし、
;*IOCS(&H0183)をコールする
;*
;*参考データ
;*薄い
;*CONTRAST DATA ADRESS(BANK0)   CONTRAST DATA
;*0D2E　　　                     0A10
;*0D30                          4810
;*0D32                          8011
;*0D34                          4020
;* ～
;*0D6A                          0078
;*0D6C                          7FFF
;*濃い
;*
;*PARA:
;*  $0      -   濃度(0～31):ハードは0～64で2の倍数
;*USE:
;*  $1      -   $0と組み合わせてWORDとして使用
;*  $3,$4   -   濃度
;*  $28,$29 -   IOCSコール番地
;*　注意:IOCS(&H0183)の破壊レジスタは不明なので未記載
;*
;**************************************************

#IF (MODEL=VX3)
ELVAD:EQU &H610B
#ENDIF

#if (MODEL=FX870P)|(MODEL=VX4)
ELVAD:EQU &H110B
#ENDIF

CONTRAST_CHANGE:

;濃度指定が31を超えていたら戻る
SBC $0,32
RTN NC

main:

main1:  ldw     $3,&H0D2E        ;begin of the contrast table

BIU $0
LD $1,$31

main2:
adw     $3,$0
cal     contr
RTN

 ; set the contrast to the value from table &H0D2E, pointed to by $3,$4
; (equivalent to the ROM subroutine at address &H0183)
contr:  ppo     &HC3
        gst     ua,$0
        pst     ua,&H45
        ldw     $1,($3)
        pst     ua,$0
        ld      $0,$sx
        sbc     $3,&H56
        jr      nc,cont1
        didm    $2,3
cont1:  or      $0,&H0C
        stlm    $0,3
        rtn

RESTORE_CONTRAST:
pre     ix,ELVAD        ;ELVAD, pointer to the contrast data
ldw     $3,(ix+$sx)
JP     contr


;****************************************
;*  GPRINT_WIDE
;*
;*X(8～192)、Y(8,16,24,32)のキャラを表示する
;*
;*PARA
;*      $10     - X
;*      $11     - Y
;*      $12     - X-LENGTH(8-192)
;*      $13,$14 - CHARACTOR BMP ADRESS
;*      $16     - Y-LENGTH(8,16,24,32)
;****************************************
GPRINT_WIDE:

SBC $16,8
JR Z,GPRINT_WIDE08
SBC $16,16
JR Z,GPRINT_WIDE16
SBC $16,24
JR Z,GPRINT_WIDE24
;SBC $16,32
;JR Z,GPRINT_WIDE32

GPRINT_WIDE32:
CAL GPRINT_WIDE_PROC
GPRINT_WIDE24:
CAL GPRINT_WIDE_PROC
GPRINT_WIDE16:
CAL GPRINT_WIDE_PROC
GPRINT_WIDE08:
;JP GPRINT_WIDE_PROC

GPRINT_WIDE_PROC:
PHUM $15,6
CAL GPRINT
PPUM $10,6

;Y座標を+8
AD $11,8

;BMP開始アドレスを指定されたBMPの長さ分プラスする
LD $17,$12
LD $18,$31

ADW $13,$17

RTN

;******************************************
;*           GPRINT_X16BIT
;*
;*&H-7FFF<X<&HFFFFまでの範囲でGPRINTを行う
;*
;*PARA:
;*      $11     - Y
;*      $12     - X_LENGTH
;*      $13,$14 - CHARACTOR ADRESS
;*      $17,$18 - X
;*
;*USE:  $20,$21 - X_LEN(16BIT)
;*      $22,$23 - NEW X_LEN(16BIT)
;*      $24,$25 - &H00C0
;*      $26,$27 - &H8000
;*      $28,$29 - &H80C0
;******************************************
GPRINT_X16BIT:

LDW $24,&H00C0
LDW $26,&H8000
LDW $28,&H80C0

;X<192ならGPRINTで処理する
SBCW $17,$24
JR NC,START_GPRX16BIT
ADW $17,$26
JP GPRX16_LEN_CUT

START_GPRX16BIT:

ADW $26,$17;&H8000

;X>192なら戻る(描画エリアは&H8000～&H80C0)
SBCW $26,$28;&H80C0
RTN NC

;$20,$21でX_LENを16BIT化
LD $21,$31
LD $20,$12

;X+X_LEN<&H8000なら戻る(描画エリアは&H8000～&H80C0)
ADW $20,$26
LDW $26,&H8000
SBCW $20,$26;&H8000
RTN C

;負のX座標を2の補数で正の数にする
CMPW $17

;キャラクタデータの描画開始位置を補正する
ADW $13,$17

;キャラクタデータの長さを補正する
SB $12,$17

;Xの描画位置を&H8000(0)にする
LDW $17,&H8000

GPRX16_LEN_CUT:

;$23,$24でX_LENを16BIT化
LD $23,$12
LD $24,$31

;X_LEN>192(&HC0)なら長さを&H80C0-(X+X_LEN)に変更
ADW $23,$17
SBW $23,$28
JR C,GPRX16BITXLEN_OK
;X_LENを補正する
SB $12,$23

GPRX16BITXLEN_OK:
;補正したX座標を8BIT化する
LD $10,$17

JP GPRINT



;************************************************************
;*                   SET_GPRINT_OR
;*
;*　GPRINTをOR転送モードに設定する
;*
;*USE:
;*      $0～$2
;*      IX
;************************************************************

SET_GPRINT_OR:

;OR $20,$24 PATCH
PRE IX,GPRINT_OR2024
LDM $0,(IX+$31),3
PRE IX,GPRINT_OR2024_00
STM $0,(IX+$31),3
PRE IX,GPRINT_OR2024_01
STM $0,(IX+$31),3
PRE IX,GPRINT_OR2024_02
STM $0,(IX+$31),3

;OR $19,$24
PRE IX,GPRINT_OR1924
LDM $0,(IX+$31),3
PRE IX,GPRINT_OR1924_00
STM $0,(IX+$31),3

;OR $0,$1
PRE IX,GPRINT_OR0001
LDM $0,(IX+$31),3
PRE IX,GPRINT_OR0001_00
STM $0,(IX+$31),3

;LD $19,0
PRE IX,GPRINT_OR_INIT
LDM $0,(IX+$31),3
PRE IX,GPRINT_ORAN_19
STM $0,(IX+$31),3

RTN

;************************************************************
;*                   SET_GPRINT_AN
;*
;*　GPRINTをAND転送モードに設定する
;*
;*USE:
;*      $0～$2
;*      IX
;************************************************************

SET_GPRINT_AN:

;AN $20,$24 PATCH
PRE IX,GPRINT_AN2024
LDM $0,(IX+$31),3
PRE IX,GPRINT_OR2024_00
STM $0,(IX+$31),3
PRE IX,GPRINT_OR2024_01
STM $0,(IX+$31),3
PRE IX,GPRINT_OR2024_02
STM $0,(IX+$31),3

;AN $19,$24
PRE IX,GPRINT_AN1924
LDM $0,(IX+$31),3
PRE IX,GPRINT_OR1924_00
STM $0,(IX+$31),3

;AN $0,$1
PRE IX,GPRINT_AN0001
LDM $0,(IX+$31),3
PRE IX,GPRINT_OR0001_00
STM $0,(IX+$31),3

;LD $19,&HFF
PRE IX,GPRINT_AN_INIT
LDM $0,(IX+$31),3
PRE IX,GPRINT_ORAN_19
STM $0,(IX+$31),3

RTN

;************************************************************
;*                           GPRINT
;*
;*   LCD(0,0)がこのサブルーチンでは(0,8)となる。
;*   OR転送(デフォルト)とAND転送が可能、転送方法の変更はSET_GPRINT_OR/ANDをコール
;*   Y座標は画面外に書き込まない処理を行っている。
;*   X座標についてはGPRINT_XMAX(定数)を超える部分は描画しない処理を行っている。
;*   X座標の描画制限を無視したい場合は、このサブルーチン内のGPRINT_NO_CHECKを呼び出すこと。
;*   処理は最上段(キャラクタをBYTE SHFIT)と最下段(キャラクタをBYTE SHFIT)、
;*   行をまたぐためキャラクタをWORD SHIFTする場合の3つに分けて行っている。
;*   また、高速化のためY座標が８の倍数の場合は、キャラのシフトを行わない処理を行っている。
;*
;* PARAMETER
;*  $10       キャラのX座標
;*  $11       キャラのY座標
;*  $12       キャラの長さ
;*  $13-$14   キャラのアドレス
;* WORK
;*  $0        カウンタ
;*  $1        GPRINT_XMAX読み込み用
;*  $15-$16   LEDTPのアドレス（LEDTP0:&H6201、LEDTP1:&H62C1・・）
;*  $17-$18   LEDTP+192(LCDをまたぐ際の下段LCDのアドレス）
;*  $19-$20   キャラシフト用ワーク
;*  $21       レジスタ退避用
;*  $22-$23   またぐ場合：2バイト足し算（ADW $R+$22)
;*            またがない場合（LCDLINE1）：ワーク
;*  $24       OR転送用ワーク
;*  IX        CHR ADRESS
;*  IZ        BASE LEDTP ADRESS
;************************************************************

GPRINT_OR2024:OR $20,$24
GPRINT_OR1924:OR $19,$24
GPRINT_OR0001:OR $0,$1
GPRINT_AN2024:AN $20,$24
GPRINT_AN1924:AN $19,$24
GPRINT_AN0001:AN $0,$1

GPRINT_OR_INIT:LD $19,0
GPRINT_AN_INIT:LD $19,&HFF

GPRINT:

;横幅が0なら戻る
SBC $12,0
RTN Z

;Y軸チェック

;キャラのY座標=0なら描画範囲外なので戻る
SBC $11,$31 ;$31=0
RTN Z

;キャラのY座標>40なら描画範囲外なので戻る
SBC $11,40
RTN NC

;X軸チェック
;キャラのX座標>GPRINT_XMAXなら描画範囲外なので戻る
PRE IX,GPRINT_XMAX
LD $1,(IX+$31)
SBC $10,$1
RTN NC

;キャラのX座標+キャラの長さ>GPRINT_XMAXなら、キャラの長さを調節して
;描画するキャラがGPRINT_XMAXからはみ出ないようにする。
GPRINT_XLEN_CK:
LD $0,$10
AD $0,$12
SBC $0,$1
JR C,LINE_0
LD $12,$1
SB $12,$10 ;キャラの長さ=GPRINT_XMAX-キャラのX座標

GPRINT_NO_CHECK:

;  Y<8ならLINE0のみの描画処理
LINE_0:
SBC $11,8
JR NC,LINE_0_1
JR DRAW1

;  8<Y<16ならLINE0とLINE1のまたぎ描画処理
LINE_0_1:
SB $11,8
SBC $11,8
JR NC,LINE_1_2
LDW $15,LEDTP0
JP Z,LINE_NOSHIFT  ;Y座標が8の倍数(8)の処理
JP DRAW0_3 ;JRは使用不能

;  16<Y<24ならLINE1とLINE2のまたぎ描画処理
LINE_1_2:
SB $11,8
SBC $11,8
JR NC,LINE_2_3
LDW $15,LEDTP1
JP Z,LINE_NOSHIFT  ;Y座標が8の倍数(16)の処理
JP DRAW0_3

;  24<Y<32ならLINE2とLINE3のまたぎ描画処理
LINE_2_3:
SB $11,8
SBC $11,8
JR NC,LINE_4
LDW $15,LEDTP2
JP Z,LINE_NOSHIFT  ;Y座標が8の倍数(24)の処理
JR DRAW0_3

;  32<Y<40ならLINE3のみの描画処理
LINE_4:
SB $11,8
LDW $15,LEDTP3
JP Z,LINE_NOSHIFT  ;Y座標が8の倍数(32)の処理

;************************
;境界をまたがないLCD最下段の描画
;************************
DRAW4:
LD $0,$31 ;$31=0 COUNTER=0

PRE IX,$13 ;キャラのアドレス
PRE IZ,LEDTP3

LOOP4:
LD $21,$11 ;$11はY-(8*n)の余りあまりなので
;キャラクタを何ビットシフトするのかを決める値

LD $20,(IX+$0) ;$0=COUNTER

   SBC $21,$31
   JR Z,NO_SHIFT4

    CHRSHFT4:
    BID $20
    SB $21,$30 ;$30=1
    JR NZ,CHRSHFT4

NO_SHIFT4:
PHU $0
AD $0,$10 ;X座標を追加

LD $24,(IZ+$0)
GPRINT_OR2024_00:
OR $20,$24;DB 0,0,0;"OR $20,$24" OR "AN $20,$24"
ST $20,(IZ+$0)
PPU $0

AD $0,$30 ;$30=1
SBC $0,$12
JR NZ,LOOP4
RTN

;************************
;境界をまたがないLCD最上段の描画
;************************
DRAW1:
LD $0,$31 ;$31=0 COUNTER=0

PRE IX,$13 ;キャラのアドレス
PRE IZ,LEDTP0

LOOP1:
LD $21,$11 ;$11はY-(8*n)の余りあまりなので
;キャラクタを何ビットシフトするのかを決める値

LD $20,(IX+$0) ;$0=COUNTER

;LCDLINE1だけはSHIFTを逆にしているので8から
;SHIFT量を減算して調整する

;また8だとキャラが消えてしまうので8の場合はSHIFT
;はしない
LD $22,8
SB $22,$21
JR Z,N_SHIFT1

    CHRSHFT1:
    BIU $20
    SB $22,$30 ;$30=1
    JR NZ,CHRSHFT1

N_SHIFT1:
PHU $0
AD $0,$10 ;X座標を追加

LD $24,(IZ+$0)
GPRINT_OR2024_01:
OR $20,$24;DB 0,0,0;"OR $20,$24" OR "AN $20,$24"
ST $20,(IZ+$0)
PPU $0

AD $0,$30 ;$30=1
SBC $0,$12
JR NZ,LOOP1
RTN

;************************
;境界をまたぐ描画
;************************
DRAW0_3:
LD $0,$31 ;$31=0 COUNTER=0
LDW $22,&HC0

;PRE IX,$13 ;キャラのアドレス
PRE IZ,$15 ;描画するLCDの上段アドレス

LOOP0_3:
LD $21,$11 ;$11はY-(8*n)の余りあまりなので
;キャラクタを何ビットシフトするのかを決める値

PRE IX,$13 ;キャラのアドレス

LD $20,(IX+$0) ;$0=COUNTER

GPRINT_ORAN_19:
;キャラシフトに2バイト使用するので下位ビットをクリアする
;OR転送の場合は0、AND転送の場合は&HFFで初期化する
LD $19,&H00
;
    SBC $21,$31
    JR Z,NO_SHIFTE

    CHRSHFTE:
    BIDW $20
    SB $21,$30 ;$30=1
    JR NZ,CHRSHFTE

NO_SHIFTE:

;$17に下段のLCDアドレスを設定$15(LCD上段アドレス＋192
LDW $17,$15
ADW $17,$22;$22=&HC0

PRE IX,$17

PHU $0
AD $0,$10 ;X座標を追加
LD $24,(IZ+$0)
GPRINT_OR2024_02:
OR $20,$24;DB 0,0,0;"OR $20,$24" OR "AN $20,$24"
ST $20,(IZ+$0);上段の描画

LD $24,(IX+$0)
GPRINT_OR1924_00:
OR $19,$24;DB 0,0,0;"OR $19,$24" OR "AN $19,$24"
ST $19,(IX+$0);下段の描画
PPU $0

AD $0,$30 ;$30=1
SBC $0,$12
JR NZ,LOOP0_3
RTN

LINE_NOSHIFT:

LD $11,$31
ADW $15,$10

SET_CPRINT_OR:

PRE IX,$15
PRE IZ,$13

C_PRINTLOOP_OR:
SB $12,$30
RTN C
LD $0,(IZ+$12)
LD $1,(IX+$12)
GPRINT_OR0001_00:
OR $0,$1;DB 0,0,0;"OR $0,$1" OR "AN $0,$1"
ST $0,(IX+$12)
JR C_PRINTLOOP_OR

;------------------------------------------------------------
; DRAW
; 機能 : X1,Y1からX2,Y2へMODE情報に従ってビットラインを引く
; 入力 :
; $10 = MODE ( Bit0= 1:PSET、 0:PRESET、Bit7= 1:LCDへ出力 )
; $11 = Y2 , $12 = X2
; $13 = Y1 , $14 = X1
; 利用レジスタ : $0 ～ $17 , IX
;------------------------------------------------------------
DRAW:
	CAL	PARAMD		;始点/終点/X,Y増分を求める
	CAL	MAKEADR		;始点のLEDTPアドレスを求める

;--------------------------------
; 傾き(ドット単位の増加値)作成
; $8  = Y増分、$9  = X増分
; 出力 $1,$0 = 傾き(単位：1/256)
;  $6 = 傾き端数(単位：1/65536)
;--------------------------------
	SBC	$9,$8		;X増分 < Y増分?
	JR	C,YCAL		; Yes --> Y軸で判定

	LDW	$4,$8,CALD	;傾き=Y増分/X増分
YCAL:
	LD	$4,$9		;傾き=X増分/Y増分
	LD	$5,$8		;
CALD:	PHU	$5		;
	CAL	DIVB		;$1,$0=傾き(1/256)
	PPU	$5		;

	PHUW	$1		;傾きを保存
	LD	$4,$3		;余りをもう一度割る
	CAL	DIVB		;
	LDW	$6,$0		;$6=傾き(1/65536) ,$7=0
	PPUW	$0		;$1,$0=傾き(1/256)

;--------------------------------
; 描画情報初期化
;--------------------------------
DRAWINIT:
;	LD	$7,$31		;余り繰り込みワーク初期化($7=0)
	LDW	$2,&H80		;増分データ初期化(=0.5)

	SBC	$9,$8		;X増分 < Y増分?
	JR	C,YDRAW		; Yes --> Y基軸描画

;--------------------------------
; X基軸描画
; IX --- LEDTPアドレス
; $15 = Y始点、$16 = X始点
; $13 = Y終点、$14 = X終点
; $11 = PSETデータ
; $9  = X増分
;--------------------------------
XDRAW:
	AD	$9,$30		;X増分+1
XDRAWL:
	CAL	MKDRAW		;DRAWデータ作成($4=描画データ)
	STI	$4,(IX+$31)	;ドット描画(IX=IX+1)

	SB	$9,$30		;描画終了?
	RTN	Z		; Yes

	CAL	INCVEC		;傾きデータ更新
	JR	Z,XDRAWL	;Y位置に変更無しなら、次の描画へ

	SBC	$13,$15		;Yは増加する?
	JR	C,XDRAWD	; No

	BID	$11		;描画データ更新(Y増加)
	JR	NC,XDRAWL	;アドレス更新要求なし

	LDD	$5,(IX+192)	;IX=IX+192
	ROD	$11,XDRAWL	;描画データ初期化(=&H80)
XDRAWD:
	BIU	$11		;描画データ更新(Y減少)
	JR	NC,XDRAWL	;アドレス更新要求なし

	LDD	$5,(IX-192)	;IX=IX-192
	LD	$11,$30,XDRAWL	;描画データ初期化(=&H01)

;--------------------------------
; Y基軸描画
; IX --- LEDTPアドレス
; $15 = Y始点、$16 = X始点
; $13 = Y終点、$14 = X終点
; $11 = PSETデータ
; $8  = Y増分
;--------------------------------
YDRAW:
	AD	$8,$30		;Y増分+1
YDRAWL:
	CAL	MKDRAW		;DRAWデータ作成($4=描画データ)
	STD	$4,(IX+$31)	;ドット描画(IX=変化しない)

	SB	$8,$30		;描画終了?
	RTN	Z		; Yes

	BID	$11		;描画データ更新(Y増加)
	JR	NC,YDRAW10	;アドレス更新要求なし

	ROD	$11		;描画データ初期化(=&H80)
	LDD	$5,(IX+192)	;アドレス更新IX=IX+192
YDRAW10:
	CAL	INCVEC		;傾きデータ更新
	JR	Z,YDRAWL	;X位置に変更無しなら、次の描画へ

	SBC	$14,$16		;Xは増加する?
	JR	C,YDRAWD	; No

	LDD	$5,(IX+$30)	;IX=IX+1
	JR	YDRAWL		;
YDRAWD:
	LDD	$5,(IX-$30)	;IX=IX-1
	JR	YDRAWL		;

;------------------------------------------------------------
; 始点、終点、増分を決定
; 入力 :
; $11 = Y2 , $12 = X2
; $13 = Y1 , $14 = X1
; 出力
; $15 = Y始点、$16 = X始点
; $13 = Y終点、$14 = X終点
; $8  = Y増分、$9  = X増分
;------------------------------------------------------------
PARAMD:
	LDM	$0,$11,4	;Y2,X2,Y1,X1を$0～$3へコピー
	LDW	$15,$0		;取り合えず、始点 Y2,X2、終点Y1,X1とする

	SB	$1,$3		;X2 > X1?
	JR	NC,YCHK		; No -->Yチェック
	CMP	$1		;X差分($1)を正数に戻す。
YCHK:
	SB	$0,$2		;Y2 > Y1?
	JR	NC,SCHK		; No -->増分チェック
	CMP	$0		;Y差分($0)を正数に戻す。
SCHK:
	LDW	$8,$0		;Y、X増分($8,$9)格納
	SBC	$9,$8		;X増分 >= Y増分
	JR	NC,XCHK		; Yes --> X軸で判定

	SBC	$11,$13,XY_CHK	;Y2 < Y1 ?
XCHK:
	SBC	$12,$14		;X2 < X1 ?
XY_CHK:	RTN	C		; Yes ->RETURN

	LDW	$15,$13		;始点 Y1,X1とする。
	LDW	$13,$11		;終点 Y2,X2とする。
	RTN

;------------------------------------------------------------
; LEDTPアドレス、ビット作成
; 入力
; $15 = Y(0～31)、$16 = X(0～191)
; 出力
; IX / $2,$3 --- LEDTPアドレス
; $11 --- DRAWデータ
; $0  --- ビットカウント(0～7)
;------------------------------------------------------------
MAKEADR:
	LDW	$2,LEDTP	;LEDTPアドレスセット
;#if (MODEL=VX3)|(MODEL=V3BK2)
;	LD	$17,$31		;X上位クリア(VX-3のみ)
;	ADW	$2,$16		;X始点加算
;#else
	AD	$2,$16		;X始点加算
;#endif
	LD	$0,$15		;Y始点取得
	AN	$0,&H18		;行位置(2ビット)取り出し
	LD	$1,$31		;
	DIUW	$0		;16倍作成
	ADW	$2,$0		;16倍を加算
	BIDW	$1		;8倍
	ADW	$2,$0		;LEDTPアドレス算出

	LD	$0,$15		;$0=Y MOD 7
	AN	$0,7		;
;#if (MODEL=BANK2)|(MODEL=V3BK2)
;	PST	UA,&H66		;IX=バンク2選択
;#endif
	PRE	IX,BIT_DATA	;$11=DRAW Bit data
	LDD	$11,(IX+$0)	;
;#if (MODEL=BANK2)|(MODEL=V3BK2)
;	PST	UA,&H56		;IX=バンク1選択
;#endif
	PRE	IX,$2		;IX=LEDTPアドレス
	RTN

;------------------------------------------------------------
; MKDRAW : DRAW用データ作成(画面データとの演算結果を返す)
; 入力
; IX = LEDTPアドレス
; $10 = MODE(1:PSET、0:PRESET)
; $11 = PSETデータ
; ($17 = PRESETデータ)
; 出力
; $4  = DRAWデータ
;------------------------------------------------------------
MKDRAW:
	LDD	$4,(IX+$31)	;画面データ取得($4)
MKDRAW2:
	ANC	$10,$30		;PSET ?
	JR	NZ,DOTSET	; Yes ->PSET

	ANC	$10,2		;XOR ?
	JR	Z,DOTRESET	; No ->PRESET

	XR	$4,$11		;XOR表示
	RTN
DOTSET:
	OR	$4,$11		;ドットセット
	RTN
DOTRESET:
	LD	$5,$11		;ビット反転
	INV	$5		;
	AN	$4,$5		;ドットリセット
	RTN

;------------------------------------------------------------
; INCVEC 傾きデータ($2,$3)を更新する
; $1,$0 = 傾き(単位：1/256)
; $6 = 傾き端数(単位：1/65536)
; 出力
; $2,$3 = 傾きデータワーク(単位：1/256)
; $7 = 傾きデータワーク(単位：1/65536)
; ZF = 描画データ更新の有無(Z:更新なし、NZ:あり)
;------------------------------------------------------------
INCVEC:	LD	$5,$3		;増分(上位桁)保存

	AD	$7,$6		;端数繰り込みワーク加算
	JR	NC,INCVEC10	;繰り込みあり?
	ADW	$2,$30		;Yes->傾きに繰り込む(単位：1/256)
INCVEC10:
	ADW	$2,$0		;傾きデータ足しこみ

	SBC	$5,$3		;変化なし？
	RTN

;------------------------------------------------------------
; DIVB : 8ビット符号無し整数除算
;
; 入力  :$4    --- 被除算数(8bit)
;       :$5    --- 割り数(8bit)
; 結果  :$0,$1 --- 商($1:正数部、$0:小数点以下)
;       :$3    --- 剰余
;------------------------------------------------------------
DIVB:	XRM	$0,$0,4		;商($0,$1)、カウント($2)、剰余($3)を初期化
	SBC	$4,$31		;被除算数が0なら、終了。
	RTN	Z		;

	SBC	$5,$31		;0で割る場合、終了。
	RTN	Z		;

	BYUW	$5		;下位桁を0クリア
	LD	$2,8		;初期カウンタを8とする

DIVINIT:
	AD	$2,$30		;除算ループカウント+1
	BIUW	$5		;左シフト
	JR	NC,DIVINIT	;桁あふれが発生するまでループ。
	RODW	$6		;右シフト(割数を1ビット戻す)

DIVLOOP:
	ADW	$0,$30		;商+1
	SBW	$3,$5		;元数($3,$4)から、割数($5,$6)を引く。
	JR	NC,DIVNEXT	;結果が正数(引き算可能)なら、次の桁へ

	SBW	$0,$30		;商を元に戻す(-1)
	ADW	$3,$5		;元数($3,$4)を復元する。

DIVNEXT:
	SB	$2,$30		;除算カウント更新(-1)
	RTN	Z		;計算終了 ?

	BIUW	$0		;桁上げ：商($0,$1)をシフトアップ(2倍)
	BIDW	$6,JR DIVLOOP	;桁下げ：割数($5,$6)をシフトダウン(1/2)

;------------------------------------------------------------
; 描画(DRAW)ビットテーブル
;------------------------------------------------------------
BIT_DATA:DB	128,64,32,16,8,4,2,1	;Bit shift data


;**********************************
;*      SET_SGPRINT_DATA
;*PARA: $0,$1   - NO(0-31)
;*      $2,$3   - CHARACTOR DATA ADRESS(8*8 BITMAP)
;*WORK:
;*      IX      - キャラクタの読み込みアドレス
;*      IZ      - キャラクタの書き込みアドレス
;**********************************

MK_SG_CLR:DB 0,0,0,0,0,0,0,0

SET_SGPRINT_DATA:

PRE IX,MK_SG_CLR
LDM $20,(IX+$31),8

;格納先アドレスの算出。1キャラ128BYTEなのでキャラ番号を128倍する
BIUW $0;2
BIUW $0;4
BIUW $0;8
BIUW $0;16
BIUW $0;32
BIUW $0;64
BIUW $0;128

LDW $4,SG_CHR_DATA00
ADW $0,$4

PHUW $1

;キャラクタの読み込みアドレス設定
PRE IX,$2

;キャラクタの書き込みアドレスの設定
PRE IZ,$0

LD $19,64;下段書き込み用

;0DOT SHIFT
LDM $0,(IX+$31),8
STM $0,(IZ+$31),8       ;上段
STM $20,(IZ+$19),8     ;下段

PPUW $20
LDW $18,8
ADW $20,$18
LDW $22,$20
LDW $18,64
ADW $22,$18

PRE IX,$20;上段書き込み用
PRE IZ,$22;下段書き込み用

;データをレジスタに展開・初期化
LD $15,$7
LD $14,$31
LD $13,$6
LD $12,$31
LD $11,$5
LD $10,$31
LD $9,$4
LD $8,$31
LD $7,$3
LD $6,$31
LD $5,$2
LD $4,$31
LD $3,$1
LD $2,$31
LD $1,$0
LD $0,$31

LD $18,7  ;データ読み込みカウンタ


MSGDATA_LOOP:
BIDW $1
BIDW $3
BIDW $5
BIDW $7
BIDW $9
BIDW $11
BIDW $13
BIDW $15

STI $0,(IZ+$31)
STI $1,(IX+$31)
STI $2,(IZ+$31)
STI $3,(IX+$31)
STI $4,(IZ+$31)
STI $5,(IX+$31)
STI $6,(IZ+$31)
STI $7,(IX+$31)
STI $8,(IZ+$31)
STI $9,(IX+$31)
STI $10,(IZ+$31)
STI $11,(IX+$31)
STI $12,(IZ+$31)
STI $13,(IX+$31)
STI $14,(IZ+$31)
STI $15,(IX+$31)

SB $18,$30
JR NZ,MSGDATA_LOOP
RTN

;************************************************************
; SGPRINT_FAST
; 　LCD(0,0)がこのサブルーチンでは(0,8)となる。
;   Y座標は画面外に書き込まない処理を行っている。
;   X座標の描画制限を無視したい場合は、このサブルーチン内のSGPRINT_FAST_NCを呼び出すこと。
;   キャラクタ長は8固定でGPRINT_XMAX(定数)を超える部分も描画する。
;
;   処理は最上段(キャラクタをBYTE SHFIT)と最下段(キャラクタをBYTE SHFIT)、
;   行をまたぐためキャラクタをWORD SHIFTする場合の3つに分けて行っている。
;   また、高速化のためY座標が８の倍数の場合は、キャラのシフトを行わない処理を行っている。
;
; PARAMETER
;  $10       キャラのX座標
;  $11       キャラのY座標
;  $12       キャラの長さ
;  $13-$14   キャラのアドレス
;
; WORK
;  $0        カウンタ
;  $15-$16   LEDTPのアドレス（LEDTP0:&H6201、LEDTP1:&H62C1・・）
;  $17-$18   LEDTP+192(LCDをまたぐ際の下段LCDのアドレス）
;  $19-$20   キャラシフト用ワーク
;  $21       レジスタ退避用
;  $22-$23   またぐ場合：2バイト足し算（ADW $R+$22)
;            またがない場合（LCDLINE1）：ワーク
;  $24       OR転送用ワーク
;  IX        CHR ADRESS
;  IZ        BASE LEDTP ADRESS
;************************************************************

SGPRINT_FAST:

;X軸チェック
;キャラのX座標>GPRINT_XMAXなら描画範囲外なので戻る
SBC $10,D_GPRINT_XMAX
RTN NC

SGPRINT_FAST_NC:

;Y軸チェック

;キャラのY座標=0なら描画範囲外なので戻る
SBC $11,$31 ;$31=0
RTN Z

;キャラのY座標>40なら描画範囲外なので戻る
SBC $11,40
RTN NC

;  Y<7ならLINE0のみの描画処理
SGF_LINE_0:
SBC $11,8
JR NC,SGF_LINE_0_1
LDW $26,LEDTP0
JR SGF_DRAW1

;  8<Y<15ならLINE0とLINE1のまたぎ描画処理
SGF_LINE_0_1:
SB $11,8
SBC $11,8
JR NC,SGF_LINE_1_2
LDW $26,LEDTP0
JP SGF_DRAW0_3 ;JRは使用不能

;  16<Y<24ならLINE1とLINE2のまたぎ描画処理
SGF_LINE_1_2:
SB $11,8
SBC $11,8
JR NC,SGF_LINE_2_3
LDW $26,LEDTP1
JP SGF_DRAW0_3

;  24<Y<32ならLINE2とLINE3のまたぎ描画処理
SGF_LINE_2_3:
SB $11,8
SBC $11,8
JR NC,SGF_LINE_4
LDW $26,LEDTP2
JR SGF_DRAW0_3

;  32<Y<40ならLINE3のみの描画処理
SGF_LINE_4:
SB $11,8
LDW $26,LEDTP3

;************************
;境界をまたがないLCD最下段の描画
;************************
SGF_DRAW4:

;キャラクターの読み込みアドレスを算出する
CAL SUB_SGPRINT_CALC

;書き込みアドレスの算出
LD $2,$10
LD $3,$31
ADW $26,$2;LEDTPX+X座標
;書き込みアドレスをIZに設定
PRE IZ,$26

;$0-$7  読み込みキャラクタデータ
;$8-$15 背景データ
;IX     読み込みキャラクタデータ
;IZ     書き込みアドレス

;キャラクタデータを$0-$7に読み込む
LDM $0,(IX+$31),8

;VRAMデータを$8-$14に読み込む
LDM $8,(IZ+$31),8

JP SGF_DATA_PROC
;RTN

;************************
;境界をまたがないLCD最上段の描画
;************************
SGF_DRAW1:

;キャラクターの読み込みアドレスを算出する
CAL SUB_SGPRINT_CALC

;読み込みキャラクタのアドレスを+64(8BYTE×8キャラ)して下段のキャラに設定
LDW $0,64
ADW $22,$0
;読み込みキャラクタのアドレスをIXに設定
PRE IX,$22

;$0-$7  読み込みキャラクタデータ
;$8-$15 背景データ
;IX     読み込みキャラクタデータ
;IZ     書き込みアドレス

;書き込みアドレスの算出
LD $2,$10
LD $3,$31
ADW $26,$2;LEDTPX+X座標

;書き込みアドレスをIZに設定
PRE IZ,$26

JR SGF_DATA_PROC

;RTN

;************************
;境界をまたぐ描画
;************************
SGF_DRAW0_3:

CAL SUB_SGPRINT_CALC

;読み込みキャラクタ(下段)のアドレスを+64(8BYTE×8キャラ)に設定
LDW $24,$22
LDW $0,64
ADW $24,$0

;書き込みアドレス(上段)の算出
LD $2,$10
LD $3,$31
ADW $26,$2;LEDTPX+X座標

;書き込みアドレス(下段)の算出
LDW $28,$26
LDW $0,192;NEXT VRAM
ADW $28,$0

;$0-$7  読み込みキャラクタデータ
;$8-$15 背景データ
;IX     読み込みキャラクタデータ
;IZ     書き込みアドレス

;読み込みキャラクタ(上段)のアドレスをIXに設定
PRE IX,$22
;書き込みアドレス(上段)をIZに設定
PRE IZ,$26

;キャラクタ(上段)を$0-$7に読み込む
LDM $0,(IX+$31),8

;下段のVRAMデータ(上段)を$8-$14に読み込む
CAL SGF_DATA_PROC

;読み込みキャラクタ(下段)のアドレスをIXに設定
PRE IX,$24
;書き込みアドレス(下段)をIZに設定
PRE IZ,$28

JR SGF_DATA_PROC

;RTN

;******************************
;*PARA
;* IX   - CHARACTOR DATA ASRESS
;* IZ   - VRAM ADRESS
;*WORK
;* $0-$7  - CHARACTOR DATA
;* $8-$15 - VRAM DATA
;******************************

SGF_DATA_PROC:

;キャラクタ(上段)を$0-$7に読み込む
LDM $0,(IX+$31),8

;VRAMデータ(上段)を$8-$14に読み込む
LDM $8,(IZ+$31),8

;キャラと背景のOR(8BYTE)をとる
ORM $0,$8,8

;VRAMデータ(上段)に書き込む
STM $0,(IZ+$31),8

RTN

;************************************************************
; SGPRINT_4
; 　LCD(0,0)がこのサブルーチンでは(0,8)となる。
;   キャラは4×2固定
;   キャラはY座標が2ドットごと4段階の16×8のビットマップを用意すること
;   Y方向の移動は偶数しか出来ない。
;   Y座標は画面外に書き込まない処理を行う。
;   X座標についてはGPRINT_XMAX(定数)を超える部分は描画しない処理を行う。
;
;    0123456789012345
;0   ■■■■
;1   ■■■■
;2       ■■■■
;3       ■■■■
;4           ■■■■
;5           ■■■■
;6               ■■■■
;7               ■■■■
;
;   DB &HC0,&HC0,&HC0,&HC0,&H30,&H30,&H30,&H30
;   DB &H0C,&H0C,&H0C,&H0C,&H03,&H03,&H03,&H03
;
; PARAMETER
;  $10       キャラのX座標
;  $11       キャラのY座標
;  $12       キャラの長さ(4の倍数),4未満では戻る
;  $13-$14   キャラのアドレス
;
; USE
;  $17       キャラの長さ(強制的に4)
; WORK
;  $0        カウンタ
;  $9        WORK
;  $12       WORK
;  $15-$16   LEDTPのアドレス（PB-1000 LEDTP0:&H6201、LEDTP1:&H62C1・・）
;  IX        CHR ADRESS
;  IZ        BASE LEDTP ADRESS
;************************************************************

SGPRINT_4:

;キャラの長さを4の倍数に設定する
AN $12,&HFC    ;キャラの長さが4の場合3
RTN Z

SB $12,$30

;Y軸チェック

;キャラのY座標<8なら描画範囲外なので戻る
SBC $11,8
RTN C

;キャラのY座標>40なら描画範囲外なので戻る
SBC $11,40
RTN NC

;X軸チェック
;キャラのX座標>GPRINT_XMAXなら描画範囲外なので戻る
SBC $10,D_GPRINT_XMAX
RTN NC

;キャラのX座標+キャラの長さ>GPRINT_XMAXならキャラの長さを調節して、
;描画するキャラがGPRINT_XMAXからはみ出ないようにする。
LD $0,$10
AD $0,$17
SBC $0,D_GPRINT_XMAX
JR C,SG4_DRAW
LD $17,D_GPRINT_XMAX
SB $17,$10 ;キャラの長さ=GPRINT_XMAX-キャラのX座標

;************************
;       描画
;************************
SG4_DRAW:

;VRAM書き込みアドレスの算出
SBC $11,16
JR C,SG4_L0
SBC $11,24
JR C,SG4_L1
SBC $11,32
JR C,SG4_L2
LDW $0,LEDTP3;&H147C
JR SG4_SET_VRAM

SG4_L0:
LDW $0,LEDTP0;&H123C
JR SG4_SET_VRAM

SG4_L1:
LDW $0,LEDTP1;&H12FC
JR SG4_SET_VRAM

SG4_L2:
LDW $0,LEDTP2;&H13BC

SG4_SET_VRAM:
PHU $11
LD $11,$31
ADW $0,$10;LEDTPx+X座標
PRE IZ,$0
PPU $11

;キャラクタデータ読み込みアドレス設定
;キャラのY座標は偶数しか設定できない
AN $11,&H06
BIU $11
PHU $12
LD $12,$31

ADW $13,$11
PRE IX,$13

PPU $12

;キャラクタを$0に読み込む
LDM $0,(IX+$31),4

SG4_LOOP:
;OR転送
LDM $4,(IZ+$31),4
ORM $4,$0,4
STIM $4,(IZ+$31),4
SB $12,4
JR NC,SG4_LOOP
RTN

;**********************************
;*PARA
;* $11      - キャラクタのシフト量
;* $13,$14  - キャラクタデータの先頭アドレス
;*USE
;* $0
;* $1
;*RTN
;* IX       - READ CHARACTOR ADRESS
;* $22,$23  - READ CHARACTOR ADRESS
;**********************************

;$22,$23 読み込みキャラクタデータ(上段)
;$24,$25 読み込みキャラクタデータ(下段)(ここでは未使用)
;$26,$27 書き込みアドレス(上段)
;$28,$29 書き込みアドレス(下段)(ここでは未使用)
;IX      読み込みキャラクタデータ
;IZ      書き込みアドレス

SUB_SGPRINT_CALC:
LDW $22,$13
;シフト済みキャラクタの読み込みアドレスの算出
LD $1,$31
LD $0,$11
;シフトする量を8倍する
BIU $0
BIU $0
BIU $0
ADW $22,$0
;読み込みキャラクタのアドレスをIXに設定
PRE IX,$22
RTN

;*********************************
;*           CPRINT
;*PARA:
;*      $10     X(0-191)
;*      $11     Y(8の倍数:8,16,24,32,40)
;*      $12     LENGTH(8の倍数以外は動作保証しない)
;*      $13,$14 CHARACTOR ADRESS
;*      $15     LOOP(&HFF=LOOP指定):同じキャラクタを繰り返して表示
;*********************************
CPRINT:

AN $12,&HF8
RTN Z

SB $11,8 ;GPRINT座標系は左上が(0,8)なので、Y座標から8を引き座標系を(0,0)にする

LDW $0,LEDTP0
LDW $2,192
SET_LEDTOPLOOP:
SB $11,8
JR C,SET_CPRINT
ADW $0,$2
JR SET_LEDTOPLOOP

SET_CPRINT:
LD $11,$31
ADW $0,$10

PRE IX,$0
PRE IZ,$13

SBC $15,&HFF
JR Z,C_PRINTLOOP_REP

C_PRINTLOOP:
LDIM $0,(IZ+$31),8
STIM $0,(IX+$31),8
SB $12,8
RTN Z ;SBC $12,$30 ;調整
JR C_PRINTLOOP

C_PRINTLOOP_REP:
LDM $0,(IZ+$31),8
C_PRINTLOOP_REPL:
STIM $0,(IX+$31),8
SB $12,8
RTN Z ;SBC $12,$30 ;調整
JR C_PRINTLOOP_REPL

;*********************************
;*           CPRINT_OR
;*PARA:
;*      $10     X(0-191)
;*      $11     Y(8の倍数:8,16,24,32,40)
;*      $12     LENGTH(8の倍数以外は動作保証しない)
;*      $13,$14 CHARACTOR ADRESS
;*      $15     LOOP(&HFF=LOOP指定):同じキャラクタを繰り返して表示
;*********************************
CPRINT_OR:

AN $12,&HF8
RTN Z

SB $11,8 ;GPRINT座標系は左上が(0,8)なので、Y座標から8を引き座標系を(0,0)にする

LDW $0,LEDTP0
LDW $2,192
SET_LEDTOPLP_OR:
SB $11,8
JR C,SET_C_PRINT_OR
ADW $0,$2
JR SET_LEDTOPLP_OR

SET_C_PRINT_OR:
LD $11,$31
ADW $0,$10

PRE IX,$0
PRE IZ,$13

SBC $15,&HFF
JR Z,C_PRTOR_LOOP_REP

C_PRINT_OR_LOOP:
LDIM $0,(IZ+$31),8
LDM $20,(IX+$31),8
ORM $20,$0,8
STIM $20,(IX+$31),8
SB $12,8
RTN Z ;SBC $12,$30 ;調整
JR C_PRINT_OR_LOOP

C_PRTOR_LOOP_REP:
LDM $0,(IZ+$31),8
C_PRTOR_LOOPREPL:
LDM $20,(IX+$31),8
ORM $20,$0,8
STIM $20,(IX+$31),8
SB $12,8
RTN Z ;SBC $12,$30 ;調整
JR C_PRTOR_LOOPREPL

;*********************************
;*             CLS
;*USE:  $27,$28 IOCS(CLEDB)アドレス
;*********************************
CLS:
LDW $28,CLEDB ;**************(機種依存)
CAL IOCS_CAL
RTN

;************************************
;*              TEXT
;*
;* D_TEXTと比べ、$28,$29,IZが破壊される
;* DOTMKを呼び出すため$0～$11,IX,IZも破壊される
;*
;*PARA:
;*      $10 X
;*      $11 Y
;*      $12 LENGTH
;*      $13,$14 DATA ADRESS
;*USE:
;*      $0 CHARACTOR DATA
;*      $1 WORK
;*      $2 WORK/LEDTOP WORK
;*      $3 WORK/LEDTOP WORK
;*      $4 WORK
;*      $28,$29 IOCS ADRESS(DOTMK)
;*      IX DATA READ INDEX
;*      IZ DATA STORE INDEX
;************************************
TEXT:

;文字の長さが0なら戻る
SBC $12,$31
RTN Z

PRE IX,$13

;文字表示座標をEDTOP0+(Y*32+X)を計算する
DIU $11 ;Y*16
BIU $11 ;Y*2
AD $10,$11 ;カーソル開始位置
LD $11,$10;X_START+LEN
AD $11,$12
SB $11,$30

;$10 EDTOP START
;$11 EDTOP END

LD $0,$10
LD $1,$31

LDW $20,EDTOP0
ADW $0,$20
PRE IZ,$0

LD $1,$31

TEXT_LOOP:
LD $0,(IX+$1)
ST $0,(IZ+$1)
AD $1,$30
SBC $1,$12
JR Z,@DOTMK
JR TEXT_LOOP

@DOTMK:
;-----------------------------------------------------
; debug FX-870P/VX-4のDOTMK(977F)は仕様が違う事が判明。
; こたちゃん氏の解析では$10､$11に表示開始/終了位置を
; 指定するが、正しく動作するのは$10=0の場合のみとなる。
; PB-1000/Cと同様に$10を正しく利用できるようにするには、
; 呼出しアドレスをDOTMK+4にして$2,$3にLEDTP指定が必要。
; VX-3も同様。
;-----------------------------------------------------

LD $0,$10      ;$0=カーソル開始位置($10)
LD $1,$31   ;
;-----------------------------------------------------
; $2,$3 = LEDTPアドレス(開始位置)設定
;-----------------------------------------------------
BIUW $0         ;2倍を作成
LDW $4,$0       ;2倍を保存
BIUW $0         ;4倍を作成
ADW $0,$4       ;4倍+2倍=6倍にする
LDW $2,LEDTP0   ;LEDTPアドレスを加える
ADW $2,$0       ;$2,$3=LEDTP+$10*6

LDW $28,DOTMK   ;DOTMK指定
JP IOCS_CAL

RTN




