;*******************************
;* STAGE2 MAP DATA
;* LCD LINE0 DATA
;* LCD LINE1 DATA
;* LCD LINE2 DATA
;* LCD LINE3 DATA
;* EVENT NO
;*  EVENT NO &HFF - BOSS STAGE
;*******************************

INIT_DATA_STAGE2:
; INITIAL DATA(18POINT)
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,1,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,2,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,1,0,0

STAGE2_MAP:
DB NO_MAP_DATA;READY,ERASE
DB NO_MAP_DATA;START,ERASE
DB NO_MAP_DATA;READY START DISPLAY END
DB NO_MAP_DATA;GAME START
DB 1,0,0,0,0
;
DB 1,0,0,0,0
;DB 1,0,0,0,&HFF
DB 0,0,0,0,&HF2;群体発生コード
DB 0,0,0,0,1;群体SUPPLY(1-4)
DB 0,0,0,0,2;群体SUPPLY(5-6)
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 1,0,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,4,0
DB 0,0,0,0,&HF2;群隊発生コード
DB 0,0,0,0,3;群隊WEPON(1-4)
DB 0,0,0,0,4;群隊WEPON(5-6)
DB 0,0,2,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,3,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 1,0,0,0,0
DB 0,2,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,3,0
DB NO_MAP_DATA
DB 0,0,0,0,&HF2;群体発生コード
DB 0,0,0,0,5;群隊OPTION(1-4)
DB 0,0,1,0,6;群隊OPTION(5-6)
DB 0,0,2,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,3,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 1,0,0,0,0
DB 0,2,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,3,0
DB 0,0,0,0,&HF2;群体発生コード
DB 0,0,0,0,3;群隊WEPON(1-4)
DB 0,0,0,0,4;群隊WEPON(5-6)
DB 0,0,2,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,3,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 1,0,0,0,0
DB 0,2,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,3,0
DB NO_MAP_DATA
DB 0,0,0,0,&HF2;群体発生コード
DB 0,0,0,0,5;群隊OPTION(1-4)
DB 0,0,1,0,6;群隊OPTION(5-6)
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,2,0
DB 0,0,0,0,&HF0
DB NO_MAP_DATA
DB 0,0,2,0,7;3
DB NO_MAP_DATA
DB 0,0,0,0,8;4
DB NO_MAP_DATA
DB 7,5,0,0,0
DB 8,6,0,0,&HF2;群隊発生コード
DB 0,0,0,0,&HF0
DB 0,0,0,1,1;群隊(1-4)
DB 0,0,0,0,2;群隊(5-6)
DB 0,0,0,0,7;3
DB 0,0,0,0,8;4
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,2,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,&HF0
DB NO_MAP_DATA
DB 0,0,3,0,&HF1
DB NO_MAP_DATA
DB 0,1,0,0,0
DB 0,0,0,0,9;5
DB 0,0,0,0,10;6
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,4,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,&HF0
DB NO_MAP_DATA
DB 0,0,0,0,&HF1
DB NO_MAP_DATA
DB 3,0,0,0,0
DB 0,0,0,0,9;5
DB 0,0,0,0,10;6
DB NO_MAP_DATA
DB 0,0,7,5,0
DB 0,0,8,6,0
DB NO_MAP_DATA
DB 0,0,0,0,11;7
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 1,0,0,0,0
DB 0,0,0,0,12;8
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,13;9
DB 0,0,3,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,2,0,0,0
DB 0,0,0,0,11;7
DB NO_MAP_DATA
DB 0,0,1,0,0
DB 0,0,0,1,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 3,0,0,0,0
DB 0,0,0,4,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,1,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,2,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,&HFF ;BOSS

;******************************************************
;*              STAGE2 MAP CHARACTOR
;******************************************************
STAGE2_MAP_CHARA:
MAP2_CHR00:DB 0,0,0,0,0,0,0,0 ;無地背景
MAP2_CHR01:DB &H00,&H00,&H20,&H00,&H00,&H00,&H00,&H00 ;STAR1
MAP2_CHR02:DB &H00,&H00,&H00,&H00,&H00,&H00,&H04,&H00 ;STAR2
MAP2_CHR03:DB &H00,&H00,&H20,&H00,&H00,&H04,&H00,&H00 ;STAR3
MAP2_CHR04:DB &H02,&H00,&H00,&H10,&H38,&H10,&H00,&H00 ;STAR4
;PLANET1/4
MAP2_CHR05:DB &H03,&H0C,&H10,&H20,&H40,&H80,&H80,&H80
;PLANET2/4
MAP2_CHR06:DB &H80,&H80,&H80,&H41,&H40,&H20,&H18,&H07
;PLANET3/4
MAP2_CHR07:DB &HC0,&H30,&H4C,&H02,&H13,&H49,&H01,&H11
;PLANET4/4
MAP2_CHR08:DB &H05,&H01,&H01,&H02,&H14,&H04,&H18,&HE0

;******************************************************
;*              STAGE2 ENEMY CHARACTOR
;******************************************************
;CHR_ST2_01:DB &H66,&HA5,&HFF,&H24,&H24,&HFF,&HA5,&H66
CHR_ST2_02:DB &H3C,&H66,&HFF,&HBD,&HDB,&HFF,&H99,&H99
CHR_ST2_03:DB &H42,&HFF,&HDB,&H7E,&H66,&HDB,&HDB,&HFF
CHR_ST2_04:DB &H7E,&HBD,&HDB,&HE7,&HE7,&HDB,&HBD,&H7E
CHR_ST2_05:DB &H3C,&H42,&H81,&H81,&HA1,&H91,&H42,&H3C;WHITE BOMB

;******************************************************
;*              STAGE2 BOSS CHARACTOR
;******************************************************
CHR_BOSS2_CORE:;8*8
DB &H3C,&H7E,&HA5,&HE7,&H66,&H7E,&H99,&H66
CHR_BOSS2_UPPER:;16*8
DB &HE7,&HBD,&H57,&H2B,&H15,&H0A,&H05,&H0A
DB &H15,&H2B,&H57,&HBD,&HE0,&H01,&H02,&H03
CHR_BOSS2_TAIL:;8*8
DB &H5A,&H99,&H24,&H42,&H81,&H00,&H00,&H00
CHR_BOSS2_LOWER:;16*8
DB &HE7,&HBD,&HEA,&HD4,&HA8,&H50,&HA0,&H50
DB &HA8,&HD4,&HEA,&HBD,&H07,&H80,&H40,&HC0
CHR_BOSS2_FOOT:;8*8
DB &H7E,&HAB,&HD5,&HAB,&HD5,&HAB,&HD5,&H7E
CHR_BOSS2_HAND:;8*8
DB &H42,&H99,&HDB,&H7E,&HD5,&HAB,&HD5,&H7E
CHR_BOSS2_BEAM:;8*8
DB &HF0,&H90,&H90,&H90,&H90,&H90,&H90,&HF0
CHR_BOSS2_BEAM_U:;8*8
DB &H7F,&H80,&H80,&H7F,&H00,&H00,&H00,&H00
CHR_BOSS2_BEAM_C:;8*8
DB &HFF,&H00,&H00,&HFF,&H00,&H00,&H00,&H00
CHR_BOSS2_BEAM_L:;8*8
DB &HFE,&H01,&H01,&HFE,&H00,&H00,&H00,&H00

;******************************************************
;*              STAGE2 SENARIO INITIALIZE
;******************************************************
STAGE_2_INIT:
PRE IX,BASE_SENARIO_PTR
LDW $0,SCENARIO
STW $0,(IX+$31)

PRE IX,SCENARIO
LDW $0,ST2_SCENARIO_00 ;DUMMY
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_01
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_02
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_03
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_04
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_05
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_06
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_07
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_08
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_09
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_10
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_11
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_12
STIW $0,(IX+$31)
LDW $0,ST2_SCENARIO_13
STIW $0,(IX+$31)
;シナリオを16以上追加する場合はここを修正
RTN

;**********************************
;*    STAGE2 SCENARIO DATA
;*      (9BYTE:MAX64POINT)
;* 1:TIMING(出現タイミング+カウント(今回は1ドットスクロールなので0～7))
;* 2:ENEMY NO
;* 3:X
;* 4:Y
;* 5:LENGTH-X
;* 6:LENGTH-Y
;* 7:FREE
;* 8:FREE
;* 9:EXTRA
;* 10～18：0で自動初期化
;*
;*注意:1 必ず9BYTE定義すること
;*注意:2 10～18バイト目は自動的に0で初期化される
;*
;**********************************
ST2_SCENARIO_00: ;出現しない
ST2_SCENARIO_01:
DB 0,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 2,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 4,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 6,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB &HFF ;END CODE
ST2_SCENARIO_02:
DB 0,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 2,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB &HFF ;END CODE
ST2_SCENARIO_03:
DB 0,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 2,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 4,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 6,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB &HFF ;END CODE
ST2_SCENARIO_04:
DB 0,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 2,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB &HFF ;END CODE
ST2_SCENARIO_05:
DB 0,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 2,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 4,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 6,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB &HFF ;END CODE
ST2_SCENARIO_06:
DB 0,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 2,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB &HFF ;END CODE

ST2_SCENARIO_07:
DB 0,100,136,08,8,8,0,0,&H00,3,1
DB 2,100,136,16,8,8,0,0,&H00,3,1
DB 4,100,136,24,8,8,0,0,&H00,3,1
DB 6,100,136,32,8,8,0,0,&H00,3,1
DB &HFF ;END CODE
ST2_SCENARIO_08:
DB 0,101,4,08,8,8,0,0,&H00,4,1
DB 0,102,4,32,8,8,0,0,&H00,4,1
DB 2,101,4,08,8,8,0,0,&H00,4,1
DB 2,102,4,32,8,8,0,0,&H00,4,1
DB 4,101,4,08,8,8,0,0,&H00,4,1
DB 4,102,4,32,8,8,0,0,&H00,4,1
DB 6,101,4,08,8,8,0,0,&H00,4,1
DB 6,102,4,32,8,8,0,0,&H00,4,1
DB &HFF ;END CODE
ST2_SCENARIO_09:
DB 0,101,4,08,8,8,0,0,&H00,4,1
DB 0,102,4,32,8,8,0,0,&H00,4,1
DB 2,101,4,08,8,8,0,0,&H00,4,1
DB 2,102,4,32,8,8,0,0,&H00,4,1
DB 4,101,4,08,8,8,0,0,&H00,4,1
DB 4,102,4,32,8,8,0,0,&H00,4,1
DB 6,101,4,08,8,8,0,0,&H00,4,1
DB 6,102,4,32,8,8,0,0,&H00,4,1
DB &HFF ;END CODE

ST2_SCENARIO_10:
DB 0,103,80,32,8,8,0,0,&H0A,6,1;COUNTER1は弾を撃つカウンタ(0)で発射可能,2はフェーズ、強度10
DB &HFF ;END CODE

ST2_SCENARIO_11:
DB 0,104,144,08,8,8,0,0,&H00,7,1
DB 0,104,144,32,8,8,0,0,&H00,7,1
DB &HFF ;END CODE
ST2_SCENARIO_12:
DB 0,104,144,16,8,8,0,0,&H00,7,1
DB 0,104,144,32,8,8,0,0,&H00,7,1
DB &HFF ;END CODE
ST2_SCENARIO_13:
DB 0,104,144,08,8,8,0,0,&H00,7,1
DB 0,104,144,24,8,8,0,0,&H00,7,1
DB &HFF ;END CODE

;シナリオは64まで記述可だが今は16のみ
;16以上追加する場合はSTAGE_2_INITを修正


;*********************************
;*        ENEMY MOVE
;*
;*********************************
ST2_ENEMY_MOVE:

LD $28,$31

ST2_ENEMYMOVE_LP:
PRE IX,ENEMY_DATA
;
PHU $28
;
LDM $9,(IX+$28),8
SBC $9,$31
JR Z,NEXT_ST2_ENEMY_M

;-------- NOT ACTIVE FLAG(0) ------------------------------
;-------- 全ての衝突判定対象外のオブジェクト(001-089)(MAKE JUDGEで撥ねる)---
;-------- BULLET(89:固定) -----------------------------------
SBC $9,89
JR Z,ST2_ENEMY89_MOVE;BULLET
;-------- 自弾(GUN,LASER)と衝突判定を行わない敵オブジェクト(000-089)
;-------- DROP ITEM MOTHER(90)---------------------------------
SBC $9,90
JP Z,ST2_ENEMY90_MOVE;WAVE
;-------- BOSS CORE(99:固定) -----------------------------------
;-------- NORMAL(100-199)----------------------------------
SBC $9,100
JP Z,ST2_ENEMY100MOVE;STRAIGHT-3
SBC $9,101
JP Z,ST2_ENEMY101MOVE;CROSS-RETURN-ABOVE
SBC $9,102
JP Z,ST2_ENEMY102MOVE;CROSS-RETURN-UNDER
SBC $9,103
JP Z,ST2_ENEMY103MOVE;HARD-ROCK
SBC $9,104
JP Z,ST2_ENEMY104MOVE;WHITE_BOMB_ENEMY
;-----レーザーが衝突するとレーザーが縮む敵オブジェクト(200-229)---------------
;-----レーザーが衝突するとレーザーが縮む無敵の敵オブジェクト(230-255)(壁など)----

NEXT_ST2_ENEMY_M:
;
PPU $28
;
AD $28,ENEMY_STRUCT
JR NC,ST2_ENEMYMOVE_LP

RTN

ST2_ENEMY89_MOVE:;BULLET
CAL MOVE_BULLET
JP NEXT_ST2_ENEMY_M

ST2_ENEMY90_MOVE:;WAVE(各面に登場するため細部は別ファイルに分離)
CAL ENEMY_WAVE_MOVE
JP C,ST2_KILL_ENEMY
JP END_ST2ENEMYMOVE

ST2_ENEMY100MOVE:;STRAIGHT-3
;X移動
SB $10,2;X=X-2
;X<0ならオブジェクトを消す
JP C,ST2_KILL_ENEMY

;弾を撃ったことがあるなら、弾は発射しない(COUNTER1が0:撃ってない,1:発射済み)
SBC $14,$31
JP NZ,END_ST2ENEMYMOVE

PRE IZ,MY_FIGHTER
LDW $24,(IZ+$31) ;$24:MY_X $25:MY_Y

;敵X>自機Xなら敵弾は発射しない
SBC $10,$24
JP NC,END_ST2ENEMYMOVE

;発射フラグを設定する
LD $14,$30

;敵から見た自機の方向を算出
LDW $26,$10     ;$26:ENEMY_X $27:ENEMY_Y
CAL CALDIR      ;RETURN $5->DIR
CAL INSERT_BULLET
JP END_ST2ENEMYMOVE

ST2_ENEMY101MOVE:;CROSS-RETURN-ABOVE
;PHASE CHECK

SBC $15,$31;0
JR Z,ST2_ENEMY101_PH0
SBC $15,$30;1
JR Z,ST2_ENEMY101_PH1

ST2_ENEMY101_PH2:
SB $10,3    ;X-=3
SBC $10,5
JP NC,END_ST2ENEMYMOVE
JP ST2_KILL_ENEMY

ST2_ENEMY101_PH0:
AD $10,3    ;X+=3
SBC $10,100
JP C,END_ST2ENEMYMOVE
LD $15,$30;PHASE1へ移行
JP END_ST2ENEMYMOVE

ST2_ENEMY101_PH1:
SB $10,2    ;X-=2
AD $11,1    ;Y+=1
SBC $11,32
JP C,END_ST2ENEMYMOVE
LD $15,2;PHASE2へ移行

ST2_ENEMY102MOVE:;CROSS-RETURN-UNDER

;PHASE CHECK
SBC $15,$31;0
JR Z,ST2_ENEMY102_PH0
SBC $15,$30;1
JR Z,ST2_ENEMY102_PH1

ST2_ENEMY102_PH2:
SB $10,3    ;X-=3
SBC $10,5
JP NC,END_ST2ENEMYMOVE
JP ST2_KILL_ENEMY

ST2_ENEMY102_PH0:
AD $10,3    ;X+=3
SBC $10,100
JP C,END_ST2ENEMYMOVE
LD $15,$30;PHASE1へ移行
JP END_ST2ENEMYMOVE

ST2_ENEMY102_PH1:
SB $10,2    ;X-=2
SB $11,$30  ;Y-=1
SBC $11,9
JP NC,END_ST2ENEMYMOVE
LD $15,2;PHASE2へ移行
JP END_ST2ENEMYMOVE

ST2_ENEMY103MOVE:;HARD-ROCK

;敵弾を三回発射したら退場する
SBC $15,3
JR Z,ST2_ENEMY103_PH1

;敵弾発射カウンタが1以上ならカウンタを減じる
SBC $14,$31
JR Z,ST2_ENEMY103_BOK
SB $14,$30

ST2_ENEMY103_BOK:

PRE IZ,MY_Y
LD $0,(IZ+$31)
SBC $11,$0
;Y軸が自機と同じなら敵弾発射処理
JR Z,ST2_ENEMY103PH0F
;Y軸が自機より小さければY軸+移動
JR C,ST2_ENEMY103PH0P
;Y軸が自機より大きければY軸-移動
SB $11,$30
JP END_ST2ENEMYMOVE
ST2_ENEMY103PH0P:
AD $11,$30
JP END_ST2ENEMYMOVE

ST2_ENEMY103PH0F:
SBC $14,$31
JP NZ,END_ST2ENEMYMOVE

;敵弾発射ウエイトカウンタを初期化
LD $14,16
;敵弾発射回数カウンタを加算(3回撃つと退場)
AD $15,$30
;STM $9,(IX+$28),8
;;;;;敵弾発射処理を追加;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
LD $5,4 ;発射方向はテンキーの4の方向(固定)
PHU $11
AD $11,4;敵弾Y座標の補正
CAL INSERT_BULLET
PPU $11
JP END_ST2ENEMYMOVE;NEXT_ST2_ENEMY_M

ST2_ENEMY103_PH1:
SB $10,2
SBC $10,5
JP NC,END_ST2ENEMYMOVE
JP ST2_KILL_ENEMY

ST2_ENEMY104MOVE:;WHITE_BOMB_ENEMY
SB $10,$30
STM $9,(IX+$28),3
SBC $10,60
JP NC,END_ST2ENEMYMOVE
CAL DELETE_OBJECT;自爆する場合は直接DELETE_OBJECTを呼ぶ

LD $5,7;BULLET DIR
PHUW $11
CAL INSERT_BULLET
PPUW $10

LD $5,9;BULLET DIR
PHUW $11
CAL INSERT_BULLET
PPUW $10

LD $5,3;BULLET DIR
PHUW $11
CAL INSERT_BULLET
PPUW $10

LD $5,1;BULLET DIR
CAL INSERT_BULLET
JP NEXT_ST2_ENEMY_M

END_ST2ENEMYMOVE:
;DATA SAVE & MAKE JUDGE DATA
PRE IX,ENEMY_DATA
STM $9,(IX+$28),8
JP NEXT_ST2_ENEMY_M

ST2_KILL_ENEMY:
CAL DELETE_OBJECT
JP NEXT_ST2_ENEMY_M

;*********************************
;*        STAGE2 ENEMY DISP
;*********************************
ST2_ENEMY_DISP:

LD $28,$31

ST2_ENEMYDISP_LP:
PRE IX,ENEMY_DATA

LDM $9,(IX+$28),8
SBC $9,$31
JR Z,NEXT_ST2_ENEMY_D
;
PHU $28
;
;GPRINTのRTN命令でRTN_ST2_EDISPに戻れるようにするため、RTN_ST2_EDISPのアドレスを
;SSPにPUSHしておく。
;なおGPRINTからの復帰はRTNでありSSPにスタックされたアドレス+1からプログラムを実行するため
;RTN_ST2_EDISPのアドレスから-1したものをSSPにPUSHする。
LDW $0,RTN_ST2_EDISP-1
PHSW $1

;-------- NOT ACTIVE FLAG(0) ------------------------------
;-------- 全ての衝突判定対象外のオブジェクト(001-089)(MAKE JUDGEで撥ねる)---
;-------- BULLET(89:固定) -----------------------------------
SBC $9,89
JR Z,ST2_ENEMY89_DISP;BULLET
;-------- 自弾(GUN,LASER)と衝突判定を行わない敵オブジェクト(000-089)
;-------- DROP ITEM MOTHER(90)---------------------------------
SBC $9,90
JR Z,ST2_ENEMY90_DISP;WAVE
;-------- BOSS CORE(99:固定) -----------------------------------
;-------- NORMAL(100-199)----------------------------------
SBC $9,100
JP Z,ST2_ENEMY100DISP;STRAIGHT-3
SBC $9,101
JP Z,ST2_ENEMY101DISP;CROSS-RETURN-ABOVE
SBC $9,102
JP Z,ST2_ENEMY102DISP;CROSS-RETURN-UNDER
SBC $9,103
JP Z,ST2_ENEMY103DISP;HARD-ROCK
SBC $9,104
JP Z,ST2_ENEMY104DISP;WHITE_BOMB_ENEMY
;-----レーザーが衝突するとレーザーが縮む敵オブジェクト(200-229)---------------
;-----レーザーが衝突するとレーザーが縮む無敵の敵オブジェクト(230-255)(壁など)----

;JUMPしなかった場合はSSPを戻す。
PPSW $0

RTN_ST2_EDISP:
;
PPU $28
;
NEXT_ST2_ENEMY_D:

AD $28,ENEMY_STRUCT

JR NC,ST2_ENEMYDISP_LP

RTN

ST2_ENEMY90_DISP:;WAVE
JP ENEMY_WAVE_DISP

ST2_ENEMY89_DISP:;BULLET
LDW $13,@CHR_BULLET
LD $12,4
JP SGPRINT_4

ST2_ENEMY100DISP:;STRAIGHT-3
LDW $13,SG_CHR_DATA07
JP SGPRINT_FAST

ST2_ENEMY101DISP:;CROSS-RETURN-ABOVE
ST2_ENEMY102DISP:;CROSS-RETURN-UNDER
LDW $13,SG_CHR_DATA09
JP SGPRINT_FAST

ST2_ENEMY103DISP:;HARD-ROCK
LDW $13,SG_CHR_DATA08
JP SGPRINT_FAST

ST2_ENEMY104DISP:;WHITE_BOMB_ENEMY
LDW $13,SG_CHR_DATA10
JP SGPRINT_FAST

;*********************************
;*          BOSS2 INIT
;*  +0($9)  種類(0:未使用フラグ,&H01～&HFF)
;*  +1($10)  x(必須)
;*  +2($11)  y(必須)
;*  +3($12)  キャラのXサイズ
;*  +4($13)  キャラのYサイズ
;*  +5($14)  COUNTER1
;*  +6($15)  COUNTER2
;*  +7($16)  LIFE(Cフラグで破壊)
;*  +8($17)  SCORE
;*  +9($18)  DAMAGE
;**********************************
;NOTE
;
;BOSS2は2つのパーツで構成されている。
;PARTS Noは次のとおり
;
;   UH  UF3 UF2 UF1
;   233.232.232,232
;               230.230
;                099.231 <- 099:CORE
;               230,230
;   233.232.232,232
;   LH  LF3 LF2 LF1
;
;動作の際は下記の各パーツのインデックスアドレスを
;直接指定してXを参照、変更している。
;
; 0:ENEMY_DATA_0 = 099:BOSS2 CORE           +0
; 1:ENEMY_DATA_1 = 230:BOSS2 UPPER          +16
; 2:ENEMY_DATA_2 = 231:BOSS2 TAIL           +32
; 3:ENEMY_DATA_3 = 230:BOSS2 LOWER          +48
; 4:ENEMY_DATA_4 = 232:BOSS2 UPPER FOOT_1   +64
; 5:ENEMY_DATA_5 = 232:BOSS2 UPPER FOOT_2   +80
; 6:ENEMY_DATA_6 = 232:BOSS2 UPPER FOOT_3   +96
; 7:ENEMY_DATA_7 = 233:BOSS2 UPPER HAND     +112
; 8:ENEMY_DATA_8 = 234:BOSS2 LOWER FOOT_1   +128
; 9:ENEMY_DATA_9 = 234:BOSS2 LOWER FOOT_2   +144
; A:ENEMY_DATA_A = 234:BOSS2 LOWER FOOT_3   +160
; B:ENEMY_DATA_B = 235:BOSS2 LOWER HAND     +176
;
; 50:BOSS2 BEAM
; 51:BOSS2 WIDE BEAM CENTER
; 52:BOSS2 WIDE BEAM UPPER
; 53:BOSS2 WIDE BEAM LOWER

BOSS2_DATA:
BOSS2_DATA_CORE:
DB 099,172,20,08,08,000,00,&H0A,00,&HFF,0,0,0,0,0,0     ;CORE
BOSS2_DATA_UPPER:
DB 230,169,12,16,08,000,00,&HFF,00,&HFF,0,0,0,0,0,0     ;UPPER
BOSS2_DATA_TAIL:
DB 231,180,20,08,08,000,00,&HFF,00,&HFF,0,0,0,0,0,0     ;TAIL
BOSS2_DATA_LOWER:
DB 230,169,28,16,08,000,00,&HFF,00,&HFF,0,0,0,0,0,0     ;LOWER
BOSS2_UP_FOOT1:
DB 232,162,14,08,08,255,32,&HFF,00,&HFF,0,0,0,0,0,0     ;UP_FOOT1
BOSS2_UP_FOOT2:
DB 232,156,14,08,08,255,32,&HFF,00,&HFF,0,0,0,0,0,0     ;UP_FOOT2
BOSS2_UP_FOOT3:
DB 232,150,14,08,08,255,32,&HFF,00,&HFF,0,0,0,0,0,0     ;UP_FOOT3
BOSS2_UP_HAND:
DB 233,144,14,08,08,255,32,&HFF,00,&HFF,0,0,0,0,0,0     ;UP_HAND
BOSS2_LW_FOOT1:
DB 232,162,26,08,08,255,32,&HFF,00,&HFF,0,0,0,0,0,0     ;LW_FOOT1
BOSS2_LW_FOOT2:
DB 232,156,26,08,08,255,32,&HFF,00,&HFF,0,0,0,0,0,0     ;LW_FOOT2
BOSS2_LW_FOOT3:
DB 232,150,26,08,08,255,32,&HFF,00,&HFF,0,0,0,0,0,0     ;LW_FOOT3
BOSS2_LW_HAND:
DB 233,144,26,08,08,255,32,&HFF,00,&HFF,0,0,0,0,0,0     ;LW_HAND
BOSS2_DATA_END:


BOSS2_DATA_NUM:EQU 12;BOSS2のパーツ数

BOSS2_INIT:

;RXCNT
;ENEMY_DATA初期化
LDW $0,ENEMY_DATA
LDW $2,&H0FF
LDW $28,CLEME
CAL IOCS_CAL

CAL OBJECT_ARRAY_INI

;******************* BOSSデータのブロック転送*********
;BOSS1を構成する位置データ等を転送
PRE IX,BOSS2_DATA
PRE IZ,ENEMY_DATA
PRE IY,BOSS2_DATA_END-1
BUP

;OBJECT_ARRAY POINTERをBOSS2のパーツ数に変更
PRE IX,OBJECT_ARRAY+16;OBJECT_ARRAY POINTER
LD $0,&H0F-BOSS2_DATA_NUM
ST $0,(IX+$31)
;**********************************************

;転送したBOSSデータを実体化する
CAL INSERT_OBJECT_ON

;ボス戦闘中フラグをONにする。
PRE IX,NOW_BOSS_FIGHT
ST $30,(IX+$31)
;ボス破壊フラグをOFFにする。
PRE IX,BOSS_DESTROY
ST $31,(IX+$31)
;ボスのデータ数(BOSS2:9)を設定にする。
PRE IX,BOSS_DATA_NUM
LD $0,BOSS2_DATA_NUM
ST $0,(IX+$31)

;SUPER GPRINT DATA MAKE(BOSS用)
CAL ST2_INIT_GRA_B

RTN

;************************************
;*              BOSS2 PRE
;*  (BOSS2 MOVE STANBY POSITION)
;************************************
BOSS2_PRE:

;BOSS2移動(X=X-1)
LD $0,&HFF
LD $1,$31
LD $29,BOSS2_DATA_NUM
CAL MOVE_BOSS_ALL

CAL BOSS2_MOVE_TAIL

;BOSS1(CORE)のX座標
LD $0,(IX+$30)

;BOSS2のX座標が100になったらボス戦に突入
SBC $0,100
RTN NC

PRE IX,PHASE
LD $0,3
ST $0,(IX+$31) ;PHASE2->3
ST $31,(IX+$30) ;PHASE_COUNTER->0
RTN

;************************
;*  BOSS2の足を動かす
;************************
BOSS2_MOVE_TAIL:

LD $23,17
LDW $24,(IX+$23);$24:UPPER_X,$25:UPPER_Y
LD $23,49
LDW $26,(IX+$23);$26:LOWER_X,$27:LOWER_Y

PRE IZ,USER_WORK
LD $19,(IZ+$31);ANGLE

CAL ANS_SIN16;$0 - 符号付SIN($8)*16

AD $19,$30
SBC $19,36
JR C,ANGLE_SAFE
LD $19,$31
ANGLE_SAFE:
PRE IZ,USER_WORK
ST $19,(IZ+$31)

;HAND
PHU $27;LOWER Y
PHU $25;UPPER Y
PHU $0;SIN
;UPPER
;X
SB $24,24
;Y
AD $25,$0
LD $21,113
STW $24,(IX+$21);UPPER HAND
;LOWER
;X
SB $26,24
;Y
SB $27,$0
LD $22,177
STW $26,(IX+$22);UPPER LOWER HAND
PPU $0;SIN
PPU $25;UPPER Y
PPU $27;LOWER Y

;FOOT3
CAL FOOT_MOVE
;FOOT2
CAL FOOT_MOVE
;FOOT1

FOOT_MOVE:

;SINがマイナスなら符号を反転する
ANC $0,&H80
JR Z,BOSS2_SIN_PLUS
CMP $0
BID $0
CMP $0
JR END_SIN_CHECK
BOSS2_SIN_PLUS:
BID $0
END_SIN_CHECK:

PHU $27;UPPER Y
PHU $25;LOWER Y
PHU $0;SIN
;UPPER
;X
AD $24,6
;Y
AD $25,$0
SB $21,16
STW $24,(IX+$21);UPPER HAND
;LOWER
;X
AD $26,6
;Y
SB $27,$0
SB $22,16
STW $26,(IX+$22);LOWER HAND

PPU $0
PPU $25
PPU $27

RTN

;************************
;*  BOSS2本体を円状に動かす
;************************
BOSS2_MOVE_BODY:

LD $19,$14

CAL ANS_SIN8;$0 - 符号付SIN($8)*8
PHU $0
CAL ANS_COS8;$0 - 符号付COS($8)*8
PPU $1

;$0=Xの変化量
;$1=Yの変化量

LD $2,49;LOWER->TAIL->UPPER->COREの順のため+49
;BOSS LOWERが登場して停止した位置のX,Y
LD $10,97-8;登場時COS0(+8)となるため、Xを-8する
LD $11,28
;
AD $10,$0
AD $11,$1
STW $10,(IX+$2)

;BOSS TAILが登場して停止した位置のX,Y
LD $10,108-8;登場時COS0(+8)となるため、Xを-8する
LD $11,20
;
AD $10,$0
AD $11,$1
SB $2,16
STW $10,(IX+$2)

;BOSS UPPERが登場して停止した位置のX,Y
LD $10,97-8;登場時COS0(+8)となるため、Xを-8する
LD $11,12
;
AD $10,$0
AD $11,$1
SB $2,16
STW $10,(IX+$2)

;BOSS COREが登場して停止した位置のX,Y
LD $10,100-8;登場時COS0(+8)となるため、Xを-8する
LD $11,20
;
AD $10,$0
AD $11,$1
SB $2,16
STW $10,(IX+$2)

AD $14,$30
SBC $14,36
RTN C
LD $14,$31
RTN

;*********************************
;*          MOVE BOSS2
;*
;*USE:
;*      $0      WORK
;*      $2,$3   JUMP TABLE
;*      $9-$16  ENEMY DATA
;*      $28     COUNTER
;*      IX
;*      IZ
;*********************************
MOVE_BOSS2:

LD $28,$31

MOVE_BOSS2_LOOP:
PHU $28
PRE IX,ENEMY_DATA

LDM $9,(IX+$28),8

;-------- NOT ACTIVE FLAG(0) ------------------------------
;-------- 全ての衝突判定対象外のオブジェクト(001-089)(MAKE JUDGEで撥ねる)---
SBC $9,80
JP Z,BOSS2_P80_MOVE;BEAM
SBC $9,81
JP Z,BOSS2_P81_MOVE;WIDE BEAM UPPER
SBC $9,82
JP Z,BOSS2_P82_MOVE;WIDE BEAM CENTER
SBC $9,83
JP Z,BOSS2_P83_MOVE;WIDE BEAM LOWER
;-------- BULLET(89:固定) -----------------------------------
;-------- 自弾(GUN,LASER)と衝突判定を行わない敵オブジェクト(000-089)
;-------- DROP ITEM MOTHER(90)---------------------------------
;-------- BOSS CORE(99:固定) -----------------------------------
SBC $9,99
JR Z,BOSS2_P99_MOVE
;-------- NORMAL(100-199)----------------------------------
;-----レーザーが衝突するとレーザーが縮む敵オブジェクト(200-229)---------------
;-----レーザーが衝突するとレーザーが縮む無敵の敵オブジェクト(230-255)(壁など)----


NEXT_MOVE_BOSS2:
PPU $28
AD $28,ENEMY_STRUCT
JR NC,MOVE_BOSS2_LOOP

RTN

BOSS2_P08_MOVE:
CAL MOVE_BULLET
JR NEXT_MOVE_BOSS2

BOSS2_P99_MOVE:
CAL BOSS2_MOVE_BODY
CAL BOSS2_MOVE_TAIL

PRE IZ,SECTION
LDM $0,(IZ+$31),2;$0:SECTION $1:SECTION_COUNTER

SBC $0,$31
JR Z,BOSS2_P99_SEC0
SBC $0,$30
JP Z,BOSS2_P99_SEC1
SBC $0,2
JP Z,BOSS2_P99_SEC2
SBC $0,3
JP Z,BOSS2_P99_SEC3
SBC $0,4

BOSS2_P99_SEC0:
AD $15,$30
SBC $15,16
JP C,END_BOSS2_MOVE
;END BOSS2 P99 SECTION0
LD $15,$31
LD $0,$30;SECTION->1
LD $1,$31;SECTION COUNTER -> 0
PRE IZ,SECTION
STM $0,(IZ+$31),2
JP END_BOSS2_MOVE

BOSS2_P99_SEC1:

PRE IZ,MY_Y
LD $0,(IZ+$31)

LD $5,113
LDW $1,(IX+$5);UPPER HAND X,Y
LD $5,177
LDW $3,(IX+$5);LOWER HAND X,Y

SBC $0,$2
JR Z,BOSS2_HAND_FIRE
SBC $0,$4
JR NZ,BOSS2_P99_NOFIRE

BOSS2_HAND_FIRE:
PRE IZ,BOSS2_P99BEAM
LDIM $17,(IZ+$31),8
LDM $25,(IZ+$31),2
;UPPER HAND FIRE
LDW $18,$1
AD $19,4
CAL INSERT_OBJECT;IX破壊
;LOWER HAND FIRE
LDW $18,$3
AD $19,4
CAL INSERT_OBJECT;IX破壊
JP END_BOSS2P99SEC1

BOSS2_P99_NOFIRE:

AD $15,$30
SBC $15,32
JP C,END_BOSS2_MOVE
END_BOSS2P99SEC1:
;END BOSS2 P99 SECTION1
LD $15,$31
LD $0,2;SECTION->2
LD $1,$31;SECTION COUNTER -> 0
PRE IZ,SECTION
STM $0,(IZ+$31),2
JP END_BOSS2_MOVE

BOSS2_P99_SEC2:
AD $15,$30
SBC $15,32
JP C,END_BOSS2_MOVE
LD $15,$31

;END BOSS2 P99 SECTION2
LD $15,$31
LD $0,3;SECTION->3
LD $1,$31;SECTION COUNTER -> 0
PRE IZ,SECTION
STM $0,(IZ+$31),2
JP END_BOSS2_MOVE

BOSS2_P99BEAM:
DB 80,0,0,8,4,0,0,&HFF,0,1;ビーム
BOSS2_P99WBEAM:
DB 81,0,0,4,8,0,0,&HFF,0,1;拡大ビーム

BOSS2_P99_SEC3:
PRE IZ,BOSS2_P99WBEAM
LDIM $17,(IZ+$31),8
LDM $25,(IZ+$31),2
LD $18,$10
;AD $18,4
LD $19,$11
;SB $19,4
CAL INSERT_OBJECT;IX破壊

LD $17,82;CENTER
CAL INSERT_OBJECT;IX破壊

LD $17,83;LOWER
CAL INSERT_OBJECT;IX破壊

;END BOSS2 P99 SECTION3
LD $0,0;SECTION->0
LD $1,$31;SECTION COUNTER -> 0
PRE IZ,SECTION
STM $0,(IZ+$31),2
JP END_BOSS2_MOVE

BOSS2_P80_MOVE:         ;BEAM
CAL BOSS2_WBEAM_MOVE
JP END_BOSS2_MOVE

BOSS2_P81_MOVE:         ;WIDE BEAM UPPER
CAL BOSS2_WBEAM_MOVE
AD $14,$30
SBC $14,4
JP C,END_BOSS2_MOVE
SB $11,$30
LD $14,$31;COUNTER RESET
JP END_BOSS2_MOVE

BOSS2_P82_MOVE:         ;WIDE BEAM CENTER
CAL BOSS2_WBEAM_MOVE
JP END_BOSS2_MOVE

BOSS2_P83_MOVE:         ;WIDE BEAM LOWER
CAL BOSS2_WBEAM_MOVE
AD $14,$30
SBC $14,4
JP C,END_BOSS2_MOVE
AD $11,$30
LD $14,$31;COUNTER RESET
JP END_BOSS2_MOVE

BOSS2_WBEAM_MOVE:
SB $10,3
RTN NC
PPSW $0;CALLで呼ばれたスタックを解放
JP ST2_KILL_BOSS

;**********************
;*      ANS SIN 16
;*PARA $19 - ANGLE(0-35)
;*RTN  $0  - 符号付SIN($8)*16
;***********************
ANS_SIN16:
SBC $19,36
JR C,CALC_SIN16
LD $19,$31
CALC_SIN16:
PRE IZ,@SIN_TABLE16
LD $0,(IZ+$19)
RTN

;**********************
;*      ANS SIN 8
;*PARA $19 - ANGLE(0-35)
;*RTN  $0  - 符号付SIN($8)*8
;***********************
ANS_SIN8:
SBC $19,36
JR C,CALC_SIN8
LD $19,$31
CALC_SIN8:
PRE IZ,@SIN_TABLE8
LD $0,(IZ+$19)
RTN

;**********************
;*      ANS COS 8
;*PARA $19 - ANGLE(0-35)
;*RTN  $0  - 符号付COS($8)*8
;***********************
ANS_COS8:
SBC $19,36
JR C,CALC_COS8
LD $19,$31
CALC_COS8:
PRE IZ,@COS_TABLE8
LD $0,(IZ+$19)
RTN

;R=16
@SIN_TABLE16:
DB 0,3,5,8,10,12,13,14,15                       ;SIN0-80
@COS_TABLE16:
DB 16,15,14,13,12,10,8,5,3                      ;SIN90-170  ,COS0-80
DB 0,&HFD,&HFB,&HF8,&HF6,&HF4,&HF3,&HF2,&HF1    ;SIN180-260 ,COS90-170
DB &HF0,&HF1,&HF2,&HF3,&HF4,&HF6,&HF8,&HFB,&HFD ;SIN270-350 ,COS180-260
;@SIN END
DB 0,3,5,8,10,12,13,14,15                      ;          ,COS270-350
;@COS END

;R=8
@SIN_TABLE8:
DB 0,1,3,4,6,7,7,8,8                       ;SIN0-80
@COS_TABLE8:
DB 8,8,8,7,7,6,4,3,1                      ;SIN90-170  ,COS0-80
DB 0,&HFF,&HFD,&HFC,&HFA,&HF9,&HF9,&HF8,&HF8    ;SIN180-260 ,COS90-170
DB &HF8,&HF8,&HF8,&HF9,&HF9,&HFA,&HFC,&HFD,&HFF ;SIN270-350 ,COS180-260
;@SIN END
DB 0,1,3,4,6,7,7,8,8
;COS270-350
;@COS END

ST2_KILL_BOSS:
CAL DELETE_OBJECT
JP NEXT_MOVE_BOSS2

END_BOSS2_MOVE:
PRE IX,ENEMY_DATA
STM $9,(IX+$28),8
JP NEXT_MOVE_BOSS2

;*********************************
;*        DISP BOSS2
;*
;*USE:
;*      $0      WORK
;*      $2,$3   JUMP TABLE
;*      $9-$16  ENEMY DATA
;*      $28     COUNTER
;*      IX
;*      IZ
;*********************************
DISP_BOSS2:
LD $28,$31

DISP_BOSS2_LOOP:

PRE IX,ENEMY_DATA

LDM $9,(IX+$28),8
SBC $9,$31
JR Z,NEXT_DISP_BOSS2
;
PHU $28
;
;GPRINTのRTN命令でRTN_ST2_DBOSS2に戻れるようにするため、RTN_ST2_DBOSS2のアドレスを
;SSPにPUSHしておく。
;なおGPRINTからの復帰はRTNでありSSPにスタックされたアドレス+1からプログラムを実行するため
;RTN_ST2_DBOSS2のアドレスから-1したものをSSPにPUSHする。
LDW $0,RTN_ST2_DBOSS2-1
PHSW $1

SBC $9,80
JR Z,BOSS2_P080_DISP;BOSS2 BEAM
SBC $9,81
JR Z,BOSS2_P081_DISP;BOSS2 WIDE BEAM UPPER
SBC $9,82
JP Z,BOSS2_P082_DISP;BOSS2 WIDE BEAM CENTER
SBC $9,83
JP Z,BOSS2_P083_DISP;BOSS2 WIDE BEAM LOWER
SBC $9,89;BULLETは89固定
JR Z,BOSS2_P089_DISP;BULLET
SBC $9,99
JR Z,BOSS2_P099_DISP;BOSS2 CORE
SBC $9,232
JP Z,BOSS2_P232_DISP;BOSS2 FOOT UPPER
SBC $9,233
JP Z,BOSS2_P233_DISP;BOSS2 HAND UPPER

;JUMPしなかった場合はSSPを戻す。
PPSW $0

RTN_ST2_DBOSS2:

;
PPU $28
;
NEXT_DISP_BOSS2:
AD $28,ENEMY_STRUCT
JR NC,DISP_BOSS2_LOOP
RTN

BOSS2_P080_DISP:
LD $12,8
LDW $13,SG_CHR_DATA14;CHR_BOSS1_BEAM
JP SGPRINT_FAST

BOSS2_P081_DISP:
LD $12,8
LDW $13,SG_CHR_DATA15;BOSS2 WIDE BEAM UPPER
JP SGPRINT_FAST

BOSS2_P082_DISP:
LD $12,8
LDW $13,SG_CHR_DATA16;BOSS2 WIDE BEAM CENTER
JP SGPRINT_FAST

BOSS2_P083_DISP:
LD $12,8
LDW $13,SG_CHR_DATA17;BOSS2 WIDE BEAM LOWER
JP SGPRINT_FAST

BOSS2_P089_DISP:;BULLET
LDW $13,@CHR_BULLET
LD $12,4
JP SGPRINT_4

BOSS2_P099_DISP:
PHUW $11
LD $12,8
LDW $13,SG_CHR_DATA06;BOSS1_CORE
CAL SGPRINT_FAST
PPUW $10

PHUW $11
LD $12,8
SB $10,3
SB $11,8
LDW $13,SG_CHR_DATA07;CHR_BOSS1_UPPER_1_2
CAL SGPRINT_FAST
PPUW $10

PHUW $11
LD $12,8
AD $10,3
SB $11,8
LDW $13,SG_CHR_DATA08;CHR_BOSS1_UPPER_2_2
CAL SGPRINT_FAST
PPUW $10

PHUW $11
LD $12,8
AD $10,8
LDW $13,SG_CHR_DATA09;CHR_BOSS1_TAIL
CAL SGPRINT_FAST
PPUW $10

PHUW $11
LD $12,8
SB $10,3
AD $11,8
LDW $13,SG_CHR_DATA10;CHR_BOSS1_LOWER_1_2
CAL SGPRINT_FAST
PPUW $10

LD $12,8
AD $10,3
AD $11,8
LDW $13,SG_CHR_DATA11;CHR_BOSS1_LOWER_2_2
JP SGPRINT_FAST

BOSS2_P232_DISP:
LD $12,8
LDW $13,SG_CHR_DATA12;CHR_BOSS1_FOOT
JP SGPRINT_FAST

BOSS2_P233_DISP:
LD $12,8
LDW $13,SG_CHR_DATA13;CHR_BOSS1_HAND
JP SGPRINT_FAST


;**********************************
;*      BOSS2撃破時の処理
;**********************************
BOSS_DEF_ST2:

;RTN CODE 0:継続をセット
LD $5,$31

;下へ降下
LD $0,$31
LD $28,2
LD $29,BOSS2_DATA_NUM

PRE IX,ENEMY_DATA
BOSS2_ALL_MV_LP:
AD (IX+$28),$30
AD $28,16
SB $29,$30
JR NZ,BOSS2_ALL_MV_LP

PRE IX,EXTRA_COUNTER
AD (IX+$31),$30
LD $0,56
SBC (IX+$31),$0
RTN NZ

;RTN CODE 1:次のフェーズに移行をセット
LD $5,$30
RTN

;**********************************
;*      ST2_INIT_GRAPHIC
;**********************************

ST2_INIT_GRA_S:
LDW $0,0;自機
LDW $2,CHR_FIGHTER
CAL SET_SGPRINT_DATA

LDW $0,1;MY BOMB L
LDW $2,CHR_BOMB_L
CAL SET_SGPRINT_DATA

LDW $0,2;MY_BOMB_R
LDW $2,CHR_BOMB_R
CAL SET_SGPRINT_DATA

LDW $0,3;FIGHTER_SHADOW
LDW $2,CHR_OPTION
CAL SET_SGPRINT_DATA

;NO4 RESERVE
;LDW $0,4
;LDW $2,CHR_OPTION
;CAL SET_SGPRINT_DATA

;NO5 RESERVE
;LDW $0,5
;LDW $2,CHR_OPTION
;CAL SET_SGPRINT_DATA

;ENEMY_WAVE固定

LDW $0,6
LDW $2,CHR_STA_WAVE
CAL SET_SGPRINT_DATA

;ENEMY
LDW $0,7
LDW $2,CHR_ST2_02;STRAIGHT-3
CAL SET_SGPRINT_DATA

LDW $0,8
LDW $2,CHR_ST2_03;HARD-ROCK
CAL SET_SGPRINT_DATA

LDW $0,9
LDW $2,CHR_ST2_04;CROSS-RETURN-ABOVE
CAL SET_SGPRINT_DATA

LDW $0,10;WHITE_BOMB;WHITE_BOMB_ENEMY
LDW $2,CHR_ST2_05
CAL SET_SGPRINT_DATA

;LDW $0,11;BOSS
;LDW $2,CHR_BOSS2_6_1
;CAL SET_SGPRINT_DATA

;LDW $0,12;BOSS
;LDW $2,CHR_BOSS2_6_2
;CAL SET_SGPRINT_DATA

;LDW $0,13;BOSS
;LDW $2,CHR_BOSS2_7_1
;CAL SET_SGPRINT_DATA

;LDW $0,14;BOSS
;LDW $2,CHR_BOSS2_7_2
;CAL SET_SGPRINT_DATA

RTN

ST2_INIT_GRA_B:
;BOSS
LDW $0,6;BOSS2 CORE
LDW $2,CHR_BOSS2_CORE
CAL SET_SGPRINT_DATA

LDW $0,7;CHR_BOSS2_UPPER_1_2
LDW $2,CHR_BOSS2_UPPER
CAL SET_SGPRINT_DATA

LDW $0,8;CHR_BOSS2_UPPER_2_2
LDW $2,CHR_BOSS2_UPPER+8
CAL SET_SGPRINT_DATA

LDW $0,9;CHR_BOSS2_TAIL
LDW $2,CHR_BOSS2_TAIL
CAL SET_SGPRINT_DATA

LDW $0,10;CHR_BOSS2_LOWER_1_2
LDW $2,CHR_BOSS2_LOWER
CAL SET_SGPRINT_DATA

LDW $0,11;CHR_BOSS2_LOWER_2_2
LDW $2,CHR_BOSS2_LOWER+8
CAL SET_SGPRINT_DATA

LDW $0,12;CHR_BOSS2_FOOT
LDW $2,CHR_BOSS2_FOOT
CAL SET_SGPRINT_DATA

LDW $0,13;CHR_BOSS2_HAND
LDW $2,CHR_BOSS2_HAND
CAL SET_SGPRINT_DATA

LDW $0,14;;BOSS2 BEAM
LDW $2,CHR_BOSS2_BEAM
CAL SET_SGPRINT_DATA

LDW $0,15;BOSS2 WIDE BEAM UPPER
LDW $2,CHR_BOSS2_BEAM_U
CAL SET_SGPRINT_DATA

LDW $0,16;BOSS2 WIDE BEAM CENTER
LDW $2,CHR_BOSS2_BEAM_C
CAL SET_SGPRINT_DATA

LDW $0,17;BOSS2 WIDE BEAM LOWER
LDW $2,CHR_BOSS2_BEAM_L
CAL SET_SGPRINT_DATA
RTN

SET_STAGE2_DATA:
;STAGE2の初期化サブルーチンのアドレス
LDW $0,STAGE_2_INIT
PRE IX,STAGE_INIT
STW $0,(IX+$31)
;STAGE2のマップデータのアドレス
LDW $0,STAGE2_MAP
PRE IX,STAGE_MAP
STW $0,(IX+$31)
;STAGE2のマップに登場する背景キャラクタのデータのアドレス
LDW $0,STAGE2_MAP_CHARA
PRE IX,STAGE_MAP_CHARA
STW $0,(IX+$31)
;STAGE2に登場するの敵のキャラクタデータのアドレス
LDW $0,INIT_DATA_STAGE2
PRE IX,INIT_DATA_STAGE
STW $0,(IX+$31)
;STAGE2の敵の移動サブルーチンのアドレス
LDW $0,ST2_ENEMY_MOVE
PRE IX,ENEMY_MOVE_ADR
STW $0,(IX+$31)
;STAGE2の敵の表示サブルーチンのアドレス
LDW $0,ST2_ENEMY_DISP
PRE IX,ENEMY_DISP_ADR
STW $0,(IX+$31)
;BOSS2初期化サブルーチンのアドレス
LDW $0,BOSS2_INIT
PRE IX,BOSS_INIT_ADR
STW $0,(IX+$31)
;BOSS2登場時の動作サブルーチンのアドレス
LDW $0,BOSS2_PRE
PRE IX,BOSS_PRE_ADR
STW $0,(IX+$31)
;BOSS2移動サブルーチンのアドレス
LDW $0,MOVE_BOSS2
PRE IX,BOSS_MOVE_ADR
STW $0,(IX+$31)
;BOSS2表示サブルーチンのアドレス
LDW $0,DISP_BOSS2
PRE IX,BOSS_DISP_ADR
STW $0,(IX+$31)
;BOSS2の名前が格納されたアドレス
PRE IX,MES_NAME_BOSS2
LDM $0,(IX+$31),8
PRE IX,BOSS_NAME
STM $0,(IX+$31),8
;
;SUPER GPRINT DATA MAKE
CAL ST2_INIT_GRA_S

RTN

