;*******************************
;* STAGE4 MAP DATA
;* LCD LINE0 DATA
;* LCD LINE1 DATA
;* LCD LINE2 DATA
;* LCD LINE3 DATA
;* EVENT NO
;*  EVENT NO &HFF - BOSS STAGE
;*******************************

INIT_DATA_STAGE4:
; INITIAL DATA(18POINT)
DB 00,00,00,00,0
DB 15,00,00,00,0
DB 00,00,00,00,0
DB 00,15,00,00,0
DB 00,00,00,15,0
DB 00,00,00,00,0
DB 15,00,00,00,0
DB 00,00,00,00,0
DB 00,15,00,00,0
DB 00,00,00,00,0
DB 00,00,00,00,0
DB 00,00,15,00,0
DB 00,00,00,15,0
DB 15,00,00,00,0
DB 00,00,00,00,0
DB 00,00,00,15,0
DB 00,00,00,00,0
DB 00,00,00,00,0;18

STAGE4_MAP:
DB 00,15,00,00,0;READY,ERASE
DB NO_MAP_DATA;START,ERASE
DB NO_MAP_DATA;READY START DISPLAY END
DB 00,00,15,00,0;GAME START
DB NO_MAP_DATA;DUMMY(1)

;SPACE AREA
;******SPACE AREA**********
;DB 0,0,0,0,&HFF
DB 0,0,0,0,&HF2;群体発生コード
DB 0,0,0,0,23;群体SUPPLY(1-4)
DB 0,0,0,0,24;群体SUPPLY(5-6)
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 15,0,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,15,0
DB 0,0,0,0,&HF2;群隊発生コード
DB 0,0,0,0,25;群隊WEPON(1-4)
DB 0,0,0,0,26;群隊WEPON(5-6)
DB 0,0,15,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,15,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 15,0,0,0,0
DB 0,15,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,15,0
DB NO_MAP_DATA
DB 0,0,0,0,&HF2;群体発生コード
DB 0,0,0,0,27;群隊OPTION(1-4)
DB 0,0,15,0,28;群隊OPTION(5-6)
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 15,0,0,0,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 0,0,0,15,0

DB NO_MAP_DATA;DUMMY
;DB 00,00,00,00,&HFF;DEBUG
DB NO_MAP_DATA
DB 00,00,00,00,29;23
DB 15,00,00,00,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,00,15,00,29;23
DB 00,00,00,00,&HF0
DB NO_MAP_DATA
DB 00,15,00,00,0;10
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,00,00,00,30;24
DB NO_MAP_DATA
DB 00,00,00,15,0
DB 00,00,00,00,29;23
DB 00,00,00,00,&HF0
DB 15,00,00,00,0
DB NO_MAP_DATA
DB NO_MAP_DATA;20
DB 00,15,00,00,30;24
DB 00,00,00,00,29;23
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,00,00,15,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,00,15,00,0
DB NO_MAP_DATA;30
DB NO_MAP_DATA;31

;ATTACKER & DEFENDER AREA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 15,00,00,00,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,00,00,15,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,15,00,00,0
;
DB 00,00,00,00,36;30
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,00,15,00,37;31
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,00,00,15,0
DB 00,00,00,00,36;30
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,15,00,00,0
DB 00,00,00,00,37;31
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 15,00,00,15,0
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB NO_MAP_DATA
DB 00,15,00,00,&HF2
;DEFENSE AREA

;******BASE AREA**********
;DB 0,00,00,0,0;DUMMY
DB 04,00,00,01,1
DB 04,00,00,01,9
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,10
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,22
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,9
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,13

;DB 00,00,00,0,0;DUMMY
DB 03,00,00,01,2
DB 03,00,00,01,11;MIS_BASE_UNDER(Y:24)
DB 03,03,00,01,3
DB 03,03,00,01,0
DB 03,00,00,01,0
DB 03,00,00,01,12;AIR BASE(Y:24)
DB 03,00,00,01,0
DB 03,00,00,01,0
DB 03,03,00,01,3
DB 03,03,00,01,0
DB 03,00,00,01,0
DB 03,00,00,01,0
DB 04,00,00,01,4
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,10;UNDER MIS BASE(Y:32)
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,13

;DB NO_MAP_DATA;DUMMY
DB 04,00,00,03,5
DB 04,00,00,03,14
DB 04,00,03,03,6
DB 04,00,03,03,0
DB 04,00,03,03,0
DB 04,00,03,03,10;UNDER MIS BASE(Y:32)
DB 04,00,03,03,0
DB 04,00,03,03,0
DB 04,00,03,03,0
DB 04,00,00,0,15
DB 04,00,03,03,0
DB 04,00,03,03,0
DB 04,00,03,03,0
DB 04,00,03,03,0
DB 04,00,03,03,21;ABOVE MIS BASE(Y:24)
DB 04,00,00,00,15
DB 04,00,03,03,0
DB 04,00,03,03,10;UNDER MIS BASE(Y:32)
DB 04,00,00,00,15
DB 04,00,03,03,0
DB 04,00,03,03,21;ABOVE MIS BASE(Y:24)
DB 04,00,00,00,15
DB 04,00,03,03,0
DB 04,00,03,03,0

;DB 04,0,0,2,0;DUMMY
DB 04,00,00,02,7
DB 04,00,00,02,0
DB 04,00,00,02,0
DB 04,01,00,01,0
DB 04,03,04,01,8
DB 04,00,04,01,0
DB 04,00,04,01,0
DB 04,00,04,01,0
DB 04,00,04,01,17
DB 04,00,04,01,0
DB 04,00,04,01,0
DB 04,00,04,01,0
DB 04,00,04,01,18
DB 04,00,04,01,0
DB 04,00,04,01,0
DB 04,00,04,01,19
DB 04,00,04,01,0
DB 04,00,04,01,19
DB 04,00,04,01,0
DB 04,00,04,01,0
DB 04,00,04,01,0
DB 04,00,04,01,0

;------------BASE AREA END ----------------

;BOSS AREA
DB 04,00,00,01,1
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,0
DB 04,00,00,01,&HFF ;BOSS

;******************************************************
;*              STAGE4 MAP CHARACTOR
;******************************************************
STAGE4_MAP_CHARA:
MAP4_CHR00:DB 0,0,0,0,0,0,0,0 ;無地背景
;MAP AREA BG

;********* CHARACTOR
;BASE
MAP4_CHR01:DB &HC0,&HC0,&HC0,&HC0,&HC0,&HC0,&HC0,&HC0;91
MAP4_CHR02:DB &HF0,&HF0,&HF0,&HF0,&HF0,&HF0,&HF0,&HF0;92
MAP4_CHR03:DB &HFF,&HFF,&HFF,&HFF,&HFF,&HFF,&HFF,&HFF;94
MAP4_CHR04:DB &H03,&H03,&H03,&H03,&H03,&H03,&H03,&H03;97
;

;上段
MAP4_CHR05:DB &H21,&H22,&H64,&HA5,&HA5,&HA4,&HA2,&HA1
MAP4_CHR06:DB &H90,&H8E,&HB2,&H42,&H8E,&H92,&H92,&H92
MAP4_CHR07:DB &H92,&H92,&H92,&H92,&H8E,&H42,&H32,&H0E
MAP4_CHR08:DB &H02,&H7E,&H86,&HA8,&H90,&H90,&H95,&H91
MAP4_CHR09:DB &H91,&H91,&H91,&H91,&H95,&H90,&HE0,&H20
;下段
MAP4_CHR10:DB &HE1,&H11,&HC9,&H29,&H29,&HC9,&H09,&HD2
MAP4_CHR11:DB &H52,&H52,&H52,&H52,&H52,&H52,&H22,&H02
MAP4_CHR12:DB &H02,&H22,&H52,&H52,&H72,&H52,&H72,&H52
MAP4_CHR13:DB &H52,&H22,&H02,&H02,&H3C,&HD4,&H54,&H74
MAP4_CHR14:DB &H04,&H04,&H74,&H54,&H54,&HFE,&H01,&H01
;星
MAP4_CHR15:;STAR
DB &H00,&H40,&H00,&H00,&H02,&H00,&H20,&H00

;******************************************************
;*              STAGE4 ENEMY CHARACTOR
;******************************************************

CHR_ST4_AIRBASE:
DB &H7F,&H80,&H98,&HD0,&H50,&H44,&H4C,&H48;88
DB &H48,&H4C,&H44,&H50,&HD0,&H98,&H80,&H7F

CHR_ST4_BASE_A1:DB &HFE,&H09,&H09,&H07,&H01,&H01,&H01,&HFE;89
CHR_ST4_BASE_A2:DB &HFE,&H01,&H07,&H09,&H09,&H07,&H01,&HFE;89
CHR_ST4_BASE_A3:DB &HFE,&H01,&H01,&H01,&H07,&H09,&H09,&HFE;89
CHR_ST4_BASE_A4:DB &HFE,&H25,&H25,&H19,&H01,&H01,&H01,&HFE;89
CHR_ST4_BASE_A6:DB &HFE,&H01,&H01,&H01,&H19,&H25,&H25,&HFE;89

CHR_ST4_BASE_U4:DB &H7F,&HA4,&HA4,&H98,&H80,&H80,&H80,&H7F;90
CHR_ST4_BASE_U6:DB &H7F,&H80,&H80,&H80,&H98,&HA4,&HA4,&H7F;90
CHR_ST4_BASE_U7:DB &H7F,&H90,&H90,&HE0,&H80,&H80,&H80,&H7F;90
CHR_ST4_BASE_U8:DB &H7F,&H80,&HE0,&H90,&H90,&HE0,&H80,&H7F;90
CHR_ST4_BASE_U9:DB &H7F,&H80,&H80,&H80,&HE0,&H90,&H90,&H7F;90

CHR_ST4_01:DB &H3C,&H5E,&H97,&HF3,&H73,&H37,&H67,&HFE;AIRBORN
CHR_ST4_02:DB &HFF,&HFF,&HFF,&H81,&HFF,&HE7,&H3C,&H3C;DEFENDER
CHR_ST4_03:DB &HE7,&HA5,&HE7,&HBD,&H99,&HC3,&H5A,&H66;ATTACKER1,2
CHR_ST4_04:DB &H66,&HC3,&HA5,&H18,&H18,&HA5,&HC3,&H66;CIRCULAR

;補給物品
CHR_ST4_SHUTTER:DB &HFF,&HD5,&HAB,&HD5,&HAB,&HD5,&HAB,&HFF
CHR_ST4_DOOR:DB &HFF,&H81,&HBD,&HA5,&HA5,&HBD,&H81,&HFF
CHR_ST4_CONT:DB &HFF,&H87,&HB7,&H97,&H97,&HB7,&H87,&HFF
CHR_ST4_CONT_BIG:;(16*16)
DB &H3F,&H20,&H28,&H2F,&H20,&H2F,&H28,&H20
DB &H20,&H28,&H2F,&H20,&H2F,&H28,&H20,&H3F
DB &HFF,&H07,&H17,&HF7,&H07,&HF7,&H17,&H07
DB &H07,&H17,&HF7,&H07,&HF7,&H17,&H07,&HFF
CHR_ST4_AIRPLANE:DB &H3B,&H6B,&HEF,&H9B,&H5B,&H5F,&H8B,&HFB

;******************************************************
;*              STAGE4 BOSS CHARACTOR
;******************************************************
CHR_BOSS4_CORE:;8*8(99)
DB &H7C,&H82,&H93,&HBB,&HBB,&H93,&H82,&H7C
CHR_BOSS4_BODY:;8*8(230)
DB &HFF,&HFF,&HFF,&HFF,&HFF,&HFF,&HFF,&HFF
CHR_BOSS4_L_LEG:;8*8(231)
DB &H23,&H7F,&HFF,&HFF,&HFF,&HFF,&HFF,&HFF
CHR_BOSS4_R_LEG:;8*8(232)
DB &HFF,&HFF,&HFF,&HFF,&HFF,&HFF,&H7F,&H23
CHR_BOSS4_FOOT:;8*8(233)
DB &HFE,&HFF,&HFF,&HFF,&HFF,&HFF,&HFF,&HFE

;******************************************************
;*              STAGE4 SENARIO INITIALIZE
;******************************************************
STAGE_4_INIT:
PRE IX,BASE_SENARIO_PTR
LDW $0,SCENARIO
STW $0,(IX+$31)

PRE IX,SCENARIO
LDW $0,ST4_SCENARIO_00 ;DUMMY
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_01
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_02
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_03
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_04
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_05
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_06
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_07
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_08
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_09
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_10
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_11
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_12
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_13
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_14
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_15
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_16
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_17
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_18
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_19
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_20
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_21
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_22
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_23
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_24
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_25
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_26
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_27
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_28
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_29
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_30
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_31
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_32
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_33
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_34
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_35
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_36
STIW $0,(IX+$31)
LDW $0,ST4_SCENARIO_37
STIW $0,(IX+$31)
;シナリオを追加する場合はここを修正(MAX64POINT)
RTN

;**********************************
;*    STAGE4 SCENARIO DATA
;*      (9BYTE:MAX64POINT)
;* 1:TIMING(出現タイミング+カウント(今回は1ドットスクロールなので0～7))
;* 2:ENEMY NO
;* 3:X
;* 4:Y
;* 5:LENGTH-X
;* 6:LENGTH-Y
;* 7:COUNTER1
;* 8:COUNTER2
;* 9:LIFE
;* 10:SCORE
;* 11:DAMAGE
;*
;*注意:必ず11BYTE定義すること
;*
;**********************************
ST4_SCENARIO_00: ;出現しない
DB &HFF ;END CODE

;------------ MAP ----------------------

ST4_SCENARIO_01:;MAP1
DB 0,230,136,08,&HF8,2,0,0,&HF8,0,10;最長248(&HF8)
DB 0,236,136,38,&HF8,2,0,0,&HF8,0,10;U2最長248(&HF8)
DB &HFF ;END CODE

ST4_SCENARIO_02:;MAP2
DB 0,230,136,08,&HB0,2,0,0,&HFF,0,10
DB 0,233,136,32,&H60,8,0,2,&HFF,2,10
DB &HFF ;END CODE

ST4_SCENARIO_03:;MAP3
DB 0,233,136,24,&H10,8,0,0,&HFF,2,10
DB &HFF ;END CODE

ST4_SCENARIO_04:;MAP4
DB 0,236,136,38,&H50,2,0,0,&HFF,0,10;U2
DB &HFF ;END CODE

ST4_SCENARIO_05:;MAP5
DB 0,233,136,08,&HC0,8,0,0,&HFF,0,10
DB 0,236,136,38,&HC0,2,0,0,&HFF,0,10;U2
DB &HFF ;END CODE

ST4_SCENARIO_06:;MAP6
DB 0,233,136,16,&HB0,8,0,0,&HFF,0,10
DB &HFF ;END CODE

ST4_SCENARIO_07:;MAP7
DB 0,231,136,08,&H20,4,0,0,&HFF,0,10
DB 0,236,136,38,&HB0,2,0,0,&HFF,0,10;U2
DB &HFF ;END CODE

ST4_SCENARIO_08:;MAP8
DB 0,230,128,24,&H08,2,0,0,&HFF,0,10;突起部
DB 0,230,136,08,&H90,2,0,0,&HFF,0,10
DB 0,236,136,22,&H90,2,0,0,&HFF,0,10
DB 0,233,136,24,&H08,8,0,0,&HFF,0,10
DB 0,201,136,32,&H08,8,0,0,&H03,1,10;隠し扉(Y:32)
DB &HFF ;END CODE
;------------ MAP END --------------

;------------ IN MAP ENEMY ----------

ST4_SCENARIO_09:
DB 0,150,136,32,08,8,0,0,&H00,1,1;UNDER MIS BASE(Y:32)
DB 0,140,136,08,08,8,0,0,&H00,1,1;ABOVE MIS BASE(Y:08)
DB &HFF ;END CODE

ST4_SCENARIO_10:
DB 0,150,136,32,08,8,0,0,&H00,1,1;UNDER MIS BASE(Y:32)
DB &HFF ;END CODE

ST4_SCENARIO_11:
DB 0,150,136,24,08,8,0,0,&H00,1,1;UNDER MIS BASE(Y:24)
DB &HFF ;END CODE

ST4_SCENARIO_12:
DB 0,160,136,24,16,8,0,0,&H00,3,1;AIR BASE(Y:24)
DB &HFF ;END CODE

ST4_SCENARIO_13:
DB 0,140,136,08,08,8,0,0,&H00,1,1;ABOVE MIS BASE(Y:08)
DB &HFF ;END CODE

ST4_SCENARIO_14:
DB 0,140,136,16,08,8,0,0,&H00,1,1;ABOVE MIS BASE(Y:16)
DB &HFF ;END CODE

ST4_SCENARIO_15:
DB 0,200,136,08,08,16,50,0,&H0A,0,1;シャッター(Y:8)
DB &HFF ;END CODE

ST4_SCENARIO_16:
DB 0,201,136,32,08,08,00,0,&H05,1,1;隠し扉(Y:32)
DB &HFF ;END CODE

ST4_SCENARIO_17:
DB 0,175,136,32,08,08,00,0,&H03,10,1;コンテナ(Y:32)
DB &HFF ;END CODE

ST4_SCENARIO_18:
DB 0,170,136,24,16,16,00,0,&H0A,100,1;大型コンテナ(Y:24)
DB &HFF ;END CODE

ST4_SCENARIO_19:
DB 0,180,136,32,08,08,00,0,&H00,10,1;飛行機(駐機)(Y:32)
DB &HFF ;END CODE

ST4_SCENARIO_20:
DB 0,150,136,24,08,8,0,0,&H00,1,1;UNDER MIS BASE(Y:24)
DB &HFF ;END CODE

ST4_SCENARIO_21:
DB 0,140,136,24,08,8,0,0,&H00,1,1;ABOVE MIS BASE(Y:24)
DB &HFF ;END CODE

ST4_SCENARIO_22:
DB 0,160,136,32,16,8,0,0,&H00,3,1;AIR BASE(Y:32)
DB &HFF ;END CODE

;--------------- STAGE4 START ----------------
ST4_SCENARIO_23:
DB 0,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 2,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 4,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 6,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB &HFF ;END CODE
ST4_SCENARIO_24:
DB 0,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB 2,90,136,20,8,8,0,1,&HFF,2,1;WAVE(LIFE&BOMB)
DB &HFF ;END CODE
ST4_SCENARIO_25:
DB 0,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 2,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 4,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 6,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB &HFF ;END CODE
ST4_SCENARIO_26:
DB 0,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB 2,90,136,20,8,8,0,2,&HFF,2,1;WAVE(WEPON)
DB &HFF ;END CODE
ST4_SCENARIO_27:
DB 0,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 2,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 4,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 6,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB &HFF ;END CODE
ST4_SCENARIO_28:
DB 0,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB 2,90,136,20,8,8,0,3,&HFF,2,1;WAVE(OPTION)
DB &HFF ;END CODE

ST4_SCENARIO_29:;飛行機
DB 0,190,144,08,08,08,00,0,&H00,1,1;飛行機
DB 0,190,136,20,08,08,00,0,&H00,1,1;飛行機
DB 0,190,144,32,08,08,00,0,&H00,1,1;飛行機
DB &HFF ;END CODE

ST4_SCENARIO_30:;CIRCULER
DB 0,100,136,08,08,08,40,0,&H00,1,1;CIRCULER1
DB 0,110,002,32,08,08,40,0,&H00,1,1;CIRCULER2
DB 2,100,136,08,08,08,40,0,&H00,1,1;CIRCULER1
DB 2,110,002,32,08,08,40,0,&H00,1,1;CIRCULER2
DB 4,100,136,08,08,08,40,0,&H00,1,1;CIRCULER1
DB 4,110,002,32,08,08,40,0,&H00,1,1;CIRCULER2
DB 6,100,136,08,08,08,40,0,&H00,1,1;CIRCULER1
DB 6,110,002,32,08,08,40,0,&H00,1,1;CIRCULER2
DB &HFF ;END CODE

ST4_SCENARIO_31:
DB &HFF ;END CODE

ST4_SCENARIO_32:
DB &HFF ;END CODE

ST4_SCENARIO_33:
DB &HFF ;END CODE

ST4_SCENARIO_34:
DB &HFF ;END CODE

ST4_SCENARIO_35:
DB &HFF ;END CODE

;-------------- AFTER MAP ---------------
ST4_SCENARIO_36:;DEFENDER+ATTACKER-1
DB 0,202,136,08,8,8,00,0,&HFF,0,1;DEFENDER
DB 0,202,136,24,8,8,00,0,&HFF,0,1;DEFENDER
DB 6,120,136,08,8,8,16,0,&H00,1,1
DB 6,120,136,24,8,8,16,0,&H00,1,1
DB &HFF ;END CODE

ST4_SCENARIO_37:;DEFENDER+ATTACKER-1
DB 0,202,136,16,8,8,00,0,&HFF,0,1;DEFENDER
DB 0,202,136,32,8,8,00,0,&HFF,0,1;DEFENDER
DB 6,130,136,16,8,8,16,0,&H00,1,1
DB 6,130,136,32,8,8,16,0,&H00,1,1
DB &HFF ;END CODE

;16以上追加する場合はSTAGE_2_INITを修正(MAX64POINT)

;*********************************
;*        ENEMY MOVE
;*
;* $9-$25   ENEMY DATA
;* $28      COUNTER
;*********************************
ST4_ENEMY_MOVE:

LD $28,$31

;**********************************************
;           　　STAGE4の特殊処理
;
;地上物については背景のスクロールと同期させるため2回に1回
;左に移動させる処理を行う。
;地上物(キャラNo70以降)及び背景と同期状態(垂直上昇中)の
;飛行物体の左移動($10)-1については、$30ではなく$29を使用すること。
;
;**********************************************
PRE IZ,GLOBAL_COUNTER
LD $29,(IZ+$31)
AN $29,$30 ;1
;
;特殊処理終了

ST4_ENEMYMOVE_LP:
PRE IX,ENEMY_DATA
;
PHUW $29
;
LDM $9,(IX+$28),8
SBC $9,$31
JR Z,NEXT_ST4_ENEMY_M

;-------- NOT ACTIVE FLAG(0) ------------------------------
;-------- 全ての衝突判定対象外のオブジェクト(001-089)(MAKE JUDGEで撥ねる)---
;-------- BULLET(89:固定) -----------------------------------
SBC $9,89
JP Z,ST4_ENEMY89_MOVE;BULLET
;-------- 自弾(GUN,LASER)と衝突判定を行わない敵オブジェクト(000-089)
;-------- DROP ITEM MOTHER(90)---------------------------------
SBC $9,90
JP Z,ST4_ENEMY90_MOVE;WAVE
;-------- BOSS CORE(99:固定) -----------------------------------
;-------- NORMAL(100-199)----------------------------------
SBC $9,165
JP Z,ST4_ENEMY165MOVE;AIRBORN       ;10->165
SBC $9,120
JP Z,ST4_ENEMY120MOVE;ATTACKER1     ;12->120
SBC $9,130
JP Z,ST4_ENEMY130MOVE;ATTACKER2     ;13->130
SBC $9,175
JP Z,ST4_ENEMY175MOVE;コンテナ         ;17->175
SBC $9,170
JP Z,ST4_ENEMY170MOVE;大型コンテナ      ;18->170
SBC $9,180
JP Z,ST4_ENEMY180MOVE;飛行機(駐機)    ;19->180
SBC $9,190
JP Z,ST4_ENEMY190MOVE;飛行機         ;20->190
SBC $9,100
JP Z,ST4_ENEMY100MOVE;CIRCULER1     ;21->100
SBC $9,110
JP Z,ST4_ENEMY110MOVE;CIRCULER2     ;22->110
SBC $9,160
JP Z,ST4_ENEMY160MOVE;AIR_BASE      ;88->160
SBC $9,140
JP Z,ST4_ENEMY140MOVE;MIS_BASE_ABOVE;89->140
SBC $9,150
JP Z,ST4_ENEMY150MOVE;MIS_BASE_UNDER;90->150
;-----レーザーが衝突するとレーザーが縮む敵オブジェクト(200-229)---------------
SBC $9,200
JP Z,ST4_ENEMY200MOVE;シャッター
SBC $9,201
JP Z,ST4_ENEMY201MOVE;隠し扉
SBC $9,202
JP Z,ST4_ENEMY202MOVE;DEFENDER ;11->202
;-----レーザーが衝突するとレーザーが縮む無敵の敵オブジェクト(230-255)(壁など)----
SBC $9,&HFF
JP C,ST4_GROUND_MOVE
SBC $9,234;U2
JP Z,ST4_ENEMY234MOVE
SBC $9,235;U4
JP Z,ST4_ENEMY235MOVE
SBC $9,236;U4
JP Z,ST4_ENEMY236MOVE

NEXT_ST4_ENEMY_M:
;
PPUW $28
;
AD $28,ENEMY_STRUCT

JP NC,ST4_ENEMYMOVE_LP

RTN

ST4_ENEMY89_MOVE:;BULLET
CAL MOVE_BULLET
JP NEXT_ST4_ENEMY_M

ST4_ENEMY90_MOVE:;WAVE(各面に登場するため細部は別ファイルに分離)
CAL ENEMY_WAVE_MOVE
JP C,ST4_KILL_ENEMY
JP END_ST4ENEMYMOVE

ST4_ENEMY100MOVE:;CIRCLE1

ST4_E100_SELECT:
SBC $15,$30
JR Z,ST4_E100_SEC1
SBC $15,2
JR Z,ST4_E100_SEC2

ST4_E100_SEC0:
SB $10,3
SB $14,$30
JP NC,END_ST4ENEMYMOVE
LD $14,2
LD $15,$30
JP END_ST4ENEMYMOVE

ST4_E100_SEC1:
AD $11,2
SB $14,$30
JP NC,END_ST4ENEMYMOVE
LD $15,2
JP END_ST4ENEMYMOVE

ST4_E100_SEC2:
AD $10,3
SBC $10,130
JP NC,ST4_KILL_ENEMY;ENEMY21 KILL
JP END_ST4ENEMYMOVE

ST4_ENEMY110MOVE:;CIRCULER2

ST4_E110_SELECT:
SBC $15,$30
JR Z,ST4_E110_SEC1
SBC $15,2
JR Z,ST4_E110_SEC2

ST4_E110_SEC0:
AD $10,3
SB $14,$30
JP NC,END_ST4ENEMYMOVE
LD $14,2
LD $15,$30
JP END_ST4ENEMYMOVE

ST4_E110_SEC1:
SB $11,2
SB $14,$30
JP NC,END_ST4ENEMYMOVE
LD $15,2
JP END_ST4ENEMYMOVE

ST4_E110_SEC2:
SB $10,3
JP C,ST4_KILL_ENEMY;ENEMY22 KILL
JP END_ST4ENEMYMOVE

ST4_ENEMYCD_WAIT:EQU 16

ST4_ENEMY120MOVE:;ATTACKER1
LD $0,$30
JP ST4_ENECD_COMMON

ST4_ENEMY130MOVE:;ATTACKER2
LD $0,&HFF

;***********************************
;*       PARA
;* $0:MOVE1 Y ADD
;* ($0:1 OR &HFF)
;***********************************
ST4_ENECD_COMMON:
SB $10,$30
JP C,ST4_KILL_ENEMY

SB $14,$30

ST4_ENECD_SELECT:
SBC $15,$30;MOVE1
JR Z,ST4_ENEMYCD_SEC1
SBC $15,2;FIRE
JR Z,ST4_ENEMYCD_SEC2
SBC $15,3;MOVE2
JR Z,ST4_ENEMYCD_SEC3

;WAIT
SBC $14,$31
JP NZ,END_ST4ENEMYMOVE
LD $15,$30
LD $14,ST4_ENEMYCD_WAIT
JP END_ST4ENEMYMOVE

ST4_ENEMYCD_SEC1:;MOVE1
AD $11,$0
SBC $14,ST4_ENEMYCD_WAIT-8
JP NZ,END_ST4ENEMYMOVE
LD $15,2
LD $14,ST4_ENEMYCD_WAIT
JP END_ST4ENEMYMOVE

ST4_ENEMYCD_SEC2:;FIRE
PHUW $11
LD $5,4
AD $11,4
CAL INSERT_BULLET
PPUW $10
LD $15,3
LD $14,ST4_ENEMYCD_WAIT
JP END_ST4ENEMYMOVE

ST4_ENEMYCD_SEC3:;MOVE2
SB $11,$0
SBC $14,ST4_ENEMYCD_WAIT-8
JP NZ,END_ST4ENEMYMOVE
LD $15,$31
LD $14,ST4_ENEMYCD_WAIT
JP END_ST4ENEMYMOVE

ST4_ENEMY165MOVE:
SBC $15,$30
JR Z,ST4_ENEMY165SEC1
SB $10,$29;垂直上昇中で背景と同期
SB $11,$30
SBC $11,14
JP NZ,END_ST4ENEMYMOVE
LD $15,$30
JP END_ST4ENEMYMOVE
ST4_ENEMY165SEC1:
SB $10,3
JP C,ST4_KILL_ENEMY
JP END_ST4ENEMYMOVE

ST4_ENEMY200MOVE:;シャッター
SB $10,$29;背景と同期
JP C,ST4_KILL_ENEMY
SBC $15,$30
JR Z,ST4_ENEMY15_PH1
SBC $15,2;PHASE2は何もしない
JP Z,END_ST4ENEMYMOVE
SB $14,$30
JP NZ,END_ST4ENEMYMOVE
LD $14,16
LD $15,$30;PHASE1へ移行
JP END_ST4ENEMYMOVE
ST4_ENEMY15_PH1:
AD $11,$30
SB $14,$30
JP NZ,END_ST4ENEMYMOVE
LD $15,2;PHASE2へ移行
JP END_ST4ENEMYMOVE

ST4_ENEMY175MOVE:;コンテナ
ST4_ENEMY170MOVE:;大型コンテナ
ST4_ENEMY180MOVE:;飛行機(駐機)
ST4_ENEMY201MOVE:;隠し扉
SB $10,$29;背景と同期
JP C,ST4_KILL_ENEMY
JP END_ST4ENEMYMOVE

ST4_ENEMY190MOVE:;飛行機
SB $10,3
JP C,ST4_KILL_ENEMY
JP END_ST4ENEMYMOVE

ST4_ENEMY202MOVE:;DEFENDER
SB $10,$30
JP C,ST4_KILL_ENEMY
JP END_ST4ENEMYMOVE

ST4_AIRBORN_WAIT:EQU 16
ST4_ENEMY165DATA:
DB 8,8,20,0,&H00,2,1;NO,X,Yは含まない

ST4_ENEMY160MOVE:;AIR_BASE
SB $10,$29
JP C,ST4_KILL_ENEMY

;ENEMY_X-MY_X<80なら飛行機を飛ばす
PRE IZ,MY_X
LD $0,(IZ+$31)
LD $1,$10
SB $1,$0
SBC $1,80
JP NC,END_ST4ENEMYMOVE

SB $14,$30
JP NC,END_ST4ENEMYMOVE
LD $17,165
LD $18,$10
AD $18,4
LD $19,$11
SB $19,4
PRE IZ,ST4_ENEMY165DATA
LDM $20,(IZ+$31),7
CAL INSERT_OBJECT
LD $14,ST4_AIRBORN_WAIT
JP END_ST4ENEMYMOVE

;*****************　地上物

ST4_MIS_WAIT:EQU 32

ST4_ENEMY140MOVE:;MIS_BASE_ABOVE
SB $10,$29;背景と同期
JP C,ST4_KILL_ENEMY
LD $26,$10
AD $26,4
LD $27,$11
PRE IZ,MY_X
LDW $24,(IZ+$31)
CAL CALDIR
SBC $5,7
JP NC,ST4_ENE140DSKIP
LD $15,$5
ST4_ENE140DSKIP:
AD $14,$30
SBC $14,ST4_MIS_WAIT
JP C,END_ST4ENEMYMOVE
PHUW $11
AD $10,4
AD $11,6
CAL INSERT_BULLET
PPUW $10
LD $14,$31
JP END_ST4ENEMYMOVE

ST4_ENEMY150MOVE:;MIS_BASE_UNDER
SB $10,$29;背景と同期
JP C,ST4_KILL_ENEMY
LD $26,$10
AD $26,4
LD $27,$11
PRE IZ,MY_X
LDW $24,(IZ+$31)
CAL CALDIR
SBC $5,4
JP C,ST4_ENE150DSKIP
LD $15,$5
ST4_ENE150DSKIP:
AD $14,$30
SBC $14,ST4_MIS_WAIT
JP C,END_ST4ENEMYMOVE
PHUW $11
AD $10,4
AD $11,2
CAL INSERT_BULLET
PPUW $10
LD $14,$31
JP END_ST4ENEMYMOVE

ST4_ENEMY233MOVE:;GROUND
ST4_ENEMY234MOVE:;GROUND
ST4_ENEMY235MOVE:;GROUND
ST4_ENEMY236MOVE:;GROUND
ST4_GROUND_MOVE:;GROUND
;地形のLIFEをMAX(&HFF)にする
LD $16,&HFF
;
SB $10,$29;背景と同期
JR NZ,END_ST4ENEMYMOVE
SB $12,8
JR Z,ST4_KILL_ENEMY
JR C,ST4_KILL_ENEMY
AD $10,8

END_ST4ENEMYMOVE:
;DATA SAVE & MAKE JUDGE DATA
PRE IX,ENEMY_DATA
STM $9,(IX+$28),8
JP NEXT_ST4_ENEMY_M

ST4_KILL_ENEMY:
CAL DELETE_OBJECT
JP NEXT_ST4_ENEMY_M

;*********************************
;*        STAGE4 ENEMY DISP
;*********************************
ST4_ENEMY_DISP:

LD $28,$31

ST4_ENEMYDISP_LP:
PRE IX,ENEMY_DATA

LDM $9,(IX+$28),8
SBC $9,$31
JP Z,NEXT_ST4_ENEMY_D
;
PHU $28
;
;GPRINTのRTN命令でRTN_ST4_EDISPに戻れるようにするため、RTN_ST4_EDISPのアドレスを
;SSPにPUSHしておく。
;なおGPRINTからの復帰はRTNでありSSPにスタックされたアドレス+1からプログラムを実行するため
;RTN_ST4_EDISPのアドレスから-1したものをSSPにPUSHする。
LDW $0,RTN_ST4_EDISP-1
PHSW $1



;-------- NOT ACTIVE FLAG(0) ------------------------------
;-------- 全ての衝突判定対象外のオブジェクト(001-089)(MAKE JUDGEで撥ねる)---
;-------- BULLET(89:固定) -----------------------------------
SBC $9,89
JR Z,ST4_ENEMY89_DISP;BULLET
;-------- 自弾(GUN,LASER)と衝突判定を行わない敵オブジェクト(000-089)
;-------- DROP ITEM MOTHER(90)---------------------------------
SBC $9,90
JR Z,ST4_ENEMY90_DISP;WAVE
;-------- BOSS CORE(99:固定) -----------------------------------
;-------- NORMAL(100-199)----------------------------------
;SBC $9,100
;JP Z,ST4_ENEMY100DISP;CIRCULER1     ;21->100
SBC $9,120
JP C,ST4_ENEMY110DISP;CIRCULER2     ;22->110
;SBC $9,120
;JP Z,ST4_ENEMY120DISP;ATTACKER1     ;12->120
SBC $9,140
JP C,ST4_ENEMY130DISP;ATTACKER2     ;13->130
SBC $9,140
JP Z,ST4_ENEMY140DISP;MIS_BASE_ABOVE;89->140
SBC $9,150
JP Z,ST4_ENEMY150DISP;MIS_BASE_UNDER;90->150
SBC $9,160
JP Z,ST4_ENEMY160DISP;AIR_BASE      ;88->160
SBC $9,165
JP Z,ST4_ENEMY165DISP;AIRBORN       ;10->165
SBC $9,170
JP Z,ST4_ENEMY170DISP;大型コンテナ      ;18->170
SBC $9,175
JP Z,ST4_ENEMY175DISP;コンテナ         ;17->175
SBC $9,180
JP Z,ST4_ENEMY180DISP;飛行機(駐機)    ;19->180
SBC $9,190
JP Z,ST4_ENEMY190DISP;飛行機         ;20->190

;-----レーザーが衝突するとレーザーが縮む敵オブジェクト(200-229)---------------
SBC $9,200
JP Z,ST4_ENEMY200DISP;シャッター
SBC $9,201
JP Z,ST4_ENEMY201DISP;隠し扉
SBC $9,202
JP Z,ST4_ENEMY202DISP;DEFENDER
;-----レーザーが衝突するとレーザーが縮む無敵の敵オブジェクト(230-255)(壁など)----
;BG画面で描画するため不要
;SBC $9,230
;JP Z,ST4_ENEMY230DISP;DEBUG
;SBC $9,231
;JP Z,ST4_ENEMY231DISP;DEBUG
;SBC $9,232
;JP Z,ST4_ENEMY232DISP;DEBUG
;SBC $9,233
;JP Z,ST4_ENEMY233DISP;DEBUG
;SBC $9,234
;JP Z,ST4_ENEMY234DISP;DEBUG
;SBC $9,235
;JP Z,ST4_ENEMY235DISP;DEBUG
;SBC $9,236
;JP Z,ST4_ENEMY236DISP;DEBUG

;JUMPしなかった場合はSSPを戻す。
PPSW $0

RTN_ST4_EDISP:
;
PPU $28
;
NEXT_ST4_ENEMY_D:

AD $28,ENEMY_STRUCT

JP NC,ST4_ENEMYDISP_LP

RTN

ST4_ENEMY89_DISP:;BULLET
LD $12,4
LDW $13,@CHR_BULLET
JP SGPRINT_4

ST4_ENEMY90_DISP:;WAVE
JP ENEMY_WAVE_DISP

ST4_ENEMY100DISP:;CIRCULER1
ST4_ENEMY110DISP:;CIRCULER2
LDW $13,SG_CHR_DATA07
JP SGPRINT_FAST

ST4_ENEMY120DISP:;ATTACKER1
ST4_ENEMY130DISP:;ATTACKER2
LDW $13,SG_CHR_DATA08
JP SGPRINT_FAST

ST4_ENEMY140DISP:
SBC $15,6
JR Z,ST4_ENE140DIR6
LD $1,$31
LD $0,$15
SB $0,1
BIU $0
BIU $0
BIU $0
LDW $13,CHR_ST4_BASE_A1
ADW $13,$0
JP CPRINT_OR
ST4_ENE140DIR6:
LDW $13,CHR_ST4_BASE_A6
JP CPRINT_OR

ST4_ENEMY150DISP:;MIS_BASE_UNDER
SBC $15,4
JR Z,ST4_ENE90_DIR4
LD $1,$31
LD $0,$15
SB $0,6
BIU $0
BIU $0
BIU $0
LDW $13,CHR_ST4_BASE_U6
ADW $13,$0
JP CPRINT_OR
ST4_ENE90_DIR4:
LDW $13,CHR_ST4_BASE_U4
JP CPRINT_OR

LDW $13,CHR_ST4_AIRBASE
JP CPRINT_OR

ST4_ENEMY160DISP:
LDW $13,CHR_ST4_AIRBASE
JP CPRINT_OR

ST4_ENEMY165DISP:;AIRBORN
LDW $13,SG_CHR_DATA09
JP SGPRINT_FAST

ST4_ENEMY170DISP:;コンテナ大
PHUW $11
LD $12,16
LDW $13,CHR_ST4_CONT_BIG
CAL CPRINT_OR
PPUW $10
LD $12,16
AD $11,8
LDW $13,CHR_ST4_CONT_BIG+16
JP CPRINT_OR

ST4_ENEMY175DISP:;コンテナ
LDW $13,CHR_ST4_CONT
JP CPRINT_OR

ST4_ENEMY180DISP:;飛行機(駐機)
LDW $13,CHR_ST4_AIRPLANE
JP CPRINT_OR

ST4_ENEMY190DISP:;飛行機
LDW $13,SG_CHR_DATA08;CHR_BOSS4_F_FIGHTER
JP SGPRINT_FAST


;---------- レーザーが当たると貫通せず、レーザーの長さが短くなる敵(200-230)------------
ST4_ENEMY200DISP:;シャッター(Y:8)
PHUW $11
LD $12,8
LDW $13,CHR_ST4_SHUTTER
CAL GPRINT
PPUW $10
LD $12,8
AD $11,8
LDW $13,CHR_ST4_SHUTTER
JP GPRINT

ST4_ENEMY201DISP:;隠し扉
LDW $13,CHR_ST4_DOOR
JP CPRINT_OR

ST4_ENEMY202DISP:;DEFENDER
LDW $13,CHR_ST4_02
JP CPRINT_OR

;****** MAPはBG画面に描画するため不要
;ST4_ENEMY230DISP: ;DEBUG
;ST4_ENEMY231DISP: ;DEBUG
;ST4_ENEMY232DISP: ;DEBUG
;ST4_ENEMY233DISP: ;DEBUG
;ST4_ENEMY234DISP: ;DEBUG
;ST4_ENEMY235DISP: ;DEBUG
;ST4_ENEMY236DISP: ;DEBUG
;SB $11,4
;LD $12,8
;LDW $13,CHR_WHITE_BOX
;JP GPRINT


;*********************************
;*          BOSS4 INIT
;*  +0($9)  種類(0:未使用フラグ,&H01～&HFF)
;*  +1($10)  x(必須)
;*  +2($11)  y(必須)
;*  +3($12)  キャラのXサイズ
;*  +4($13)  キャラのYサイズ
;*  +5($14)  NONE
;*  +6($15)  NONE
;*  +7($16)  LIFE(Cフラグで破壊)(&HFF:破壊不能)
;**********************************
;
;NOTE
;BOSS4は12のパーツで構成されている。
;PARTS Noは次のとおり
;
;                   099
;       231.230.230.230.230.230.232
;       230                     230
;       233                     233
;
;動作の際は下記の各パーツのインデックスアドレスを
;直接指定してX,Yの位置加算、減算;している。
;
;235,235,235,235,235,235,235..
;
;LEFT-LEG<- ->RIGHT LEG
;          0
;       4321789
;       5     A
;       6     B
;
;236,236.236,236,236,236,236..
;
; 0:ENEMY_DATA_0 = 099:BOSS4 CORE(0)
; 1:ENEMY_DATA_1 = 230:BOSS4 BODY(1)
; 2:ENEMY_DATA_2 = 230:BOSS4_L_LEG_P1_C(2)
; 3:ENEMY_DATA_3 = 230:BOSS4_L_LEG_P2_C(3)
; 4:ENEMY_DATA_4 = 231:BOSS4_L_LEG_P3_C(4)
; 5:ENEMY_DATA_5 = 230:BOSS4_L_LEG_P4_C(5)
; 6:ENEMY_DATA_6 = 233:BOSS4_L_LEG_P5_C(6)
; 7:ENEMY_DATA_7 = 230:BOSS4_R_LEG_P1_C(7)
; 8:ENEMY_DATA_8 = 230:BOSS4_R_LEG_P2_C(8)
; 9:ENEMY_DATA_9 = 232:BOSS4_R_LEG_P3_C(9)
; A:ENEMY_DATA_A = 230:BOSS4_R_LEG_P4_C(10)
; B:ENEMY_DATA_B = 233:BOSS4_R_LEG_P5_C(11)
;
; 235:天井(MOVE及びDISPでの処理なし、表示はBGで描画)
; 236:地面(MOVE及びDISPでの処理なし、表示はBGで描画)

BOSS4_DATA:
BOSS4_CORE:DB 099,116,08+32,8,8,0,0,&H0A,0,&HFF,0,0,0,0,0,0
BOSS4_BODY:DB 230,116,16+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_LP1:DB 230,112,16+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_LP2:DB 230,108,16+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_LP3:DB 231,104,16+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_LP4:DB 230,104,24+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_LP5:DB 233,104,32+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_RP1:DB 230,122,16+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_RP2:DB 230,128,16+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_RP3:DB 232,128,16+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_RP4:DB 230,128,24+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_RP5:DB 233,128,32+32,8,8,0,0,&HFF,0,&HFF,0,0,0,0,0,0
BOSS4_DATA_END:

;---------BOSS4足移動テーブル---------------------
BOSS4MOVETBLX_L:DB 0,0,0,255,255,255,255,255,255,255,255,0,0,0,0,0
BOSS4MOVETBLY_L:DB 0,254,254,255,255,255,255,0,0,0,0,2,2,2,2,0
BOSS4MOVETBLX_R:DB 0,0,0,0,0,1,1,1,1,1,1,1,1,0,0,0
BOSS4MOVETBLY_R:DB 0,254,254,255,255,255,255,0,0,0,0,2,2,2,2,0
BOSS4MOVETBL_LG:DB 16,14,12,10,8,8,8,8,8,8,8,8,10,12,14,16

BOSS4_DATA_NUM:EQU 12;BOSS4のパーツ数

BOSS_MAP_UPPER:
DB 235,0,08,144,2,0,0,&HFF,0,10,0,0,0,0,0,0;UPPER
BOSS_MAP_LOWER:
DB 236,0,38,144,2,0,0,&HFF,0,10,0,0,0,0,0,0;LOWER

BOSS4_INIT:

;RXCNT
;ENEMY_DATA初期化
LDW $0,ENEMY_DATA
LDW $2,&H0FF
LDW $28,CLEME
CAL IOCS_CAL

CAL OBJECT_ARRAY_INI

;******************* BOSSデータのブロック転送*********
;BOSS1を構成する位置データ等を転送
PRE IX,BOSS4_DATA
PRE IZ,ENEMY_DATA
PRE IY,BOSS4_DATA_END-1
BUP

;OBJECT_ARRAY POINTERをBOSS4のパーツ数に変更
PRE IX,OBJECT_ARRAY+16;OBJECT_ARRAY POINTER
LD $0,&H0F-BOSS4_DATA_NUM
ST $0,(IX+$31)
;**********************************************

;MAP UPPER
PRE IX,BOSS_MAP_UPPER
LDIM $17,(IX+$31),8
LDM $25,(IX+$31),2
CAL INSERT_OBJECT

;MAP LOWER
PRE IX,BOSS_MAP_LOWER
LDIM $17,(IX+$31),8
LDM $25,(IX+$31),2
CAL INSERT_OBJECT

;転送したBOSSデータを実体化する
CAL INSERT_OBJECT_ON

;ボス戦闘中フラグをONにする。
PRE IX,NOW_BOSS_FIGHT
ST $30,(IX+$31)
;ボス破壊フラグをOFFにする。
PRE IX,BOSS_DESTROY
ST $31,(IX+$31)
;ボスのデータ数(BOSS4:11)を設定にする。
PRE IX,BOSS_DATA_NUM
LD $0,BOSS4_DATA_NUM
ST $0,(IX+$31)

;BOSS4左右移動の規定回数設定
PRE IZ,USER_WORK
LD $0,10
ST $0,(IZ+$31)

;SUPER GPRINT DATA MAKE(BOSS用)
CAL ST4_INIT_GRA_B

RTN

;************************************
;*              BOSS4 PRE
;*  (BOSS4 MOVE STANBY POSITION)
;************************************
BOSS4_PRE:

;BOSS2移動(Y=Y-1)
LD $0,$31
LD $1,&HFF
LD $29,BOSS4_DATA_NUM
CAL MOVE_BOSS_ALL

;BOSS4のX座標が96になったらボス戦に突入
PRE IX,ENEMY_DATA
LD $0,(IX+2)
SBC $0,8
RTN NZ
PRE IX,PHASE
LD $0,3
ST $0,(IX+$31) ;PHASE2->3
ST $31,(IX+$30) ;PHASE_COUNTER->0

;BOSS4左右移動の規定回数設定
PRE IZ,USER_WORK
LD $0,BOSS4_MOVEMAX
ST $0,(IZ+$31)

RTN

;*********************************
;*          MOVE BOSS4
;*
;*USE:
;*      $0      WORK
;*      $2,$3   JUMP TABLE
;*      $9-$16  ENEMY DATA
;*      $28     COUNTER
;*      IX
;*      IZ
;*********************************
BOSS4_MOVEMAX:EQU 12

MOVE_BOSS4:

LD $28,$31

MOVE_BOSS4_LOOP:
PHU $28
PRE IX,ENEMY_DATA

LDM $9,(IX+$28),8
SBC $9,$31

;-------- NOT ACTIVE FLAG(0) ------------------------------
;-------- 全ての衝突判定対象外のオブジェクト(001-089)(MAKE JUDGEで撥ねる)---
;-------- BULLET(89:固定) -----------------------------------
SBC $9,89
;JR Z,ST4_ENEMY89_MOVE;BULLET
;-------- 自弾(GUN,LASER)と衝突判定を行わない敵オブジェクト(000-089)
;-------- DROP ITEM MOTHER(90)---------------------------------
;-------- BOSS CORE(99:固定) -----------------------------------
SBC $9,99
JP Z,BOSS4_P99_MOVE;WAVE
;-------- NORMAL(100-199)----------------------------------
;-----レーザーが衝突するとレーザーが縮む敵オブジェクト(200-229)---------------
;-----レーザーが衝突するとレーザーが縮む無敵の敵オブジェクト(230-255)(壁など)----

NEXT_MOVE_BOSS4:
PPU $28
AD $28,ENEMY_STRUCT
JR NC,MOVE_BOSS4_LOOP

RTN

BOSS4_P99_MOVE:

PRE IZ,SECTION
LD $0,(IZ+$31)

SBC $14,0
JR Z,BOSS4_PROC0;左移動(向かって左の足)
SBC $14,1
JP Z,BOSS4_PROC1;左移動(向かって右の足)
SBC $14,2
JP Z,BOSS4_PROC2;右移動(向かって左の足)
SBC $14,3
JP Z,BOSS4_PROC3;右移動(向かって右の足)
SBC $14,4
JP Z,BOSS4_PROC4;停止(次右移動)
SBC $14,5
JP Z,BOSS4_PROC5;停止(次左移動)

JR NEXT_MOVE_BOSS4 ;保険

;***************************
;*    左移動(向かって左の足)
;***************************
BOSS4_PROC0:
PRE IX,ENEMY_DATA_04;5
LDM $9,(IX+$31),5
PRE IZ,BOSS4MOVETBLX_L
LD $9,(IZ+$15)
AD $10,$9
PRE IZ,BOSS4MOVETBLY_L
LD $9,(IZ+$15)
AD $11,$9
STW $10,(IX+$30)

PRE IX,ENEMY_DATA_03;4
PRE IZ,ENEMY_DATA_00;1
;X座標
LD $0,$15
BID $0
AD $0,$10

ST $0,(IX+$30)

;Y座標
LD $1,16
AD $1,$11
BID $1
ST $1,(IX+2)

PRE IX,ENEMY_DATA_02;3
;X座標
LD $2,(IZ+$30)
AD $2,$0
BID $2
ST $2,(IX+$30)

;Y座標
LD $3,16
AD $3,$1
BID $3
ST $3,(IX+2)

PRE IX,ENEMY_DATA_05;6
ST $10,(IX+1)
LD $6,$11
AD $6,8
ST $6,(IX+2)

PRE IX,ENEMY_DATA_06;7
ST $10,(IX+1)
LD $6,$11
PRE IZ,BOSS4MOVETBL_LG
LD $0,(IZ+$15)
AD $6,$0
ST $6,(IX+2)

PRE IX,ENEMY_DATA_00;1
AD $15,$30 ;COUNTER+1
ST $15,(IX+6)
SBC $15,16
JP NZ,NEXT_MOVE_BOSS4
ST $30,(IX+5) ;左移動(右足)へ移行
ST $31,(IX+6) ;カウンタの初期化
JP NEXT_MOVE_BOSS4

;***************************
;*   左移動(向かって右の足)
;***************************
BOSS4_PROC1:

PRE IX,ENEMY_DATA_09;10
LDM $9,(IX+$31),8
PRE IZ,BOSS4MOVETBLX_L
LD $9,(IZ+$15)
AD $10,$9
PRE IZ,BOSS4MOVETBLY_L
LD $9,(IZ+$15)
AD $11,$9
STW $10,(IX+$30)
AD $15,$30 ;COUNTER+1
AN $15,&H0F
ST $15,(IX+6)

PRE IX,ENEMY_DATA_08;09
PRE IZ,ENEMY_DATA_01
;X座標
LD $0,(IZ+$30)
AD $0,$10
BID $0
LD $29,$0
BID $29
AD $0,2
ST $0,(IX+$30)

;Y座標
LD $1,16
AD $1,$11
BID $1
ST $1,(IX+2)

PRE IX,ENEMY_DATA_07;08
;X座標
LD $2,(IZ+$30)
AD $2,$0
BID $2
ST $2,(IX+$30)

;Y座標
LD $3,16
AD $3,$1
BID $3
ST $3,(IX+2)

PRE IX,ENEMY_DATA_10;11
ST $10,(IX+1)
LD $6,$11
AD $6,8
ST $6,(IX+2)

PRE IX,ENEMY_DATA_11;12
ST $10,(IX+1)
LD $6,$11
PRE IZ,BOSS4MOVETBL_LG
LD $0,(IZ+$15)
AD $6,$0
ST $6,(IX+2)

;CORE(0)とBODY(1)は偶数の時だけ移動
ANC $15,$30
JR NZ,NOMOVEBOSS4CORE
PRE IX,ENEMY_DATA_00;01
SB (IX+$30),$30
PRE IX,ENEMY_DATA_01;02
SB (IX+$30),$30

NOMOVEBOSS4CORE:
PRE IX,ENEMY_DATA_00;01
AD $15,$30 ;COUNTER+1
ST $15,(IX+6)
SBC $15,16
JP NZ,NEXT_MOVE_BOSS4
;規定回数移動したかチェック
PRE IZ,USER_WORK
LD $0,(IZ+$31)
SB (IZ+$31),$30
JR Z,BOSS4_CHANGE_MR
ST $31,(IX+5) ;左移動(向かって左の足)へ移行
ST $31,(IX+6) ;カウンタの初期化
JP NEXT_MOVE_BOSS4
BOSS4_CHANGE_MR:
LD $0,BOSS4_MOVEMAX
ST $0,(IZ+$31)
LD $0,4
ST $0,(IX+5) ;停止(次右移動)へ移行
ST $31,(IX+6) ;ボス2カウンタを初期化
JP NEXT_MOVE_BOSS4

;***************************
;*   右移動(向かって左の足)
;***************************
BOSS4_PROC2:

PRE IX,ENEMY_DATA_04;05
LDM $9,(IX+$31),8
PRE IZ,BOSS4MOVETBLX_R
LD $9,(IZ+$15)
AD $10,$9
PRE IZ,BOSS4MOVETBLY_R
LD $9,(IZ+$15)
AD $11,$9
STW $10,(IX+$30)
AD $15,$30 ;COUNTER+1
AN $15,&H0F
ST $15,(IX+6)

PRE IX,ENEMY_DATA_03;04
PRE IZ,ENEMY_DATA_00;01
;X座標
LD $0,(IZ+$30)
AD $0,$10
BID $0
ST $0,(IX+$30)

;Y座標
LD $1,16
AD $1,$11
BID $1
ST $1,(IX+2)

PRE IX,ENEMY_DATA_02;03
;X座標
LD $2,(IZ+$30)
AD $2,$0
BID $2
ST $2,(IX+$30)

;Y座標
LD $3,16
AD $3,$1
BID $3
ST $3,(IX+2)

PRE IX,ENEMY_DATA_05;06
ST $10,(IX+1)
LD $6,$11
AD $6,8
ST $6,(IX+2)

PRE IX,ENEMY_DATA_06;07
ST $10,(IX+1)
LD $6,$11
PRE IZ,BOSS4MOVETBL_LG
LD $0,(IZ+$15)
AD $6,$0
ST $6,(IX+2)

;CORE(0)とBODY(1)は偶数の時だけ移動
ANC $15,$30
JR NZ,NOMOVEBOSS4_CR
PRE IX,ENEMY_DATA_00;01
AD (IX+$30),$30
PRE IX,ENEMY_DATA_01;02
AD (IX+$30),$30

NOMOVEBOSS4_CR:
PRE IX,ENEMY_DATA_00;01
AD $15,$30 ;COUNTER+1
ST $15,(IX+6)
SBC $15,16
JP NZ,NEXT_MOVE_BOSS4
;規定回数移動したかチェック
PRE IZ,USER_WORK
SB (IZ+$31),$30
JR Z,BOSS4_CHANGE_ML
LD $1,3
ST $1,(IX+5) ;右移動(向かって右の足)へ移行
ST $31,(IX+6) ;ボス2アニメーションカウンタを初期化
ST $0,(IX+7) ;ボス2移動カウンタを保存
JP NEXT_MOVE_BOSS4
BOSS4_CHANGE_ML:
LD $0,BOSS4_MOVEMAX
ST $0,(IZ+$31)
LD $0,5
ST $0,(IX+5) ;停止(次左移動)へ移行
ST $31,(IX+6) ;ボス2アニメーションカウンタを初期化
ST $31,(IX+7) ;ボス2移動カウンタの初期化
JP NEXT_MOVE_BOSS4

;***************************
;*   右移動(向かって右の足)
;***************************
BOSS4_PROC3:
PRE IX,ENEMY_DATA_09;10
LDM $9,(IX+$31),5
PRE IZ,BOSS4MOVETBLX_R
LD $9,(IZ+$15)
AD $10,$9
PRE IZ,BOSS4MOVETBLY_R
LD $9,(IZ+$15)
AD $11,$9
STW $10,(IX+$30)

PRE IX,ENEMY_DATA_08;09
PRE IZ,ENEMY_DATA_00;01
;X座標
LD $0,$15
BID $0
INV $0
AD $0,$10
ST $0,(IX+$30)

;Y座標
LD $1,16
AD $1,$11
BID $1
ST $1,(IX+2)

PRE IX,ENEMY_DATA_07;08
;X座標
LD $2,(IZ+$30)
AD $2,$0
BID $2
ST $2,(IX+$30)

;Y座標
LD $3,16
AD $3,$1
BID $3
ST $3,(IX+2)

PRE IX,ENEMY_DATA_10;11
ST $10,(IX+1)
LD $6,$11
AD $6,8
ST $6,(IX+2)

PRE IX,ENEMY_DATA_11;12
ST $10,(IX+1)
LD $6,$11
PRE IZ,BOSS4MOVETBL_LG
LD $0,(IZ+$15)
AD $6,$0
ST $6,(IX+2)

PRE IX,ENEMY_DATA_00;01
AD $15,$30 ;COUNTER+1
ST $15,(IX+6)
SBC $15,16
JP NZ,NEXT_MOVE_BOSS4
LD $0,2
ST $0,(IX+5) ;右移動(向かって左の足)
ST $31,(IX+6) ;ボス2アニメーションカウンタを初期化
JP NEXT_MOVE_BOSS4

;***************************
;*   　　停止後右移動
;***************************
BOSS4_PROC4:
PRE IX,ENEMY_DATA_00;01
AD $15,$30 ;COUNTER+1
ST $15,(IX+6)
SBC $15,16
JP NZ,NEXT_MOVE_BOSS4
LD $0,3
ST $0,(IX+5) ;右移動(右足)へ移行
ST $31,(IX+6) ;ボス2アニメーションカウンタを初期化
;
JP NEXT_MOVE_BOSS4

;***************************
;*   　　停止後左移動
;***************************
BOSS4_PROC5:
PRE IX,ENEMY_DATA_00;01
AD $15,$30 ;COUNTER+1
ST $15,(IX+6)
SBC $15,16
JP NZ,NEXT_MOVE_BOSS4
ST $31,(IX+5) ;右移動(左足)へ移行
ST $31,(IX+6) ;ボス2アニメーションカウンタを初期化

JP NEXT_MOVE_BOSS4

ST4_KILL_BOSS:
CAL DELETE_OBJECT
JP NEXT_MOVE_BOSS4

END_BOSS4_MOVE:
PRE IX,ENEMY_DATA
STM $9,(IX+$28),8
JP NEXT_MOVE_BOSS4


;*********************************
;*        DISP BOSS4
;*
;*USE:
;*      $0      WORK
;*      $2,$3   JUMP TABLE
;*      $9-$16  ENEMY DATA
;*      $28     COUNTER
;*      IX
;*      IZ
;*********************************
DISP_BOSS4:
LD $28,$31

DISP_BOSS4_LOOP:

PRE IX,ENEMY_DATA

LDM $9,(IX+$28),8
SBC $9,$31
JR Z,NEXT_DISP_BOSS4
;
PHU $28
;
;GPRINTのRTN命令でRTN_ST4_DBOSS4に戻れるようにするため、RTN_ST4_DBOSS4のアドレスを
;SSPにPUSHしておく。
;なおGPRINTからの復帰はRTNでありSSPにスタックされたアドレス+1からプログラムを実行するため
;RTN_ST4_DBOSS4のアドレスから-1したものをSSPにPUSHする。
LDW $0,RTN_ST4_DBOSS4-1
PHSW $1

;-------- NOT ACTIVE FLAG(0) ------------------------------
;-------- 全ての衝突判定対象外のオブジェクト(001-089)(MAKE JUDGEで撥ねる)---
;-------- BULLET(89:固定) -----------------------------------
SBC $9,89
;JR Z,ST2_ENEMY89_MOVE;BULLET
;-------- 自弾(GUN,LASER)と衝突判定を行わない敵オブジェクト(000-089)
;-------- DROP ITEM MOTHER(90)---------------------------------

;-------- BOSS CORE(99:固定) -----------------------------------
SBC $9,99
JP Z,BOSS4_P99_DISP;BOSS_CORE
;-------- NORMAL(100-199)----------------------------------
;-----レーザーが衝突するとレーザーが縮む敵オブジェクト(200-229)---------------
;-----レーザーが衝突するとレーザーが縮む無敵の敵オブジェクト(230-255)(壁など)----
SBC $9,230
JP Z,BOSS4_P230DISP;胴体、脚
SBC $9,231
JP Z,BOSS4_P231DISP;左ひざ
SBC $9,232
JP Z,BOSS4_P232DISP;右ひざ
SBC $9,233
JP Z,BOSS4_P233DISP;脚の一番下

;JUMPしなかった場合はSSPを戻す。
PPSW $0

RTN_ST4_DBOSS4:

;
PPU $28
;
NEXT_DISP_BOSS4:
AD $28,ENEMY_STRUCT
JR NC,DISP_BOSS4_LOOP
RTN

BOSS4_P99_DISP:;(BOSS4)
LD $12,8
LDW $13,SG_CHR_DATA06;CORE
JP SGPRINT_FAST

BOSS4_P230DISP:
LD $12,8
LDW $13,SG_CHR_DATA07;左ひざ
JP SGPRINT_FAST

BOSS4_P231DISP:
LD $12,8
LDW $13,SG_CHR_DATA08;右ひざ
JP SGPRINT_FAST

BOSS4_P232DISP:
LD $12,8
LDW $13,SG_CHR_DATA09;胴体、脚
JP SGPRINT_FAST

BOSS4_P233DISP:
LD $12,8
LDW $13,SG_CHR_DATA10;脚の一番下
JP SGPRINT_FAST

;**********************************
;*      BOSS4撃破時の処理
;**********************************
BOSS_DEF_ST4:

;RTN CODE 0:継続をセット
LD $5,$31

;下へ降下
PRE IX,ENEMY_DATA
;BOSS2移動(Y=Y-1)
LD $0,$31
LD $1,$30
LD $29,BOSS4_DATA_NUM
CAL MOVE_BOSS_ALL

PRE IX,EXTRA_COUNTER
AD (IX+$31),$30
LD $0,40
SBC (IX+$31),$0
RTN NZ
;RTN CODE 1:次のフェーズに移行をセット
LD $5,$30
RTN


;**********************************
;*      ST4_INIT_GRAPHIC
;**********************************

ST4_INIT_GRA_S:
LDW $0,0;自機
LDW $2,CHR_FIGHTER
CAL SET_SGPRINT_DATA

LDW $0,1;MY BOMB L
LDW $2,CHR_BOMB_L
CAL SET_SGPRINT_DATA

LDW $0,2;MY_BOMB_R
LDW $2,CHR_BOMB_R
CAL SET_SGPRINT_DATA

LDW $0,3;FIGHTER_SHADOW
LDW $2,CHR_OPTION
CAL SET_SGPRINT_DATA

;NO4 RESERVE
;LDW $0,4
;LDW $2,CHR_OPTION
;CAL SET_SGPRINT_DATA

;NO5 RESERVE
;LDW $0,5
;LDW $2,CHR_OPTION
;CAL SET_SGPRINT_DATA

;ENEMY
LDW $0,6
LDW $2,CHR_STA_WAVE
CAL SET_SGPRINT_DATA

LDW $0,7
LDW $2,CHR_ST4_04;CIRCULER1
CAL SET_SGPRINT_DATA

LDW $0,8
LDW $2,CHR_ST4_03;ATTACKER1,2
CAL SET_SGPRINT_DATA

LDW $0,9
LDW $2,CHR_ST4_01;AIRBORN
CAL SET_SGPRINT_DATA

RTN

ST4_INIT_GRA_B:
;BOSS
LDW $0,6;BOSS4 CORE
LDW $2,CHR_BOSS4_CORE
CAL SET_SGPRINT_DATA

LDW $0,7;BOSS4 BODY
LDW $2,CHR_BOSS4_BODY
CAL SET_SGPRINT_DATA

LDW $0,8;BOSS4 L-LEG
LDW $2,CHR_BOSS4_L_LEG
CAL SET_SGPRINT_DATA

LDW $0,9;BOSS4 R-LEG
LDW $2,CHR_BOSS4_R_LEG
CAL SET_SGPRINT_DATA

LDW $0,10;BOSS4 FOOT
LDW $2,CHR_BOSS4_FOOT
CAL SET_SGPRINT_DATA

RTN

SET_STAGE4_DATA:
;STAGE4の初期化サブルーチンのアドレス
LDW $0,STAGE_4_INIT
PRE IX,STAGE_INIT
STW $0,(IX+$31)
;STAGE4のマップデータのアドレス
LDW $0,STAGE4_MAP
PRE IX,STAGE_MAP
STW $0,(IX+$31)
;STAGE4のマップに登場する背景キャラクタのデータのアドレス
LDW $0,STAGE4_MAP_CHARA
PRE IX,STAGE_MAP_CHARA
STW $0,(IX+$31)
;STAGE4に登場するの敵のキャラクタデータのアドレス
LDW $0,INIT_DATA_STAGE4
PRE IX,INIT_DATA_STAGE
STW $0,(IX+$31)
;STAGE4の敵の移動サブルーチンのアドレス
LDW $0,ST4_ENEMY_MOVE
PRE IX,ENEMY_MOVE_ADR
STW $0,(IX+$31)
;STAGE4の敵の表示サブルーチンのアドレス
LDW $0,ST4_ENEMY_DISP
PRE IX,ENEMY_DISP_ADR
STW $0,(IX+$31)
;BOSS4初期化サブルーチンのアドレス
LDW $0,BOSS4_INIT
PRE IX,BOSS_INIT_ADR
STW $0,(IX+$31)
;BOSS4登場時の動作サブルーチンのアドレス
LDW $0,BOSS4_PRE
PRE IX,BOSS_PRE_ADR
STW $0,(IX+$31)
;BOSS4移動サブルーチンのアドレス
LDW $0,MOVE_BOSS4
PRE IX,BOSS_MOVE_ADR
STW $0,(IX+$31)
;BOSS4表示サブルーチンのアドレス
LDW $0,DISP_BOSS4
PRE IX,BOSS_DISP_ADR
STW $0,(IX+$31)
;BOSS4の名前が格納されたアドレス
PRE IX,MES_NAME_BOSS4
LDM $0,(IX+$31),8
PRE IX,BOSS_NAME
STM $0,(IX+$31),8
;
;SUPER GPRINT DATA MAKE
CAL ST4_INIT_GRA_S
;
RTN
