;********************************************
;*          LM2_OP
;* CD C:\FX-870P\LM2_OP
;* HD61 LM2_OP.TXT /P
;* DA61.EXE /PICTURE.BMP /DB /NC
;********************************************
;INKEY:EQU &H191D ;870P
;DOTMK:EQU &H9783 ;870P ;FX-870PではDOTMK+4でないと正常に動作しない
;DOTDS:EQU &H930F ;870P
;CLEDB:EQU &H9338 ;870P
;IOCS:EQU &H5321  ;BIOS CALL用

;LEDTP: EQU &H123C ;LCD表示用バッファ
;LEDTP0:EQU LEDTP       ;870P
;LEDTP1:EQU LEDTP+192   ;870P
;LEDTP2:EQU LEDTP+192*2 ;870P
;LEDTP3:EQU LEDTP+192*3 ;870P

;EDTOP0: EQU &H113B ;870P文字表示用バッファ

WAIT_MES:EQU 2000
WAIT_NORM:EQU 1000
WAIT_SHORT:EQU 500
WAIT_KEY:EQU 50
WAIT_KEY100:EQU 100
WAIT_FADE:EQU 100

;ORG &H1CD0
;START START

;*********************************************************
;*                  TAXIING MESSAGE
;*********************************************************
;Pre-flight check
MES_PREFLIGHT_CK:;16
DB "Pre-flight check"

;*********************************************************
;*                  TAXIING MESSAGE
;*********************************************************

MES_PILOT:DB "PILOT"
MES_TOWER:DB "TOWER"

;PILOT
;"Osaka Tower, FOX04,
;request taxi for takeoff."
;MES_REQ_TAXIING0:;5
;DB "PILOT"
MES_REQ_TAXIING1:;20
DB "'Osaka Tower, FOX04,"
MES_REQ_TAXIING2:;26
DB "request taxi for takeoff.'"

;TOWER
;"FOX04, Osaka Tower,
;taxi to runway 24, hold short.
;Wind 230 degrees at 8 knots."
;MES_ANS_TAXIING0:;5
;DB "TOWER"
MES_ANS_TAXIING1:;20
DB "'FOX04, Osaka Tower,"
MES_ANS_TAXIING2:;30
DB "taxi to runway 24, hold short."
MES_ANS_TAXIING3:;29
DB "Wind 230 degrees at 8 knots.'"

;*********************************************************
;*             READY TO TAKEOFF MESSAGE
;*********************************************************
;PILOT
;"Osaka Tower, FOX04,
;ready for departure,
;runway 24."
;MES_READY_TO00:;5
;DB "PILOT"
MES_READY_TO01:;20
DB "'Osaka Tower, FOX04,"
MES_READY_TO02:;20
DB "ready for departure,"
MES_READY_TO03:;11
DB "runway 24.'"

;TOWER
;"FOX04, cleared for
;takeoff runway 24, left turn
;departure after takeoff."

;MES_ALLOW_TO00:;5
;DB "TOWER"
MES_ALLOW_TO01:;19
DB "'FOX04, cleared for"
MES_ALLOW_TO02:;28
DB "takeoff runway 24, left turn"
MES_ALLOW_TO03:;25
DB "departure after takeoff.'"

;*********************************************************
;*                  TAKEOFF MESSAGE
;*********************************************************
;PILOT
;"FOX04, rolling."
;MES_ROLLING00:;5
;DB "PILOT"
MES_ROLLING01:;17
DB "'FOX04, rolling.'"

;*********************************************************
;*               AFTER TAKEOFF MESSAGE
;*********************************************************
;TOWER
;"FOX04, wind check,
;cleared for takeoff."
;MES_INFO_TO00:;5
;DB "TOWER"
MES_INFO_TO01:;19
DB "'FOX04, wind check,"
MES_INFO_TO02:;21
DB "cleared for takeoff.'"

;TOWER
;"FOX04, contact Osaka
;Departure 870"
;MES_FRQ_INFO00:;5
;DB "TOWER"
MES_FRQ_INFO01:;21
DB "'FOX04, contact Osaka"
MES_FRQ_INFO02:;14
DB "Departure 870'"
;PILOT
;"Contact Departure 870, FOX04"
;MES_FRQ_COPY00:;5
;DB "PILOT"
MES_FRQ_COPY01:;30
DB "'Contact Departure 870, FOX04'"

;GPRINT_XMAX:DB 191

;遷移管理
;PHASEはSYSTEMがBOSSを管理するために使用するので、ユーザーは使用禁止
;PHASE:DB 0
;PHASE_COUNTER:DB 0
;ユーザーに解放
;SECTION:DB 0
;SECTION_COUNTER:DB 0

;雑用に使うカウンタ、フラグ
;EXTRA:
;EXTRA_FLAG:DB 0
;EXTRA_COUNTER:DB 0

;MY_X:DB 0
;MY_Y:DB 0

;START:
LM2_OP_START:

;管理テーブル初期化
LDW $0,&H0000;7;4
PRE IX,PHASE
STW $0,(IX+$31)
LDW $0,&H0000
PRE IX,SECTION
STW $0,(IX+$31)
;PHA3:LDW $0,&HFF90
;PHA4
PRE IX,EXTRA
LD $0,0
ST $0,(IX+$31)
LD $0,0
ST $0,(IX+$30)
;

LM2OP_LOOP:

PRE IX,PHASE
LD $0,(IX+$31)

SBC $0,0
JP Z,LM2OP_PHASE0;FX-870P/VX-4表示
SBC $0,1
JP Z,LM2OP_PHASE1;F-35正面表示
SBC $0,2
JP Z,LM2OP_PHASE2;エレベーター点検文字表示
SBC $0,3
JP Z,LM2OP_PHASE3;エレベーター上下表示
SBC $0,4
JP Z,LM2OP_PHASE4;タキシング要求・許可文字表示
SBC $0,5
JP Z,LM2OP_PHASE5;タキシング表示
SBC $0,6
JP Z,LM2OP_PHASE6;離陸要求・許可文字表示
SBC $0,7
JP Z,LM2OP_PHASE7;滑走、離陸表示
SBC $0,8
JP Z,LM2OP_PHASE8;周波数設定文字表示
SBC $0,9
JP Z,LM2OP_PHASE9;接近、タイトル表示
SBC $0,10
JP Z,LM2OP_PHASEA;フェードアウト
SBC $0,11
JP LM2OP_PHASEB;フェードイン(タイトル表示)

NEXT_LM2OP:

PRE IX,PHASE
LD $0,(IX+$31)
SBC $0,12
JR NZ,LM2OP_LOOP

END_PROG:
PST UA,&H54         ;(FX-870P/VX-4のみ追加)
RTN

;*******************************************
;*          LM2OP_PHASE0
;*          FX-870P/VX-4表示
;*******************************************

LM2OP_PHASE0:

PRE IX,SECTION
LD $0,(IX+$31)
SBC $0,0
JR Z,LM2OP_PHA0_SEC00
JR LM2OP_PHA0_SEC01

LM2OP_PHA0_SEC00:
;画面クリア
CAL CLS
;濃度を最低にする
LD $0,0
CAL CONTRAST_CHANGE

;FX-870P/VX-4のBMPを左に表示
LD $10,24
LD $11,8
LD $12,64
LDW $13,FX870P_VX4
LD $16,32
CAL GPRINT_WIDE

;SYSTEM室SOFTを右上に表示
LD $10,112
LD $11,8
LD $12,48
LDW $13,BMP_SYSTEMO_SOFT
LD $16,16
CAL GPRINT_WIDE

;COPYRIGHTを右下に表示
LD $10,112
LD $11,24
LD $12,48
LDW $13,BMP_COPYRIGHT
LD $16,16
CAL GPRINT_WIDE

LDW $28,DOTDS
CAL IOCS_CAL

;次のSECTIONへ移行
PRE IX,SECTION
ST $30,(IX+$31)

JP NEXT_LM2OP

LM2OP_PHA0_SEC01:;濃度変更

PRE IX,SECTION_COUNTER
LD $0,(IX+$31)
CAL CONTRAST_CHANGE
LDW $0,50
CAL LM2OP_WAIT
PRE IX,SECTION_COUNTER
AD (IX+$31),$30
LD $0,(IX+$31)
SBC $0,32
JR Z,END_LM2OP_P0_S1
;PRE IX,SECTION_COUNTER
;ST $0,(IX+$31)
JP NEXT_LM2OP

END_LM2OP_P0_S1:
;PHASEを1に変更
PRE IX,PHASE
ST $30,(IX+$31)
;SECTION/SECTION COUNTER初期化
PRE IX,SECTION
ST $31,(IX+$31)
;SECTION COUNTERは32だけどそのまま使用
JP NEXT_LM2OP

;*******************************************
;*          LM2OP_PHASE1
;*          F-35正面表示
;*******************************************

LM2OP_PHASE1:

PRE IX,SECTION
LD $0,(IX+$31)
SBC $0,0
JR Z,LM2OP_PHA1_SEC00
JR LM2OP_PHA1_SEC01

LM2OP_PHA1_SEC00:
;画面クリア
CAL CLS
;F-35正面を中央に表示
LD $10,60
LD $11,8
LD $12,72
LDW $13,F35_FRONT
LD $16,32
CAL GPRINT_WIDE

LDW $28,DOTDS
CAL IOCS_CAL

;次のSECTIONへ移行
PRE IX,SECTION
ST $30,(IX+$31)

JP NEXT_LM2OP

LM2OP_PHA1_SEC01:;濃度変更

PRE IX,SECTION_COUNTER
LD $0,(IX+$31)
CAL CONTRAST_CHANGE
LDW $0,100
CAL LM2OP_WAIT
PRE IX,SECTION_COUNTER
SB (IX+$31),$30
LD $0,(IX+$31)
SBC $0,16;濃度が16になったら終了
JR Z,END_LM2OP_P1_S1
;PRE IX,SECTION_COUNTER
;ST $0,(IX+$31)
JP NEXT_LM2OP

END_LM2OP_P1_S1:

LDW $0,WAIT_MES
CAL LM2OP_WAIT

;PHASEを2に変更
PRE IX,PHASE
LD $0,2
ST $0,(IX+$31)
;SECTION/SECTION COUNTER初期化
PRE IX,SECTION
LDW $0,0
STW $0,(IX+$31)
JP NEXT_LM2OP

;*******************************************
;*          LM2OP_PHASE2
;*          エレベーター点検文字表示
;*******************************************

LM2OP_PHASE2:

CAL CLS

;Pre-flight check
LD $10,7
LD $11,1
LD $12,16
LDW $13,MES_PREFLIGHT_CK
CAL TEXT

LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,WAIT_NORM
CAL LM2OP_WAIT

PRE IX,PHASE
LD $0,3
ST $0,(IX+$31)
JP NEXT_LM2OP

;*******************************************
;*          LM2OP_PHASE3
;*          エレベーター上下表示
;*******************************************

LM2OP_PHASE3:

PRE IX,SECTION
LD $0,(IX+$31)

SBC $0,0
JP Z,LM2OP_ELEUD_0;F-35 ELEVATOR00表示&WAIT
SBC $0,1
JP Z,LM2OP_ELEUD_1;F-35 ELEVATORP1表示
SBC $0,2
JP Z,LM2OP_ELEUD_2;F-35 ELEVATORP2表示
SBC $0,3
JP Z,LM2OP_ELEUD_3;F-35 ELEVATORP1表示
SBC $0,4
JP Z,LM2OP_ELEUD_4;F-35 ELEVATOR00表示
SBC $0,5
JP Z,LM2OP_ELEUD_5;F-35 ELEVATORM1表示
SBC $0,6
JP Z,LM2OP_ELEUD_6;F-35 ELEVATORM2表示
SBC $0,7
JP Z,LM2OP_ELEUD_7;F-35 ELEVATORM1表示
SBC $0,8
JP Z,LM2OP_ELEUD_8;F-35 ELEVATOR00表示
;SBC $0,3
;JR Z,LM2OP_ELEUD_9
JP LM2OP_ELEUD_9;PHASE遷移処理

LM2OP_ELEUD_0:

CAL CLS
LD $10,64
LD $11,8
LD $12,64
LDW $13,F35_ELEVATOR_00
LD $16,32
CAL GPRINT_WIDE
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,WAIT_SHORT
CAL LM2OP_WAIT

PRE IX,SECTION
ST $30,(IX+$31)
JP NEXT_LM2OP

LM2OP_ELEUD_1:
CAL CLS
LD $10,64
LD $11,8
LD $12,64
LDW $13,F35_ELEVATOR_P1
LD $16,32
CAL GPRINT_WIDE
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,50
CAL LM2OP_WAIT
PRE IX,SECTION
LD $0,2
ST $0,(IX+$31)
JP NEXT_LM2OP

LM2OP_ELEUD_2:
CAL CLS
LD $10,64
LD $11,8
LD $12,64
LDW $13,F35_ELEVATOR_P2
LD $16,32
CAL GPRINT_WIDE
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,50
CAL LM2OP_WAIT
PRE IX,SECTION
LD $0,3
ST $0,(IX+$31)
JP NEXT_LM2OP

LM2OP_ELEUD_3:
CAL CLS
LD $10,64
LD $11,8
LD $12,64
LDW $13,F35_ELEVATOR_P1
LD $16,32
CAL GPRINT_WIDE
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,50
CAL LM2OP_WAIT
PRE IX,SECTION
LD $0,4
ST $0,(IX+$31)
JP NEXT_LM2OP

LM2OP_ELEUD_4:
CAL CLS
LD $10,64
LD $11,8
LD $12,64
LDW $13,F35_ELEVATOR_00
LD $16,32
CAL GPRINT_WIDE
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,50
CAL LM2OP_WAIT
PRE IX,SECTION
LD $0,5
ST $0,(IX+$31)
JP NEXT_LM2OP

LM2OP_ELEUD_5:
CAL CLS
LD $10,64
LD $11,8
LD $12,64
LDW $13,F35_ELEVATOR_M1
LD $16,32
CAL GPRINT_WIDE
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,50
CAL LM2OP_WAIT
PRE IX,SECTION
LD $0,6
ST $0,(IX+$31)
JP NEXT_LM2OP

LM2OP_ELEUD_6:
CAL CLS
LD $10,64
LD $11,8
LD $12,64
LDW $13,F35_ELEVATOR_M2
LD $16,32
CAL GPRINT_WIDE
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,50
CAL LM2OP_WAIT
PRE IX,SECTION
LD $0,7
ST $0,(IX+$31)
JP NEXT_LM2OP

LM2OP_ELEUD_7:
CAL CLS
LD $10,64
LD $11,8
LD $12,64
LDW $13,F35_ELEVATOR_M1
LD $16,32
CAL GPRINT_WIDE
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,50
CAL LM2OP_WAIT
PRE IX,SECTION
LD $0,8
ST $0,(IX+$31)
JP NEXT_LM2OP

LM2OP_ELEUD_8:
CAL CLS
LD $10,64
LD $11,8
LD $12,64
LDW $13,F35_ELEVATOR_00
LD $16,32
CAL GPRINT_WIDE
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,50
CAL LM2OP_WAIT
PRE IX,SECTION
LD $0,9
ST $0,(IX+$31)
JP NEXT_LM2OP

LM2OP_ELEUD_9:
PRE IX,SECTION
ST $31,(IX+$31)
ST $31,(IX+$30)
PRE IX,EXTRA
LDW $0,&HFF90;-112(タキシングするF-35のX座標をSECTION COUNTERに設定)
STW $0,(IX+$31)
PRE IX,PHASE
LD $0,4
ST $0,(IX+$31)
JP NEXT_LM2OP

;*******************************************
;*          LM2OP_PHASE4
;*          タキシング要求・許可文字表示
;*******************************************

LM2OP_PHASE4:

;PILOT
;"Osaka Tower, FOX87,
;request taxi for takeoff."

CAL CLS

LD $10,0
LD $11,0
LD $12,5
LDW $13,MES_PILOT
CAL TEXT

LD $10,0
LD $11,1
LD $12,20
LDW $13,MES_REQ_TAXIING1
CAL TEXT

LD $10,0
LD $11,2
LD $12,26
LDW $13,MES_REQ_TAXIING2
CAL TEXT
LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,WAIT_MES
CAL LM2OP_WAIT

;CAL HIT_ANYKEY

;TOWER
;"FOX87, Osaka Tower,
;taxi to runway 24, hold short.
;Wind 230 degrees at 8 knots."

CAL CLS

LD $10,0
LD $11,0
LD $12,5
LDW $13,MES_TOWER
CAL TEXT

LD $10,0
LD $11,1
LD $12,20
LDW $13,MES_ANS_TAXIING1
CAL TEXT

LD $10,0
LD $11,2
LD $12,30
LDW $13,MES_ANS_TAXIING2
CAL TEXT

LD $10,0
LD $11,3
LD $12,29
LDW $13,MES_ANS_TAXIING3
CAL TEXT

LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,WAIT_MES
CAL LM2OP_WAIT

;CAL HIT_ANYKEY

PRE IX,PHASE
LD $0,5
ST $0,(IX+$31)
JP NEXT_LM2OP

;*******************************************
;*          LM2OP_PHASE5
;*          タキシング表示
;*******************************************
LM2OP_PHASE5:

CAL CLS

PRE IX,SECTION
LD $0,(IX+$31)
SBC $0,0
JR Z,LM2OP_SECTION0
JR LM2OP_SECTION1

LM2OP_SECTION0:
;F-35のX座標を-90に設定する
PRE IZ,EXTRA
LDW $0,&HFF90
STW $0,(IZ+$31)
;SECTION1に移行
ST $30,(IX+$31)
JP NEXT_LM2OP

LM2OP_SECTION1:
PRE IX,EXTRA
LDW $0,2
ADW (IX+$31),$0
LDW $17,(IX+$31)
LDW $0,192
SBCW $17,$0
JP Z,END_LM2OP_PHA5

;*****************************
;*      背景
;*****************************

PHUW $18
;OSAKA_AB表示
LD $10,0
LD $11,16
LD $12,192
LDW $13,OSAKA_AB
LD $16,24
CAL GPRINT_WIDE
PPUW $17

;*****************************
;*      F-35
;*****************************

;スプライト転送のマスクデータ作成
;GPRINTをAND転送モードに変更

CAL SET_GPRINT_AN

PHUW $18
LD $11,8
LD $12,112
LDW $13,F35_TAXIING_MASK
CAL GPRINT_X16BIT
PPUW $17

PHUW $18
LD $11,16
LD $12,112
LDW $13,F35_TAXIING_MASK+112
CAL GPRINT_X16BIT
PPUW $17

PHUW $18
LD $11,24
LD $12,112
LDW $13,F35_TAXIING_MASK+(112*2)
CAL GPRINT_X16BIT
PPUW $17

PHUW $18
LD $11,32
LD $12,112
LDW $13,F35_TAXIING_MASK+(112*3)
CAL GPRINT_X16BIT
PPUW $17

;GPRINTをOR転送モードに変更
CAL SET_GPRINT_OR

;スプライト転送のマスクデータ作成終了


PHUW $18
LD $11,8
LD $12,112
LDW $13,F35_TAXIING
CAL GPRINT_X16BIT
PPUW $17

PHUW $18
LD $11,16
LD $12,112
LDW $13,F35_TAXIING+112
CAL GPRINT_X16BIT
PPUW $17

PHUW $18
LD $11,24
LD $12,112
LDW $13,F35_TAXIING+(112*2)
CAL GPRINT_X16BIT
PPUW $17

PHUW $18
LD $11,32
LD $12,112
LDW $13,F35_TAXIING+(112*3)
CAL GPRINT_X16BIT
PPUW $17

LDW $28,DOTDS
CAL IOCS_CAL

;BREAK対処
LDW $0,$30
CAL LM2OP_WAIT

JP NEXT_LM2OP

END_LM2OP_PHA5:
PRE IX,PHASE
LD $0,6
ST $0,(IX+$31)
PRE IX,SECTION
LDW $0,0
ST $0,(IX+$31)
PRE IX,EXTRA
LD $0,$31
ST $0,(IX+$31)
LD $0,&H08
ST $0,(IX+$30)
JP NEXT_LM2OP

;*******************************************
;*          LM2OP_PHASE6
;*          離陸要求・許可文字表示
;*******************************************

LM2OP_PHASE6:
;PILOT
;"Osaka Tower, FOX87,
;ready for departure,
;runway 24."
LD $10,$31
LD $11,$31
LD $12,5
LDW $13,MES_PILOT
CAL TEXT

LD $10,$31
LD $11,$30
LD $12,20
LDW $13,MES_READY_TO01
CAL TEXT

LD $10,$31
LD $11,2
LD $12,20
LDW $13,MES_READY_TO02
CAL TEXT
LDW $28,DOTDS
CAL IOCS_CAL

LD $10,$31
LD $11,3
LD $12,11
LDW $13,MES_READY_TO03
CAL TEXT

LDW $28,DOTDS
CAL IOCS_CAL
LDW $0,WAIT_MES
CAL LM2OP_WAIT

;CAL HIT_ANYKEY

;TOWER
;"FOX87, cleared for
;takeoff runway 24, right turn
;departure after takeoff."

LD $10,0
LD $11,0
LD $12,5
LDW $13,MES_TOWER
CAL TEXT

LD $10,0
LD $11,1
LD $12,19
LDW $13,MES_ALLOW_TO01
CAL TEXT

LD $10,0
LD $11,2
LD $12,28
LDW $13,MES_ALLOW_TO02
CAL TEXT
LDW $28,DOTDS
CAL IOCS_CAL

LD $10,0
LD $11,3
LD $12,25
LDW $13,MES_ALLOW_TO03
CAL TEXT

LDW $28,DOTDS
CAL IOCS_CAL
LDW $0,WAIT_MES
CAL LM2OP_WAIT

;CAL HIT_ANYKEY

PRE IX,PHASE
LD $0,7
ST $0,(IX+$31)
JP NEXT_LM2OP

;*******************************************
;*          LM2OP_PHASE7
;*          滑走、離陸表示
;*******************************************


TAKE_OFF_WAIT:EQU 8

LM2OP_PHASE7:

PRE IX,SECTION
LD $0,(IX+$31)

SBC $0,0
JP Z,LM2OP_TO_0;WAIT
SBC $0,1
JP Z,LM2OP_TO_1;rolling表示
JP LM2OP_TO_2;滑走,上昇

LM2OP_TO_0:

CAL CLS

;表示するF-35のBMP(0:NOSE DOWN 1:NOSE UP)
PRE IX,PHASE_COUNTER
ST $31,(IX+$31)

;F-35表示位置の初期化
PRE IX,MY_X
LD $0,88
ST $0,(IX+$31)
LD $0,10
ST $0,(IX+$30)

CAL LM2OP_PH7_FDISP

LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,WAIT_MES
CAL LM2OP_WAIT

PRE IX,SECTION
ST $30,(IX+$31)
JP NEXT_LM2OP

LM2OP_TO_1:

CAL CLS

LD $10,0
LD $11,0
LD $12,5
LDW $13,MES_PILOT
CAL TEXT

LD $10,0
LD $11,1
LD $12,17
LDW $13,MES_ROLLING01
CAL TEXT

LDW $28,DOTDS
CAL IOCS_CAL
LDW $0,WAIT_NORM
CAL LM2OP_WAIT

;CAL HIT_ANYKEY

PRE IX,SECTION
LD $0,2
ST $0,(IX+$31)
PRE IX,EXTRA
LD $0,0
ST $0,(IX+$31)
LD $0,TAKE_OFF_WAIT
ST $0,(IX+$30)
JP NEXT_LM2OP

LM2OP_TO_2:
CAL CLS

CAL LM2OP_PH7_FDISP

PRE IX,SECTION_COUNTER
LD $0,(IX+$31)

BIU $0

PHU $0
;LEFT RUMP
PRE IX,LM2OP_PH7_RUMP_L
LDM $10,(IX+$0),2
LD $12,8
LDW $13,BMP_RUMP
CAL GPRINT

PPU $0
PRE IX,LM2OP_PH7_RUMP_R
LDM $10,(IX+$0),2
LD $12,8
LDW $13,BMP_RUMP
CAL GPRINT

LDW $28,DOTDS
CAL IOCS_CAL

PRE IX,LM2OP_PH7_WAIT
PRE IZ,EXTRA
LD $1,(IZ+$31)
LD $0,(IX+$1)
LD $1,$31
CAL LM2OP_WAIT

PRE IX,SECTION_COUNTER
LD $0,(IX+$31)
AD $0,$30
AN $0,&H07
ST $0,(IX+$31)

;EXTRA(WAIT INDEX)が7未満ならランプの速度変化を行う
;7ならY-=1してF-35を上昇させる
;Y<0になったら次のPHASEに移行する
;F-35のBMPをNOSE UPに変更する
LD $0,(IZ+$31)
SBC $0,7
JP C,LM2OP_MOVE_RUMP

;F-35のBMPをNOSE UPに変更する
PRE IX,PHASE_COUNTER
ST $30,(IX+$31)

PRE IX,MY_X
;X=X-3
LD $0,5
SB (IX+$31),$0
;Y=Y-1
LD $0,(IX+$30)
SB $0,$30
ST $0,(IX+$30)
SBC $0,248
JP NZ,NEXT_LM2OP
;次のフェーズに移行
PRE IX,PHASE
LD $0,8
ST $0,(IX+$31)
ST $31,(IX+$30)
PRE IX,SECTION
LDW $0,0
STW $0,(IX+$31)
PRE IX,EXTRA
STW $0,(IX+$31)
JP NEXT_LM2OP

LM2OP_MOVE_RUMP:
;EXTRA COUNTERが定数(TAKE_OFF_WAIT)->0になったら定数に戻し、
;EXTRA(WAIT INDEX)を1プラスする
SB (IZ+$30),$30
JP NZ,NEXT_LM2OP
;EXTRA COUNTERを定数に戻す
LD $0,TAKE_OFF_WAIT
ST $0,(IZ+$30)
;EXTRA(WAIT INDEX)を1プラスする
LD $0,(IZ+$31)
AD (IZ+$31),$30

JP NEXT_LM2OP

LM2OP_PH7_RUMP_L:
DB 04,31+4,10,30+4,20,29+4,30,28+4
DB 40,27+4,50,26+4,60,25+4,70,24+4

LM2OP_PH7_RUMP_R:
DB 172,31+4,171,30+4,170,29+4,169,28+4
DB 168,27+4,167,26+4,166,25+4,165,24+4

LM2OP_PH7_WAIT:
DB 100,80,60,40,20,10,5,0

LM2OP_PH7_FDISP:

PRE IX,PHASE_COUNTER
LD $0,(IX+$31)

PRE IX,MY_X
LDM $10,(IX+$31),2
LD $12,64
SBC $0,$31
JR NZ,LM2OP_NOSE_UP
LDW $13,F35_STANDBY
JR LM2OPPH4_CHRSETR
LM2OP_NOSE_UP:
LDW $13,F35_TAKEOFF
LM2OPPH4_CHRSETR:
LD $16,24
CAL GPRINT_WIDE

;LINE
;LD $0,88
;LD $1,24
;LD $2,16
;LD $3,31
;CAL LINE_NEW
LD $14,88
LD $13,24
LD $12,16
LD $11,31
LD $10,&H01
CAL DRAW

;LD $0,170
;LD $1,32
;LD $2,160
;LD $3,24
;CAL LINE_NEW
LD $14,170
LD $13,32
LD $12,160
LD $11,24
LD $10,&H01
CAL DRAW;LINE_NEW

;LD $0,1
;LD $1,24
;LD $2,191
;LD $3,24
;CAL LINE_NEW
LD $14,1
LD $13,24
LD $12,191
LD $11,24
LD $10,&H01
CAL DRAW;LINE_NEW

RTN

;*******************************************
;*          LM2OP_PHASE8
;*          離陸後・周波数設定交信
;*******************************************

LM2OP_PHASE8:

CAL CLS

;TOWER
;"FOX87, wind check,
;cleared for takeoff."

LD $10,0
LD $11,0
LD $12,5
LDW $13,MES_TOWER
CAL TEXT

LD $10,0
LD $11,1
LD $12,19
LDW $13,MES_INFO_TO01
CAL TEXT

LD $10,0
LD $11,2
LD $12,21
LDW $13,MES_INFO_TO02
CAL TEXT

LDW $28,DOTDS
CAL IOCS_CAL
LDW $0,WAIT_MES
CAL LM2OP_WAIT

;CAL HIT_ANYKEY

CAL CLS

;TOWER
;"FOX87, contact Osaka
;Departure 870"

LD $10,0
LD $11,0
LD $12,5
LDW $13,MES_TOWER
CAL TEXT

LD $10,0
LD $11,1
LD $12,21
LDW $13,MES_FRQ_INFO01
CAL TEXT

LD $10,0
LD $11,2
LD $12,14
LDW $13,MES_FRQ_INFO02
CAL TEXT

LDW $28,DOTDS
CAL IOCS_CAL
LDW $0,WAIT_MES
CAL LM2OP_WAIT

;CAL HIT_ANYKEY

CAL CLS

;PILOT
;"Contact Departure 870, FOX87"

LD $10,0
LD $11,0
LD $12,5
LDW $13,MES_PILOT
CAL TEXT

LD $10,0
LD $11,1
LD $12,30
LDW $13,MES_FRQ_COPY01
CAL TEXT

LDW $28,DOTDS
CAL IOCS_CAL
LDW $0,WAIT_MES
CAL LM2OP_WAIT

;CAL HIT_ANYKEY

PRE IX,PHASE
LD $0,9
ST $0,(IX+$31)
JP NEXT_LM2OP

;*******************************************
;*          LM2OP_PHASE9
;*          接近、タイトル表示
;*******************************************
LM2OP_PHASE9:

PRE IX,SECTION
LD $0,(IX+$31)

SBC $0,0
JP Z,LM2OP_F35_SMALL;F-35小表示
SBC $0,1
JP Z,LM2OP_F35_MID;F-35中表示
JP LM2OP_F35_BIG;F-35大表示


LM2OP_F35_SMALL:

CAL CLS

LD $10,20
LD $11,8
LD $12,24
LDW $13,F35_RISE1
LD $16,16
CAL GPRINT_WIDE

LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,WAIT_SHORT
CAL LM2OP_WAIT

PRE IX,SECTION
ST $30,(IX+$31)

LM2OP_F35_MID:

CAL CLS

LD $10,40
LD $11,16
LD $12,80
LDW $13,F35_RISE2
LD $16,32
CAL GPRINT_WIDE

LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,WAIT_SHORT
CAL LM2OP_WAIT

PRE IX,SECTION
LD $0,2
ST $30,(IX+$31)

LM2OP_F35_BIG:

CAL CLS

CAL TITLE_DRAW

LDW $28,DOTDS
CAL IOCS_CAL

LDW $0,WAIT_MES
CAL LM2OP_WAIT

PRE IX,PHASE
LD $0,10
ST $0,(IX+$31)
ST $31,(IX+$30)
PRE IX,SECTION
LD $0,0
ST $0,(IX+$31)
LD $0,16
ST $0,(IX+$30)
JP NEXT_LM2OP

TITLE_DRAW:

LD $10,102
LD $11,8
LD $12,88
LDW $13,F35_TITLE
LD $16,32
CAL GPRINT_WIDE

LD $10,0;20
LD $11,8
LD $12,80
LDW $13,LM2_TITLE
LD $16,32
CAL GPRINT_WIDE

RTN


;*******************************************
;*          LM2OP_PHASEA
;*          TITLE
;*******************************************

MES_PUSH_SPC:DB "PUSH SPC KEY!"

LM2OP_PHASEA:

CAL CLS

;画面の濃度を設定値に変更する
PRE IX,CONTRAST_DATA
LD $0,(IX+$31)

CAL CONTRAST_CHANGE

;最初にF-35とタイトルを表示させる
CAL TITLE_DRAW
LDW $28,DOTDS
CAL IOCS_CAL

;カウンターとPUSH KEY表示の初期化
LD $0,10*2;COUNTER(10回でDEMOに移る場合は10*2を指定)
LD $1,$31;CHANGE FLAG

LM2OP_PHASEA_LP:

PRE IX,GLOBAL_COUNTER
AD (IX+$31),$30
LD $2,(IX+$31)
AN $2,&H04

;
PHUW $1;①
;
SBC $1,$2;PUSH SPC KEYの表示のON/OFFが変わったか?
JR Z,PRINT_NO_CHANGE;変わっていなければ画面の更新は行わない
;
;$1の値が変更されたので①のPHUWを解放する
PPUW $0
;
;規定回数PUSH SPCKEYを表示したらDEMOへ移行
LD $1,$2
SB $0,$30
JP C,END_LM2OP_PA
;
;変更後のデータをPUSHする
PHUW $1;①'
;
SBC $1,$31
JR NZ,TITLE_KEY_DISP
;
;F-35&TITLE表示
F35_TITLE_DISP:
CAL CLS
CAL TITLE_DRAW
JR TITLE_KEY_REDRAW

TITLE_KEY_DISP:
;PUSH表示
LD $10,14
LD $11,2
LD $12,4;12
LDW $13,MES_PUSH_SPC
CAL TEXT

;SPC KEY表示
LD $10,12
LD $11,3
LD $12,8;12
LDW $13,MES_PUSH_SPC+4
CAL TEXT

TITLE_KEY_REDRAW:
LDW $28,DOTDS
CAL IOCS_CAL
;
PRINT_NO_CHANGE:
LDW $0,WAIT_KEY
CAL NORM_WAIT
;
;GAME START CHECK
LDW $28,INKEY
CAL IOCS_CAL
;
PPUW $0;①又は①’をPOPする
;
SBC $17,$31
JP Z,LM2OP_PHASEA_LP
LD $3,($15)
SBC $3,&H20;SPC
JP Z,GAME_START_INIT
SBC $3,&H4D;M
JP Z,MENU
SBC $3,&H6D;m
JP Z,MENU
;
JP LM2OP_PHASEA_LP

END_LM2OP_PA:
LDW $0,WAIT_KEY
CAL NORM_WAIT

PRE IX,PHASE
LDW $0,11
ST $0,(IX+$31)
ST $31,(IX+$30)
PRE IX,SECTION
STW $0,(IX+$31)
PRE IX,EXTRA
STW $0,(IX+$31)
JP NEXT_LM2OP

;*******************************************
;*          LM2OP_PHASEB
;*          DEMO
;*******************************************

LM2OP_PHASEB:

;デモモードに変更
PRE IX,ON_DEMO
ST $30,(IX+$31)

JP GAME_START_INIT

;デモでSPCを押してデモを終了した場合
END_DEMO:

;GPRINT表示エリアを最大化
PRE IX,GPRINT_XMAX
LD $0,191
ST $0,(IX+$31)
;
PRE IZ,PHASE
;
;ゲームモードに変更/通常終了 OR SPCキーによるBREAK判定
PRE IX,ON_DEMO
LD $0,(IX+$31)
SBC $0,2;SPCキーによるBREAK判定
ST $31,(IX+$31);ゲームモードに変更
JR Z,DEMO_BREAK_PH10
;通常終了ならオープニングを最初から実施
ST $31,(IZ+$31)
JP NEXT_LM2OP

;SPCキーによるBRAEK判定ならタイトル画面へ
DEMO_BREAK_PH10:
LD $0,10
ST $0,(IZ+$31)
JP NEXT_LM2OP

;**************************************************
;*      LM2OP_WAIT(キーを押したらTITLEへジャンプ)
;**************************************************
LM2OP_WAIT:
PHUW $1
LDW $28,INKEY
CAL IOCS_CAL
PPUW $0
SBC $17,$31
JR Z,LM2OP_WAIT_NOKEY
LD $3,($15)
SBC $3,&H20;SPC
JR Z,JUMP_TITLE
LM2OP_WAIT_NOKEY:
SBW $0,$30
JR NC,LM2OP_WAIT
RTN
JUMP_TITLE:
;
LDW $0,WAIT_KEY
CAL NORM_WAIT
;
PPSW $0;LM2OP_WAITをコールしたSSPを解放
;PHASE0～9ならPHASE10に移行
PRE IX,PHASE
LD $0,10;TITLE PHASE
ST $0,(IX+$31)
LD $0,$31
ST $0,(IX+$30)
PRE IX,SECTION
STW $0,(IX+$31)
PRE IX,EXTRA
STW $0,(IX+$31)
JP NEXT_LM2OP

;**************************************************
;*      NORM_WAIT(WAITのみ)
;**************************************************
NORM_WAIT:
PHUW $1
LDW $28,INKEY
CAL IOCS_CAL
PPUW $0
SBW $0,$30
JR NC,NORM_WAIT
RTN

#include (LM2_OP_BMP.TXT)
#include (DEMO_PROC.TXT)
#include (MENU.TXT)
