;*******************************
;* STAGE3 MAP DATA
;* LCD LINE0 DATA
;* LCD LINE1 DATA
;* LCD LINE2 DATA
;* LCD LINE3 DATA
;* EVENT NO
;*  EVENT NO &HFF - BOSS STAGE
;*******************************

INIT_DATA_STAGE3:
; INITIAL DATA(18POINT)
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,1,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,2,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,0,0,0
DB 0,0,1,0,0

STAGE3_MAP:
DB NO_MAP_DATA;READY,ERASE
DB NO_MAP_DATA;START,ERASE
DB NO_MAP_DATA;READY START DISPLAY END
DB NO_MAP_DATA;GAME START
;POWER UP AREA
DB 0,0,0,0,0
DB 0,0,0,0,&HF2;群体発生コード
DB 0,0,0,0,1;群体SUPPLY(1-4)
DB 0,0,0,0,2;群体SUPPLY(5-6)
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 1,0,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,4,0
DB 0,0,0,0,&HF2;群隊発生コード
DB 0,0,0,0,3;群隊WEPON(1-4)
DB 0,0,0,0,4;群隊WEPON(5-6)
DB 0,0,2,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,3,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 1,0,0,0,0
DB 0,2,0,0,0

DB NO_MAP_DATA
DB 0,0,0,3,0;&HFF
DB 0,0,0,0,21;15
DB 0,4,0,0,0
DB NO_MAP_DATA
DB 1,0,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,2,21;15
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 1,0,0,0,0
DB 0,0,3,0,0
DB NO_MAP_DATA
;METEOR AREA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,7;1
DB NO_MAP_DATA
DB 1,0,0,0,0
DB 0,0,0,0,8;2
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,4,9;3
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,2,0,10;4
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,3,0,0,0
DB 0,0,0,0,11;5
DB NO_MAP_DATA
DB 1,0,0,0,12;6
DB 0,2,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,3,0
DB NO_MAP_DATA
DB 0,0,0,0,13;7
DB NO_MAP_DATA
DB 0,0,1,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,14;8
DB NO_MAP_DATA
DB 0,0,0,2,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,2,0,0
DB 17,13,9,5,0
DB 18,14,10,6,15;9
DB 19,15,11,7,0
DB 20,16,12,8,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,1,0
DB NO_MAP_DATA
DB 0,0,0,0,16;10
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,7;1
DB 0,2,0,0,0
DB NO_MAP_DATA
DB 0,0,0,0,8;2
DB NO_MAP_DATA
DB 0,0,0,0,15;9
DB 0,0,3,0,0
DB NO_MAP_DATA
DB 0,1,0,0,0
DB 0,0,0,0,14;8
DB 0,0,0,0,8;2
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,12;6
DB 0,0,4,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,17;11;WALL
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 3,0,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,18;12;三連WALL
DB 0,0,0,0,17;11;
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 17,13,9,5,0
DB 18,14,10,6,0
DB 19,15,11,7,0
DB 20,16,12,8,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 3,0,0,0,0
DB 0,0,0,4,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,3,0,19;13
DB 0,0,0,0,20;14
DB NO_MAP_DATA
DB 0,2,0,0,0
DB NO_MAP_DATA
DB 0,0,0,1,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,3,0,0,0
DB NO_MAP_DATA
DB 3,0,0,0,0
DB 0,0,0,4,0
DB NO_MAP_DATA
;----------SET WEAPON GUN
DB 0,0,4,0,&HFA ;MES_WAIT_START
DB NO_MAP_DATA  ;MES_WAIT
DB NO_MAP_DATA  ;MES_WAIT
DB 0,2,0,0,0    ;MES_WAIT
DB NO_MAP_DATA  ;MES_WAIT
DB NO_MAP_DATA  ;MES_WAIT
DB 3,0,0,0,0    ;MES_WAIT
DB NO_MAP_DATA  ;MES_WAIT_END
;
DB NO_MAP_DATA
DB 0,0,1,0,0
DB 0,0,0,1,&HF2
DB 0,0,0,0,3;群隊WEPON(1-4)
DB 2,0,0,0,4;群隊WEPON(5-6)
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,4,0
DB 3,0,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,1,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,2,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,0,&HFF ;BOSS

;******************************************************
;*              STAGE3 MAP CHARACTOR
;******************************************************
STAGE3_MAP_CHARA:
MAP3_CHR00:DB 0,0,0,0,0,0,0,0 ;無地背景
MAP3_CHR01:DB &H00,&H00,&H20,&H00,&H00,&H00,&H00,&H00 ;STAR1
MAP3_CHR02:DB &H00,&H00,&H00,&H00,&H00,&H00,&H04,&H00 ;STAR2
MAP3_CHR03:DB &H00,&H00,&H20,&H00,&H00,&H04,&H00,&H00 ;STAR3
MAP3_CHR04:DB &H02,&H00,&H00,&H10,&H38,&H10,&H00,&H00 ;STAR4
;RIVER
MAP3_CHR05:DB &H00,&H00,&H00,&H00,&H00,&H00,&H00,&H10 ;RIVER1_1
MAP3_CHR06:DB &H41,&H00,&H00,&H00,&H11,&H00,&H00,&H00 ;RIVER2_1
MAP3_CHR07:DB &H41,&H00,&H00,&H04,&H00,&H00,&H20,&H00 ;RIVER3_1
MAP3_CHR08:DB &H04,&H00,&H08,&H00,&H40,&H02,&H08,&H80 ;RIVER4_1
MAP3_CHR09:DB &H00,&H00,&H00,&H00,&H02,&H10,&H80,&H00 ;RIVER1_2
MAP3_CHR10:DB &H00,&H10,&H01,&H00,&H00,&H00,&H21,&H00 ;RIVER2_2
MAP3_CHR11:DB &H04,&H00,&H20,&H00,&H00,&H10,&H00,&H00 ;RIVER3_2
MAP3_CHR12:DB &H01,&H40,&H00,&H02,&H10,&H80,&H00,&H00 ;RIVER4_2
MAP3_CHR13:DB &H00,&H00,&H02,&H10,&H00,&H00,&H10,&H00 ;RIVER1_3
MAP3_CHR14:DB &H02,&H00,&H00,&H00,&H12,&H00,&H00,&H10 ;RIVER2_3
MAP3_CHR15:DB &H00,&H00,&H84,&H00,&H01,&H80,&H00,&H00 ;RIVER3_3
MAP3_CHR16:DB &H08,&H01,&H00,&H40,&H00,&H00,&H00,&H00 ;RIVER4_3
MAP3_CHR17:DB &H01,&H20,&H00,&H00,&H00,&H40,&H02,&H10 ;RIVER1_4
MAP3_CHR18:DB &H00,&H02,&H00,&H00,&H10,&H00,&H00,&H01 ;RIVER2_4
MAP3_CHR19:DB &H80,&H10,&H00,&H04,&H00,&H00,&H00,&H01 ;RIVER3_4
MAP3_CHR20:DB &H10,&H00,&H00,&H00,&H00,&H00,&H00,&H00 ;RIVER3_4

;******************************************************
;*              STAGE3 ENEMY CHARACTOR
;******************************************************
;BIG_METEOR
CHR_ST3_01:DB &H1F,&H38,&H77,&HEF,&HEF,&HEF,&HF7,&HF8
CHR_ST3_02:DB &HFF,&H7F,&HFB,&HF3,&H7F,&H3F,&H1F,&H0F
CHR_ST3_03:DB &HF0,&HFC,&H7E,&HBF,&HBF,&HBF,&H7F,&HF3
CHR_ST3_04:DB &HF7,&HFF,&HFF,&H9F,&HDE,&HFC,&HF8,&HE0

;SMALL METEOR
CHR_ST3_05:DB &H3E,&H41,&H91,&H81,&H85,&H91,&H83,&H7C
;BF-SPEAR
CHR_ST3_06:DB &H24,&H7E,&H81,&HE7,&H24,&H66,&H81,&HFF
CHR_ST3_06_SMALL:;これはCPRINTで処理するためSUPER GPRINTに登録しない
DB &H00,&H7C,&H44,&H28,&H44,&H38,&H00,&H00
;UP-DOWN
CHR_ST3_07:DB &H66,&HE7,&HA5,&HBD,&HBD,&HA5,&HE7,&H66

;******************************************************
;*              STAGE3 BOSS CHARACTOR
;******************************************************
CHR_BOSS3_CORE:;8*8
DB &H3C,&H7E,&H95,&HA3,&H95,&H81,&H42,&H3C
CHR_BOSS3_LCAN:
DB &H7E,&H81,&HFF,&HFF,&HFF,&HFF,&HFF,&H7E
CHR_BOSS3_GUN:
DB &H7E,&H81,&H81,&H81,&H81,&H81,&HD5,&HAA

;******************************************************
;*              STAGE3 SENARIO INITIALIZE
;******************************************************
STAGE_3_INIT:
PRE IX,BASE_SENARIO_PTR
LDW $0,SCENARIO
STW $0,(IX+$31)

PRE IX,SCENARIO
LDW $0,ST3_SCENARIO_00 ;DUMMY
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_01
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_02
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_03
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_04
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_05
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_06
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_07
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_08
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_09
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_10
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_11
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_12
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_13
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_14
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_15
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_16
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_17
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_18
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_19
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_20
STIW $0,(IX+$31)
LDW $0,ST3_SCENARIO_21
STIW $0,(IX+$31)
;シナリオを追加する場合はここを修正(MAX64POINT)
RTN

;**********************************
;*    STAGE3 SCENARIO DATA
;*      (9BYTE:MAX64POINT)
;* 1:TIMING(出現タイミング+カウント(今回は1ドットスクロールなので0～7))
;* 2:ENEMY NO
;* 3:X
;* 4:Y
;* 5:LENGTH-X
;* 6:LENGTH-Y
;* 7:FREE
;* 8:FREE
;* 9:EXTRA
;* 10～18：0で自動初期化
;*
;*注意:1 必ず9BYTE定義すること
;*注意:2 10～18バイト目は自動的に0で初期化される
;*
;**********************************
ST3_SCENARIO_00: ;出現しない
ST3_SCENARIO_01:
DB 0,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 2,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 4,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 6,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB &HFF ;END CODE
ST3_SCENARIO_02:
DB 0,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 2,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB &HFF ;END CODE
ST3_SCENARIO_03:
DB 0,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 2,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 4,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 6,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB &HFF ;END CODE
ST3_SCENARIO_04:
DB 0,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 2,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB &HFF ;END CODE
ST3_SCENARIO_05:
DB 0,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 2,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 4,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 6,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB &HFF ;END CODE
ST3_SCENARIO_06:
DB 0,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 2,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB &HFF ;END CODE

ST3_SCENARIO_07:;01:
DB 0,107,136,20,8,8,0,0,&H03,3,1;S:17=-4,1
DB 6,108,136,10,8,8,2,0,&H03,3,1;S:18=-4,1
DB &HFF ;END CODE
ST3_SCENARIO_08:;02:
DB 0,104,136,20,8,8,0,0,&H03,3,1;S:14=-4,-1
DB &HFF ;END CODE
ST3_SCENARIO_09:;03:
DB 0,103,136,10,16,16,0,0,&H0C,1,10;B:13=-2,1
DB &HFF ;END CODE
ST3_SCENARIO_10:;04:
DB 0,103,136,20,16,16,0,0,&H0C,1,10;B:13=-2,1
DB 4,105,136,26,8,8,2,0,&H03,3,1;S:18=-3,-1
DB &HFF ;END CODE
ST3_SCENARIO_11:;05:
DB 0,100,136,24,16,16,0,0,&H0C,1,10;B10=-3,0
DB 4,108,136,12,8,8,2,0,&H03,3,1;S:18=-4,1
DB &HFF ;END CODE
ST3_SCENARIO_12:;06:
DB 0,101,136,20,16,16,0,0,&H0C,1,10;B:11=-3,1
DB 6,108,136,8,10,8,0,0,&H03,3,1;S:18=-4,1
DB &HFF ;END CODE
ST3_SCENARIO_13:;07:
DB 0,102,136,20,16,16,0,0,&H0C,1,10;B:12=-2,0
DB 4,105,136,36,8,8,0,0,&H03,3,1;S:15=-3,-1
DB &HFF ;END CODE
ST3_SCENARIO_14:;08:
DB 0,103,136,20,16,16,0,0,&H0C,1,10;B:13=-2,1
DB 0,104,136,10,8,8,0,0,&H03,3,1;S:14=-4,0
DB &HFF ;END CODE
ST3_SCENARIO_15:;09:
DB 0,100,136,16,16,16,0,0,&H0C,1,10;B10=-3,0
DB 6,105,136,36,8,8,2,0,&H03,3,1;S:15=-3,-1
DB &HFF ;END CODE
ST3_SCENARIO_16:;10:
DB 0,101,136,20,16,16,0,0,&H0C,1,10;B:11=-3,1
DB 2,107,136,12,8,8,0,0,&H03,3,1;S:17=-4,1
DB &HFF ;END CODE
;--------------------WALL---------------
ST3_SCENARIO_17:;11:
DB 0,109,136,08,8,8,0,0,&H64,1,1;LIFE=100
DB 0,109,136,16,8,8,0,0,&H64,1,1;LIFE=100
DB 0,109,136,24,8,8,0,0,&H64,1,1;LIFE=100
DB 0,109,136,32,8,8,0,0,&H64,1,1;LIFE=100
DB &HFF ;END CODE
ST3_SCENARIO_18:;12:
DB 0,109,136,08,8,8,0,0,&H64,1,1;LIFE=100
DB 0,109,136,16,8,8,0,0,&H64,1,1;LIFE=100
DB 0,109,136,24,8,8,0,0,&H64,1,1;LIFE=100
DB 0,109,136,32,8,8,0,0,&H64,1,1;LIFE=100
DB 4,109,136,08,8,8,0,0,&H64,1,1;LIFE=100
DB 4,109,136,16,8,8,0,0,&H64,1,1;LIFE=100
DB 4,109,136,24,8,8,0,0,&H64,1,1;LIFE=100
DB 4,109,136,32,8,8,0,0,&H64,1,1;LIFE=100
DB &HFF ;END CODE
ST3_SCENARIO_19:;13:
;($14:0:上/1※反転後はCOUNTER(3))
;($15:TYPE)
DB 0,2,0,08,8,8,0,0,&H00,3,1;上
DB 0,2,0,24,8,8,1,1,&H00,3,1;下
DB 2,2,0,24,8,8,0,2,&H00,3,1;上
DB 2,2,0,16,8,8,1,0,&H00,3,1;下
DB 4,2,0,12,8,8,0,1,&H00,3,1;上
DB 4,2,0,34,8,8,1,2,&H00,3,1;下
DB 6,2,0,24,8,8,0,0,&H00,3,1;上
DB 6,2,0,18,8,8,1,1,&H00,3,1;下
DB &HFF ;END CODE
ST3_SCENARIO_20:;14:
;($14:0:上/1※反転後はSECTION)
;($15:U-4BIT=3 L-4BIT=TYPE)
DB 0,2,0,16,8,8,0,2,&H00,3,1;上
DB 0,2,0,22,8,8,1,0,&H00,3,1;下
DB 2,2,0,34,8,8,0,1,&H00,3,1;上
DB 2,2,0,32,8,8,1,2,&H00,3,1;下
DB 4,2,0,20,8,8,0,0,&H00,3,1;上
DB 4,2,0,10,8,8,1,1,&H00,3,1;下
DB 6,2,0,12,8,8,0,2,&H00,3,1;上
DB 6,2,0,28,8,8,1,0,&H00,3,1;下
DB &HFF ;END CODE
ST3_SCENARIO_21:;15:
;($14:0:上/1※反転後はSECTION)
;($15:U-4BIT=3 L-4BIT=TYPE)
DB 0,111,136,20,8,8,8,0,&H00,3,1;上
DB 0,111,136,36,8,8,8,0,&H00,3,1;下
DB 2,111,136,20,8,8,8,0,&H00,3,1;上
DB 2,111,136,36,8,8,8,0,&H00,3,1;下
DB 4,111,136,20,8,8,8,0,&H00,3,1;上
DB 4,111,136,36,8,8,8,0,&H00,3,1;下
DB 6,111,136,20,8,8,8,0,&H00,3,1;上
DB 6,111,136,36,8,8,8,0,&H00,3,1;下
DB &HFF ;END CODE
;シナリオは64まで記述可だが今は16のみ
;16以上追加する場合はSTAGE_2_INITを修正

;*********************************
;*        ENEMY MOVE
;*
;*********************************
ST3_ENEMY_MOVE:

LD $28,$31

ST3_ENEMYMOVE_LP:
PRE IX,ENEMY_DATA
;
PHU $28
;
LDM $9,(IX+$28),8
SBC $9,$31
JR Z,NEXT_ST3_ENEMY_M


;-------- NOT ACTIVE FLAG(0) ------------------------------
;-------- 全ての衝突判定対象外のオブジェクト(001-089)(MAKE JUDGEで撥ねる)---
SBC $9,1
JR Z,ST3_ENEMY01_MOVE;(修復中の壁)
SBC $9,2
JR Z,ST3_ENEMY02_MOVE;(背面移動中のBF-SPEAR)
;-------- BULLET(89:固定) -----------------------------------
SBC $9,89
JP Z,ST3_ENEMY89_MOVE;BULLET
;-------- 自弾(GUN,LASER)と衝突判定を行わない敵オブジェクト(000-089)
;-------- DROP ITEM MOTHER(90)---------------------------------
SBC $9,90
JP Z,ST3_ENEMY90_MOVE;WAVE
;-------- BOSS CORE(99:固定) -----------------------------------
;-------- NORMAL(100-199)----------------------------------
SBC $9,100;10
JP Z,ST3_ENEMY100MOVE;BIG_METEOR_1
SBC $9,101;11
JP Z,ST3_ENEMY101MOVE;BIG_METEOR_2
SBC $9,102;12
JP Z,ST3_ENEMY102MOVE;BIG_METEOR_3
SBC $9,103;13
JP Z,ST3_ENEMY103MOVE;BIG_METEOR_4
SBC $9,104;14
JP Z,ST3_ENEMY104MOVE;SMALL_METEOR_1
SBC $9,105;15
JP Z,ST3_ENEMY105MOVE;SMALL_METEOR_2
SBC $9,106;16
JP Z,ST3_ENEMY106MOVE;SMALL_METEOR_3
SBC $9,107;17
JP Z,ST3_ENEMY107MOVE;SMALL_METEOR_4
SBC $9,108;18
JP Z,ST3_ENEMY108MOVE;SMALL_METEOR_5
SBC $9,109;19
JP Z,ST3_ENEMY109MOVE;自己修復する壁
SBC $9,110;20
JP Z,ST3_ENEMY110MOVE;BF-SPEAR(実体化して攻撃)
SBC $9,111;21
JP Z,ST3_ENEMY111MOVE;BF-SPEAR
;-----レーザーが衝突するとレーザーが縮む敵オブジェクト(200-229)---------------
;-----レーザーが衝突するとレーザーが縮む無敵の敵オブジェクト(230-255)(壁など)----


NEXT_ST3_ENEMY_M:
;
PPU $28
;
AD $28,ENEMY_STRUCT

JR NC,ST3_ENEMYMOVE_LP

RTN

ST3_ENEMY01_MOVE:;(修復中の壁)
AD $15,$30
SB $10,$30
JP NC,ST3_ENEMY01_M_SA
JP ST3_KILL_ENEMY
ST3_ENEMY01_M_SA:
SBC $15,48
JP C,END_ST3ENEMYMOVE
;COUNTER=48なら通常状態に復帰
LD $9,109;壁のキャラNO
LD $16,&H64;LIFE=100
JP END_ST3ENEMYMOVE

ST3_ENEMY02_MOVE:;(背面移動中のBF-SPEAR)
AD $10,2
SBC $10,140
JP C,END_ST3ENEMYMOVE
LD $9,110;BF-SPEARの実体化
LD $14,3;COUNTER初期化
JP END_ST3ENEMYMOVE

ST3_ENEMY89_MOVE:;BULLET
CAL MOVE_BULLET
JP NEXT_ST3_ENEMY_M

ST3_ENEMY90_MOVE:;WAVE(各面に登場するため細部は別ファイルに分離)
CAL ENEMY_WAVE_MOVE
JP C,ST3_KILL_ENEMY
JP END_ST3ENEMYMOVE

ST3_ENEMY100MOVE:;BIG_METEOR_1
;LIFEが8未満なら分裂
SBC $16,8
JR C,ST3_METEOR_DIV1

;X移動
SB $10,3;X=X-3
;X<0ならオブジェクトを消す
JP C,ST3_KILL_ENEMY
JP END_ST3ENEMYMOVE

ST3_ENEMY101MOVE:;BIG_METEOR_2
;LIFEが8未満なら分裂
SBC $16,8
JR C,ST3_METEOR_DIV1

;X移動
SB $10,3;X=X-3
;X<0ならオブジェクトを消す
SBC $10,180
JP NC,ST3_KILL_ENEMY
AD $14,$30
SBC $14,8
JP C,END_ST3ENEMYMOVE
SB $11,$30
LD $14,$31
JP END_ST3ENEMYMOVE

ST3_ENEMY102MOVE:;BIG_METEOR_3
;LIFEが8未満なら分裂
SBC $16,8
JP C,ST3_METEOR_DIV2

;X移動
SB $10,2;X=X-2
;X<0ならオブジェクトを消す
SBC $10,180
JP NC,ST3_KILL_ENEMY
AD $14,$30
SBC $14,8
JP C,END_ST3ENEMYMOVE
AD $11,$30
LD $14,$31
JP END_ST3ENEMYMOVE

ST3_ENEMY103MOVE:;BIG_METEOR_4
;LIFEが8未満なら分裂
SBC $16,8
JP C,ST3_METEOR_DIV2

;X移動
SB $10,2;X=X-2
;X<0ならオブジェクトを消す
SBC $10,180
JP NC,ST3_KILL_ENEMY
AD $14,$30
SBC $14,16
JP C,END_ST3ENEMYMOVE
AD $11,$30
LD $14,$31
JP END_ST3ENEMYMOVE

;*********************************
;*          隕石分裂
;*********************************
ST3_DIV_METROR:
DB 8,8,1,2,&H03,1,1

ST3_METEOR_DIV1:
;
CAL DELETE_OBJECT;KILL BIG_METRO
;
PRE IX,ST3_DIV_METROR
LD $17,104
LD $18,$10
LD $19,$11
LDM $20,(IX+$31),7
CAL INSERT_OBJECT
;
LD $17,105
LD $18,$10
AD $18,8
LD $19,$11
;LDM $20,(IX+$31),7
CAL INSERT_OBJECT
;
LD $17,106
LD $18,$10
LD $19,$11
AD $19,8
;LDM $20,(IX+$31),7
CAL INSERT_OBJECT
;
LD $17,107
LD $18,$10
AD $18,8
LD $19,$11
AD $19,8
;LDM $20,(IX+$31),7
CAL INSERT_OBJECT
;
JP NEXT_ST3_ENEMY_M

ST3_METEOR_DIV2:
;
CAL DELETE_OBJECT;KILL BIG_METRO
;
PRE IX,ST3_DIV_METROR
LD $17,105
LD $18,$10
LD $19,$11
LDM $20,(IX+$31),7
CAL INSERT_OBJECT
;
LD $17,106
LD $18,$10
AD $18,8
LD $19,$11
;LDM $20,(IX+$31),7
CAL INSERT_OBJECT
;
LD $17,107
LD $18,$10
LD $19,$11
AD $19,8
;LDM $20,(IX+$31),7
CAL INSERT_OBJECT
;
LD $17,108
LD $18,$10
AD $18,8
LD $19,$11
AD $19,8
;LDM $20,(IX+$31),7
CAL INSERT_OBJECT
;
JP NEXT_ST3_ENEMY_M

ST3_ENEMY104MOVE:;SMALL_METEOR_1
SB $10,4
JP C,ST3_KILL_ENEMY
JP END_ST3ENEMYMOVE

ST3_ENEMY105MOVE:;SMALL_METEOR_2
SB $10,3
JP C,ST3_KILL_ENEMY
;3回に1回Y座標を減じる
SB $15,$30
JP NC,END_ST3ENEMYMOVE
LD $15,2
SB $11,$30
JP C,ST3_KILL_ENEMY
JP END_ST3ENEMYMOVE

ST3_ENEMY106MOVE:;SMALL_METEOR_3
SB $10,2
JP C,ST3_KILL_ENEMY
AD $11,2
SBC $11,40
JP NC,ST3_KILL_ENEMY
JP END_ST3ENEMYMOVE

ST3_ENEMY107MOVE:;SMALL_METEOR_4
SB $10,4
JP C,ST3_KILL_ENEMY
AD $11,$30
SBC $11,40
JP NC,END_ST3ENEMYMOVE
JP END_ST3ENEMYMOVE

ST3_ENEMY108MOVE:;SMALL_METEOR_5
SB $10,4
JR C,ST3_KILL_ENEMY
;3回に1回Y座標を加算する
SB $14,$30
JR NC,END_ST3ENEMYMOVE
LD $14,2
AD $11,$30
JR C,ST3_KILL_ENEMY
JP END_ST3ENEMYMOVE

ST3_ENEMY109MOVE:;自己修復する壁

SB $10,$30
JR NC,ST3_ENEMY109_LCK
JR ST3_KILL_ENEMY

ST3_ENEMY109_LCK:
;壁のLIFEが100であれば無傷なので通常状態を継続
SBC $16,100
JR NC,END_ST3ENEMYMOVE
;当たり判定無のオブジェクト(CHR NO=1)に変更、初期化
LD $9,1
LD $15,$31;壁の修復中フラグカウンタ=0
JP END_ST3ENEMYMOVE

ST3_ENEMY110MOVE:;BF-SPEAR
SB $10,4
JR C,ST3_KILL_ENEMY
SB $14,$30;COOUNTER-=1
JR NC,END_ST3ENEMYMOVE

;SELECT TYPE
SBC $15,$31
JR Z,ST3_ENEMY110_T0
SBC $15,$30
JR Z,END_ST3ENEMYMOVE
ST3_ENEMY110_T2:;(上昇)
SB $11,$30
LD $14,3;COUNTER1 RESET
JR C,ST3_KILL_ENEMY
JR END_ST3ENEMYMOVE
ST3_ENEMY110_T0:;(下降)
AD $11,$30
SBC $11,40
JR NC,ST3_KILL_ENEMY
LD $14,3;COUNTER1 RESET
JR END_ST3ENEMYMOVE

ST3_ENEMY111MOVE:;UP-DOWN
SB $10,3
JR C,ST3_KILL_ENEMY
SBC $15,$30
JR Z,ST3_E21_SEC1
ST3_E21_SEC0:
SB $11,2
SB $14,$30
JR NZ,END_ST3ENEMYMOVE
LD $14,8
LD $15,$30
JR END_ST3ENEMYMOVE
ST3_E21_SEC1:
AD $11,2
SB $14,$30
JR NZ,END_ST3ENEMYMOVE
LD $14,8
LD $15,$31
JR END_ST3ENEMYMOVE

END_ST3ENEMYMOVE:
;DATA SAVE
PRE IX,ENEMY_DATA
STM $9,(IX+$28),8
JP NEXT_ST3_ENEMY_M

ST3_KILL_ENEMY:
CAL DELETE_OBJECT
JP NEXT_ST3_ENEMY_M

;*********************************
;*        STAGE3 ENEMY DISP
;*********************************
ST3_ENEMY_DISP:

LD $28,$31

ST3_ENEMYDISP_LP:
PRE IX,ENEMY_DATA

LDM $9,(IX+$28),8
SBC $9,$31
JR Z,NEXT_ST3_ENEMY_D
;
PHU $28
;
;GPRINTのRTN命令でRTN_ST3_EDISPに戻れるようにするため、RTN_ST3_EDISPのアドレスを
;SSPにPUSHしておく。
;なおGPRINTからの復帰はRTNでありSSPにスタックされたアドレス+1からプログラムを実行するため
;RTN_ST3_EDISPのアドレスから-1したものをSSPにPUSHする。
LDW $0,RTN_ST3_EDISP-1
PHSW $1

SBC $9,1
JR Z,ST3_ENEMY01_DISP;修復中の壁
SBC $9,2
JR Z,ST3_ENEMY02_DISP;(背面移動中のBF-SPEAR)
SBC $9,9
JR Z,ST3_ENEMY89_DISP;BULLET
SBC $9,90
JR Z,ST3_ENEMY90_DISP;WAVE
SBC $9,104;100～103=BIG_METEOR
JP C,ST3_ENEMY100DISP
SBC $9,109;104～108=SMALL_METEOR
JP C,ST3_ENEMY104DISP
SBC $9,109
JP Z,ST3_ENEMY109DISP;自己修復する壁
SBC $9,110
JP Z,ST3_ENEMY110DISP;BF-SPEAR
SBC $9,111
JP Z,ST3_ENEMY111DISP;UP-DOWN

;JUMPしなかった場合はSSPを戻す。
PPSW $0

RTN_ST3_EDISP:
;
PPU $28
;
NEXT_ST3_ENEMY_D:

AD $28,ENEMY_STRUCT

JR NC,ST3_ENEMYDISP_LP

RTN

CHR_ST3_WALL_R1:
DB &H00,&H40,&H02,&H20,&H00,&H40,&H00
CHR_ST3_WALL_R2:
DB &H14,&HC1,&H00,&H92,&H40,&H21,&H44

ST3_ENEMY01_DISP:;(修復中の壁)
;COUNTER<8なら何も表示しない
SBC $15,16
RTN C
SBC $15,32
;COUNTER>32なら修復中2を表示
JR NC,ST3_WALL_DISP_R2
;COUNTER<48なら修復中1を表示
ST3_WALL_DISP_R1:
LDW $13,CHR_ST3_WALL_R1
JR ST3_WALL_R_DISP
ST3_WALL_DISP_R2:
LDW $13,CHR_ST3_WALL_R2
ST3_WALL_R_DISP:
LD $12,8
JP CPRINT_OR

ST3_ENEMY02_DISP:;(背面移動中のBF-SPEAR)
;$14の値(0/1)で表示するY座標(8/32)を決める
LD $11,8
SBC $14,0
JR Z,ST3_ENEMY02_A
LD $11,32
ST3_ENEMY02_A:
LD $12,8
LDW $13,CHR_ST3_06_SMALL
JP CPRINT

ST3_ENEMY89_DISP:;BULLET
LDW $13,@CHR_BULLET
LD $12,4
JP SGPRINT_4

ST3_ENEMY90_DISP:;WAVE
JP ENEMY_WAVE_DISP

;BIG_METEOR4種類
ST3_ENEMY100DISP:
ST3_ENEMY101DISP:
ST3_ENEMY102DISP:
ST3_ENEMY103DISP:

PHUW $11
LD $12,8
LDW $13,SG_CHR_DATA07
CAL SGPRINT_FAST
PPUW $10

PHUW $11
AD $10,8
LD $12,8
LDW $13,SG_CHR_DATA08
CAL SGPRINT_FAST
PPUW $10

PHUW $11
AD $11,8
LD $12,8
LDW $13,SG_CHR_DATA09
CAL SGPRINT_FAST
PPUW $10

AD $10,8
AD $11,8
LD $12,8
LDW $13,SG_CHR_DATA10
JP SGPRINT_FAST

;SMALL_METEOR4種類
ST3_ENEMY104DISP:
ST3_ENEMY105DISP:
ST3_ENEMY106DISP:
ST3_ENEMY107DISP:
ST3_ENEMY108DISP:
LD $12,8
LDW $13,SG_CHR_DATA11
JP SGPRINT_FAST

ST3_ENEMY109DISP:;自己修復する壁
LDW $13,CHR_WHITE_BOX
LD $12,8
JP CPRINT

ST3_ENEMY110DISP:;BF-SPEAR
LD $12,8
LDW $13,SG_CHR_DATA13
JP SGPRINT_FAST

ST3_ENEMY111DISP:
LD $12,8
LDW $13,SG_CHR_DATA11
JP SGPRINT_FAST

RTN

;*********************************
;*          BOSS3 INIT
;*  +0($9)  種類(0:未使用フラグ,&H01～&HFF)
;*  +1($10)  x(必須)
;*  +2($11)  y(必須)
;*  +3($12)  キャラのXサイズ
;*  +4($13)  キャラのYサイズ
;*  +5($14)  COUNTER1
;*  +6($15)  COUNTER2
;*  +7($16)  LIFE(Cフラグで破壊)
;*  +8($17)  SCORE
;*  +9($18)  DAMAGE
;**********************************
;NOTE
;
;BOSS3は1つのパーツで構成されている。
;PARTS Noは次のとおり
;
;         200.200
;         200.099.200 <- 099:CORE
;         200.200
;
;EXTRA_FLAG:
; 0:NO200が未破壊の状態
; 1:NO200が破壊され、NO201が未破壊の状態
; 2:NO200,NO201が破壊された状態
;
;
;動作の際は下記の各パーツのインデックスアドレスを
;直接指定してXを参照、変更している。
;
; 0:ENEMY_DATA_0 = &H63(99):BOSS3 CORE
; 1:ENEMY_DATA_1 = &HE6(200):BOSS3 UPPER
; 1:ENEMY_DATA_1 = &HE6(200):BOSS3 UPPER
; 1:ENEMY_DATA_1 = &HE6(200):BOSS3 UPPER
; 1:ENEMY_DATA_1 = &HE6(200):BOSS3 UPPER
; 1:ENEMY_DATA_1 = &HE6(200):BOSS3 UPPER
; 1:ENEMY_DATA_1 = &HE6(200):BOSS3 UPPER
;
;
BOSS3_GURD_LIFE:EQU &H5F

BOSS3_DATA:
;CORE
;   0   1  2  3  4  5  6  7  8  9  10 11 12
;       X  Y  XL YL C  OR L  PH SC FR
DB 099,170,20,08,08,08,00,32,00,10,00,00,00,0,0,0;L=32
;   0   1  2  3  4  5  6  7  8  9  10 11
;       X  Y  XL YL C  A  L  S  DM RL RH
DB 230,170,20,08,08,00,03,20,10,10,08,00,0,0,0,0       ;2-1
DB 230,170,20,08,08,00,08,20,10,10,08,00,0,0,0,0       ;2-1
DB 230,170,20,08,08,00,13,20,10,10,08,00,0,0,0,0       ;2-1
DB 230,170,20,08,08,00,18,20,10,10,08,00,0,0,0,0       ;2-1
DB 230,170,20,08,08,00,23,20,10,10,08,00,0,0,0,0       ;2-1
DB 230,170,20,08,08,00,28,20,10,10,08,00,0,0,0,0       ;2-1
BOSS3_DATA_END:

BOSS3_FB:
DB 231,000,00,08,08,00,00,00,05,01,00,00,0,0,0,0       ;2-1

BOSS3_DATA_NUM:EQU 1;BOSS3のパーツ数、登録時、登場時は7

BOSS3_INIT:

;RXCNT
;ENEMY_DATA初期化
LDW $0,ENEMY_DATA
LDW $2,&H0FF
LDW $28,CLEME
CAL IOCS_CAL

CAL OBJECT_ARRAY_INI

;******************* BOSSデータのブロック転送*********
;BOSS3を構成する位置データ等を転送
PRE IX,BOSS3_DATA
PRE IZ,ENEMY_DATA
PRE IY,BOSS3_DATA_END-1
BUP

;OBJECT_ARRAY POINTERをBOSS3のパーツ数に変更
PRE IX,OBJECT_ARRAY+16;OBJECT_ARRAY POINTER
LD $0,&H0F-7;BOSS3_CORE+LASER CANCELER*6
ST $0,(IX+$31)
;**********************************************

;転送したBOSSデータを実体化する
CAL INSERT_OBJECT_ON

;ボス戦闘中フラグをONにする。
PRE IX,NOW_BOSS_FIGHT
ST $30,(IX+$31)
;ボス破壊フラグをOFFにする。
PRE IX,BOSS_DESTROY
ST $31,(IX+$31)
;ボスのデータ数(BOSS3:1)を設定にする。
PRE IX,BOSS_DATA_NUM
LD $0,BOSS3_DATA_NUM
ST $0,(IX+$31)

;BOSSのキャラクターをSGPRINTに登録
CAL ST3_INIT_GRA_B

RTN

;************************************
;*              BOSS3 PRE
;*  (BOSS3 MOVE STANBY POSITION)
;************************************
BOSS3_PRE:

;BOSS3移動(X=X-1)
LD $0,&HFF
LD $1,$31
LD $29,7;BOSS3+LASER CANCELER
CAL MOVE_BOSS_ALL

;BOSS3のX座標が100になったらボス戦に突入
SBC $10,100
RTN NC
PRE IX,PHASE
LD $0,3
ST $0,(IX+$31) ;PHASE2->3
ST $31,(IX+$30) ;PHASE_COUNTER->0
RTN

;*********************************
;*          MOVE BOSS3
;*
;*USE:
;*      $0      WORK
;*      $2,$3   JUMP TABLE
;*      $9-$16  ENEMY DATA
;*      $28     COUNTER
;*      IX
;*      IZ
;*********************************
MOVE_BOSS3:

LD $28,$31

MOVE_BOSS3_LOOP:
PHU $28
PRE IX,ENEMY_DATA

LDM $9,(IX+$28),8

;-------- NOT ACTIVE FLAG(0) ------------------------------
;-------- RESERVE(1-4) ------------------------------------
;-------- DROP ITEM(5-7)(5:SUPLLY 6:WEPON 7:OPTION) -------
;-------- RESERVE(8-9) ------------------------------------
;-------- 衝突判定対象外のオブジェクト(010-049)(MAKE JUDGEで撥ねる)---
;-------- BULLET(98) --------------------------------------
;-- 自弾(GUN,LASER)と衝突判定を行わない敵オブジェクト(050-098)(BULLET,敵LASERなど)
;-------- BOSS CORE(99) -----------------------------------
SBC $9,BOSS_CORE_NO
JP Z,BOSS3_P099_MOVE
;-------- NORMAL(100-199)----------------------------------
;-----レーザーが衝突するとレーザーが縮む敵オブジェクト(200-229)---------------

;-----レーザーが衝突するとレーザーが縮む無敵の敵オブジェクト(230-255)(壁など)----
SBC $9,230
JP Z,BOSS3_P230_MOVE;LASER CANCELER
SBC $9,231
JP Z,BOSS3_P231_MOVE;LASER CANCELER FB

NEXT_MOVE_BOSS3:
PPU $28
AD $28,ENEMY_STRUCT
JR NC,MOVE_BOSS3_LOOP

RTN

;*********************************
;*       BOSS3 OPTION MOVE
;*
;*PARA $0,$1 R
;*     $2 ANGLE(0-35)
;*USE  $0-$14 SIN,COS,SUB_DIV16S,SUB_MUL16S PARA
;*     $26,$27 X変化量退避
;*     $28,$29 Y変化量退避
;*RETURN $26 X変化量
;*       $28 Y変化量
;*********************************

BOSS3_OPT_MOVE:
PHU $2 ;ANGLE
PHUW $1 ;R

CAL COS ;$0は破壊されない
LDW $2,$4
;LDW $0(R): パラメータ
CAL SUB_MUL16S ;R*SIN
LDW $0,$4
LDW $2,16;16は定数
CAL SUB_DIV16S ;(R*SIN)/16 (SIN値が16倍されているので戻す)

LDW $26,$4 ;X変化量退避

PPUW $0
PPU $2

CAL SIN ;$0は破壊されない
LDW $2,$4
;$0(R): PPUWで復旧
CAL SUB_MUL16S ;R*COS
LDW $0,$4
LDW $2,16;SIN/COSは16倍した値であるため16で割る
CAL SUB_DIV16S ;(R*COS)/16 (SIN値が16倍されているので戻す)

LDW $28,$4 ;Y変化量退避

RTN

;*********************************
;*          BOSS3 MOVE
;*********************************
BOSS3_P099_MOVE:

LD $0,(IX+8)

SBC $0,0
JR Z,BOSS3_SECTION0 ;待機
SBC $0,1
JR Z,BOSS3_SECTION1 ;オプションのRを16まで広げる
SBC $0,2
JP Z,BOSS3_SECTION2 ;弾を撃つ
SBC $0,3
JP Z,BOSS3_SECTION3 ;オプションのRを縮める
SBC $0,4
JP Z,BOSS3_SECTION4 ;反対側に移動する
SBC $0,5
JP Z,BOSS3_SECTION5 ;中央に移動する
JR NEXT_MOVE_BOSS3

BOSS3_SECTION0:
END_BOSS3PHASE0:
ST $30,(IX+8) ;PHASE1へ移行
ST $31,(IX+5) ;カウンタリセット
LD $0,1
ST $0,(IX+6) ;OPTへ拡大指示
JP NEXT_MOVE_BOSS3

BOSS3_SECTION1:;オプションのRを8広げる
AD $14,$30
ST $14,(IX+5) ;COUNTER
SBC $14,8
JR NC,END_BOSS3PHASE1
JR NEXT_MOVE_BOSS3
END_BOSS3PHASE1:
LD $0,2
ST $0,(IX+8) ;PHASE2へ移行
ST $31,(IX+5) ;カウンタリセット
LD $0,0
ST $0,(IX+6) ;OPTへ拡大停止指示
JP NEXT_MOVE_BOSS3

BOSS3_SECTION2:;自機にあわせて上下移動し8回ごと弾を発射(×8)

;オプションにミサイル弾発射停止指示
ST $31,(IX+10)

;4回に1回自機のY座標に向けて上下移動
PRE IZ,GLOBAL_COUNTER
LD $1,(IZ+$31)
LD $0,$1
AN $0,&H03
JP NZ,NEXT_MOVE_BOSS3;4でなければ移動しない

;移動処理
PRE IZ,MY_Y
LD $0,(IZ+$31)

SBC $11,$0
JR Z,BOSS3_FIRE
JR C,BOSS3_SEC2_YPLUS
SB $11,$30
JR END_BOSS3_SEC2YM
BOSS3_SEC2_YPLUS:
AD $11,$30
END_BOSS3_SEC2YM:
ST $11,(IX+2)
JP NEXT_MOVE_BOSS3

AN $1,&H07
JP NZ,NEXT_MOVE_BOSS3

BOSS3_FIRE:
;オプションにミサイル弾発射指示
ST $30,(IX+10)

AD $14,$30
ST $14,(IX+5) ;COUNTER
SBC $14,8
JR NC,END_BOSS3PHASE2
JP NEXT_MOVE_BOSS3
END_BOSS3PHASE2:
LD $0,3
ST $0,(IX+8) ;PHASE3へ移行
ST $31,(IX+5) ;カウンタリセット
LD $0,2
ST $0,(IX+6)    ;OPTへ縮小指示
ST $31,(IX+10)  ;OPTへミサイル発射停止指示
JP NEXT_MOVE_BOSS3

BOSS3_SECTION3:;オプションのRを8縮める
AD $14,$30 ;COUNTER+=1
ST $14,(IX+5)
SBC $14,8
JR NC,END_BOSS3PHASE3
JP NEXT_MOVE_BOSS3
END_BOSS3PHASE3:
LD $0,4
ST $0,(IX+8) ;PHASE3へ移行
ST $31,(IX+5) ;カウンタリセット
ST $31,(IX+6) ;OPTへ待機指示
JP NEXT_MOVE_BOSS3

BOSS3_SECTION4:;反対側に移動する
AD $10,$30
ST $10,(IX+$30)
SBC $10,150
JR Z,END_BOSS3PHASE4
JP NEXT_MOVE_BOSS3
END_BOSS3PHASE4:
LD $0,5
ST $0,(IX+8) ;PHASE5へ移行
ST $31,(IX+5) ;カウンタリセット
LD $0,240
ST $0,(IX+$30) ;BOSS3 COREのX座標を240に設定
JP NEXT_MOVE_BOSS3

BOSS3_SECTION5:;中央に移動する
AD $10,$30
ST $10,(IX+$30)
SBC $10,100
JR Z,END_BOSS3PHASE5
JP NEXT_MOVE_BOSS3
END_BOSS3PHASE5:
ST $31,(IX+8) ;PHASE0へ移行
ST $31,(IX+5) ;カウンタリセット
JP NEXT_MOVE_BOSS3

BOSS3_FIRE_RIGHT:
LD $0,4 ;BOSS3が通常弾
LD $1,$10
LD $2,$11
LD $3,8 ;Xサイズ(当たり判定で使用するので必須)
LD $4,6 ;右に弾を撃つ
LD $5,$31
LD $6,$31
LD $7,$31 ;LIFE(Cで破壊)
CAL INSERT_OBJECT
RTN

BOSS3_P230_MOVE:

PRE IZ,ENEMY_DATA
LD $0,(IZ+10)
SBC $0,$31
JR Z,BOSS3_OPT_NF

PHU $28

PRE IZ,BOSS3_FB
LDIM $17,(IZ+$31),8
LDM $25,(IZ+$31),2
LD $18,$10;X
LD $19,$11;Y
CAL INSERT_OBJECT

PPU $28

PRE IX,ENEMY_DATA

BOSS3_OPT_NF:

;BOSS3OPT_SPREAD/BOSS3OPT_SHORTEN用のINDEX
LD $27,$28
AD $27,10

PRE IZ,ENEMY_DATA
LD $0,(IZ+6) ;OPTへの指令確認
SBC $0,$31
JR Z,BOSS3_OPT_ROTATE ;指令が0なら特別な処理はしない
SBC $0,$30
JR Z,BOSS3OPT_SPREAD
SBC $0,2
JR Z,BOSS3OPT_SHORTEN
;SBC $0,3
;JR Z,BOSS3OPT_FIRE
;
BOSS3OPT_FIRE:
JR BOSS3_OPT_ROTATE

BOSS3OPT_SPREAD:
LDW $0,(IX+$27)
ADW $0,$30
JR BOSS3OPTRUPDATE

BOSS3OPT_SHORTEN:
LDW $0,(IX+$27)
SBW $0,$30

BOSS3OPTRUPDATE:
STW $0,(IX+$27)

;オプションを回転させる
BOSS3_OPT_ROTATE:

;ADD ANGLE
AD $15,$30 ;ANGLE
SBC $15,36
JR C,B3OP_ANGLESAFE_1
LD $15,$31
B3OP_ANGLESAFE_1:
LD $27,$28
AD $27,6;ANGLE
ST $15,(IX+$27)

AD $27,4;6+4=10(RL)
LDW $0,(IX+$27);R
LD $2,$15

PHU $28

CAL BOSS3_OPT_MOVE

PRE IZ,ENEMY_DATA
LD $10,(IZ+1);X
AD $10,$26
LD $11,(IZ+2);Y
AD $11,$28

PPU $28

LD $27,$28
AD $27,$30
ST $10,(IX+$27)
AD $27,$30
ST $11,(IX+$27)

JP NEXT_MOVE_BOSS3

BOSS3_P231_MOVE:
SB $10,3
JP C,ST3_KILL_BOSS
JR END_BOSS3_MOVE

ST3_KILL_BOSS:
CAL DELETE_OBJECT
JP NEXT_MOVE_BOSS3

END_BOSS3_MOVE:
PRE IX,ENEMY_DATA
STM $9,(IX+$28),8
JP NEXT_MOVE_BOSS3

;*********************************
;*        DISP BOSS3
;*
;*USE:
;*      $0      WORK
;*      $2,$3   JUMP TABLE
;*      $9-$16  ENEMY DATA
;*      $28     COUNTER
;*      IX
;*      IZ
;*********************************
DISP_BOSS3:
LD $28,$31

DISP_BOSS3_LOOP:

PRE IX,ENEMY_DATA

LDM $9,(IX+$28),8
SBC $9,$31
JR Z,NEXT_DISP_BOSS3
;
PHU $28
;
;GPRINTのRTN命令でRTN_ST3_DBOSS3に戻れるようにするため、RTN_ST3_DBOSS3のアドレスを
;SSPにPUSHしておく。
;なおGPRINTからの復帰はRTNでありSSPにスタックされたアドレス+1からプログラムを実行するため
;RTN_ST3_DBOSS3のアドレスから-1したものをSSPにPUSHする。
LDW $0,RTN_ST3_DBOSS3-1
PHSW $1

SBC $9,BOSS_CORE_NO;(09)
JR Z,BOSS3_CORE_DISP
SBC $9,230
JP Z,BOSS3_LACAN_DISP
SBC $9,231
JP Z,BOSS3_GUN_DISP

;JUMPしなかった場合はSSPを戻す。
PPSW $0

RTN_ST3_DBOSS3:

;
PPU $28
;
NEXT_DISP_BOSS3:
AD $28,ENEMY_STRUCT
JR NC,DISP_BOSS3_LOOP
RTN

BOSS3_CORE_DISP:;(BOSS3_CORE)
LD $12,8
LDW $13,SG_CHR_DATA07;BOSS3 CORE
JP SGPRINT_FAST

BOSS3_LACAN_DISP:;LASER CANCELER
LD $12,8
LDW $13,SG_CHR_DATA08
JP SGPRINT_FAST

BOSS3_GUN_DISP:;LASER CANCELER
LD $12,8
LDW $13,SG_CHR_DATA09;BOSS3_GUN
JP SGPRINT_FAST

;**********************************
;*      BOSS3撃破時の処理
;**********************************
BOSS_DEF_ST3:

;RTN CODE 0:継続をセット
LD $5,$31

;下へ降下
LD $0,2
PRE IX,ENEMY_DATA_00;BOSS3 CORE
LD $11,(IX+$0)
AD $11,$30
ST $11,(IX+$0);BOSS3 CORE

PRE IX,EXTRA_COUNTER
AD (IX+$31),$30
LD $0,40
SBC (IX+$31),$0
RTN NZ
;RTN CODE 1:次のフェーズに移行をセット
LD $5,$30
RTN

;**********************************
;*      ST3_INIT_GRAPHIC
;**********************************

ST3_INIT_GRA_S:
LDW $0,0;自機
LDW $2,CHR_FIGHTER
CAL SET_SGPRINT_DATA

LDW $0,1;MY BOMB L
LDW $2,CHR_BOMB_L
CAL SET_SGPRINT_DATA

LDW $0,2;MY_BOMB_R
LDW $2,CHR_BOMB_R
CAL SET_SGPRINT_DATA

LDW $0,3;FIGHTER_SHADOW
LDW $2,CHR_OPTION
CAL SET_SGPRINT_DATA

;NO4 RESERVE
;LDW $0,4
;LDW $2,CHR_OPTION
;CAL SET_SGPRINT_DATA

;NO5 RESERVE
;LDW $0,5
;LDW $2,CHR_OPTION
;CAL SET_SGPRINT_DATA

;ENEMY_WAVE固定
LDW $0,6
LDW $2,CHR_STA_WAVE
CAL SET_SGPRINT_DATA

;ENEMY
;BIG_METEOR
LDW $0,7
LDW $2,CHR_ST3_01
CAL SET_SGPRINT_DATA
LDW $0,8
LDW $2,CHR_ST3_02
CAL SET_SGPRINT_DATA
LDW $0,9
LDW $2,CHR_ST3_03
CAL SET_SGPRINT_DATA
LDW $0,10;A
LDW $2,CHR_ST3_04
CAL SET_SGPRINT_DATA

;SMALL_METEOR
LDW $0,11;B
LDW $2,CHR_ST3_05
CAL SET_SGPRINT_DATA

LDW $0,12;BARRIER
LDW $2,CHR_ST3_07
CAL SET_SGPRINT_DATA

LDW $0,13;BF-SPEAR
LDW $2,CHR_ST3_06
CAL SET_SGPRINT_DATA

RTN

ST3_INIT_GRA_B:;BOSS STAGE

LDW $0,7;BOSS1_CORE
LDW $2,CHR_BOSS3_CORE
CAL SET_SGPRINT_DATA

LDW $0,8;BOSS
LDW $2,CHR_BOSS3_LCAN
CAL SET_SGPRINT_DATA

LDW $0,9;BOSS
LDW $2,CHR_BOSS3_GUN
CAL SET_SGPRINT_DATA

;LDW $0,21;BOSS
;LDW $2,CHR_BOSS1_7_2
;CAL SET_SGPRINT_DATA

;LDW $0,22;BOSS
;LDW $2,CHR_BOSS1_7_2
;CAL SET_SGPRINT_DATA

RTN

SET_STAGE3_DATA:
;STAGE3の初期化サブルーチンのアドレス
LDW $0,STAGE_3_INIT
PRE IX,STAGE_INIT
STW $0,(IX+$31)
;STAGE3のマップデータのアドレス
LDW $0,STAGE3_MAP
PRE IX,STAGE_MAP
STW $0,(IX+$31)
;STAGE3のマップに登場する背景キャラクタのデータのアドレス
LDW $0,STAGE3_MAP_CHARA
PRE IX,STAGE_MAP_CHARA
STW $0,(IX+$31)
;STAGE3に登場するの敵のキャラクタデータのアドレス
LDW $0,INIT_DATA_STAGE3
PRE IX,INIT_DATA_STAGE
STW $0,(IX+$31)
;STAGE3の敵の移動サブルーチンのアドレス
LDW $0,ST3_ENEMY_MOVE
PRE IX,ENEMY_MOVE_ADR
STW $0,(IX+$31)
;STAGE3の敵の表示サブルーチンのアドレス
LDW $0,ST3_ENEMY_DISP
PRE IX,ENEMY_DISP_ADR
STW $0,(IX+$31)
;BOSS3初期化サブルーチンのアドレス
LDW $0,BOSS3_INIT
PRE IX,BOSS_INIT_ADR
STW $0,(IX+$31)
;BOSS3登場時の動作サブルーチンのアドレス
LDW $0,BOSS3_PRE
PRE IX,BOSS_PRE_ADR
STW $0,(IX+$31)
;BOSS3移動サブルーチンのアドレス
LDW $0,MOVE_BOSS3
PRE IX,BOSS_MOVE_ADR
STW $0,(IX+$31)
;BOSS3表示サブルーチンのアドレス
LDW $0,DISP_BOSS3
PRE IX,BOSS_DISP_ADR
STW $0,(IX+$31)
;BOSS3の名前が格納されたアドレス
PRE IX,MES_NAME_BOSS3
LDM $0,(IX+$31),8
PRE IX,BOSS_NAME
STM $0,(IX+$31),8
;
;SUPER GPRINT DATA MAKE
CAL ST3_INIT_GRA_S
;
RTN
